Dates and times!

Author: lpil

CHANGELOG.md

@@ -4,6 +4,7 @@
 
 - Renamed to `pog`.
 - Configuration and query API redesigned.
+- Introduced the `Date`, `Time`, and `Timestamp` types.
 
 ## v0.15.0 - Unreleased
 

src/pog.gleam

@@ -2,7 +2,11 @@
 ////
 //// Gleam wrapper around pgo library
 
+// TODO: add time and timestamp with zone once PGO supports them
+
 import gleam/dynamic.{type DecodeErrors, type Decoder, type Dynamic}
+import gleam/float
+import gleam/int
 import gleam/list
 import gleam/option.{type Option, None, Some}
 import gleam/result
@@ -272,13 +276,22 @@ pub fn bytea(a: BitArray) -> Value
 @external(erlang, "pog_ffi", "coerce")
 pub fn array(a: List(a)) -> Value
 
-/// Coerce a timestamp represented as `#(#(year, month, day), #(hour, minute, second))` into a `Value`.
-@external(erlang, "pog_ffi", "coerce")
-pub fn timestamp(a: #(#(Int, Int, Int), #(Int, Int, Int))) -> Value
+pub fn timestamp(timestamp: Timestamp) -> Value {
+  coerce_value(#(date(timestamp.date), time(timestamp.time)))
+}
+
+pub fn date(date: Date) -> Value {
+  coerce_value(#(date.year, date.month, date.day))
+}
+
+pub fn time(time: Time) -> Value {
+  let seconds = int.to_float(time.seconds)
+  let seconds = seconds +. int.to_float(time.microseconds) /. 1_000_000.0
+  coerce_value(#(time.hours, time.minutes, seconds))
+}
 
-/// Coerce a date represented as `#(year, month, day)` into a `Value`.
 @external(erlang, "pog_ffi", "coerce")
-pub fn date(a: #(Int, Int, Int)) -> Value
+fn coerce_value(a: anything) -> Value
 
 pub type TransactionError {
   TransactionQueryError(QueryError)
@@ -656,18 +669,57 @@ pub fn error_code_name(error_code: String) -> Result(String, Nil) {
   }
 }
 
-/// Checks to see if the value is formatted as `#(#(Int, Int, Int), #(Int, Int, Int))`
-/// to represent `#(#(year, month, day), #(hour, minute, second))`, and returns the
-/// value if it is.
-pub fn decode_timestamp(value: dynamic.Dynamic) {
-  dynamic.tuple2(
-    dynamic.tuple3(dynamic.int, dynamic.int, dynamic.int),
-    dynamic.tuple3(dynamic.int, dynamic.int, dynamic.int),
+pub fn decode_timestamp(
+  value: dynamic.Dynamic,
+) -> Result(Timestamp, DecodeErrors) {
+  dynamic.decode2(
+    Timestamp,
+    dynamic.element(0, decode_date),
+    dynamic.element(1, decode_time),
   )(value)
 }
 
-/// Checks to see if the value is formatted as `#(Int, Int, Int)` to represent a date
-/// as `#(year, month, day)`, and returns the value if it is.
-pub fn decode_date(value: dynamic.Dynamic) {
-  dynamic.tuple3(dynamic.int, dynamic.int, dynamic.int)(value)
+pub fn decode_date(value: dynamic.Dynamic) -> Result(Date, DecodeErrors) {
+  dynamic.decode3(
+    Date,
+    dynamic.element(0, dynamic.int),
+    dynamic.element(1, dynamic.int),
+    dynamic.element(2, dynamic.int),
+  )(value)
+}
+
+pub fn decode_time(value: dynamic.Dynamic) -> Result(Time, DecodeErrors) {
+  case dynamic.tuple3(dynamic.int, dynamic.int, decode_seconds)(value) {
+    Error(e) -> Error(e)
+    Ok(#(hours, minutes, #(seconds, microseconds))) ->
+      Ok(Time(hours:, minutes:, seconds:, microseconds:))
+  }
+}
+
+fn decode_seconds(value: dynamic.Dynamic) -> Result(#(Int, Int), DecodeErrors) {
+  case dynamic.int(value) {
+    Ok(i) -> Ok(#(i, 0))
+    Error(_) ->
+      case dynamic.float(value) {
+        Error(e) -> Error(e)
+        Ok(i) -> {
+          let floored = float.floor(i)
+          let seconds = float.round(floored)
+          let microseconds = float.round({ i -. floored } *. 1_000_000.0)
+          Ok(#(seconds, microseconds))
+        }
+      }
+  }
+}
+
+pub type Date {
+  Date(year: Int, month: Int, day: Int)
+}
+
+pub type Time {
+  Time(hours: Int, minutes: Int, seconds: Int, microseconds: Int)
+}
+
+pub type Timestamp {
+  Timestamp(date: Date, time: Time)
 }

test/pog_test.gleam

@@ -125,7 +125,7 @@ pub fn selecting_rows_test() {
     INSERT INTO
       cats
     VALUES
-      (DEFAULT, 'neo', true, ARRAY ['black'], '2022-10-10 11:30:30', '2020-03-04')
+      (DEFAULT, 'neo', true, ARRAY ['black'], '2022-10-10 11:30:30.1', '2020-03-04')
     RETURNING
       id"
 
@@ -151,11 +151,14 @@ pub fn selecting_rows_test() {
   |> should.equal(1)
   returned.rows
   |> should.equal([
-    #(id, "neo", True, ["black"], #(#(2022, 10, 10), #(11, 30, 30)), #(
-      2020,
-      3,
-      4,
-    )),
+    #(
+      id,
+      "neo",
+      True,
+      ["black"],
+      pog.Timestamp(pog.Date(2022, 10, 10), pog.Time(11, 30, 30, 100_000)),
+      pog.Date(2020, 3, 4),
+    ),
   ])
 
   pog.disconnect(db)
@@ -361,7 +364,7 @@ pub fn array_test() {
 pub fn datetime_test() {
   start_default()
   |> assert_roundtrip(
-    #(#(2022, 10, 12), #(11, 30, 33)),
+    pog.Timestamp(pog.Date(2022, 10, 12), pog.Time(11, 30, 33, 101)),
     "timestamp",
     pog.timestamp,
     pog.decode_timestamp,
@@ -371,7 +374,7 @@ pub fn datetime_test() {
 
 pub fn date_test() {
   start_default()
-  |> assert_roundtrip(#(2022, 10, 11), "date", pog.date, pog.decode_date)
+  |> assert_roundtrip(pog.Date(2022, 10, 11), "date", pog.date, pog.decode_date)
   |> pog.disconnect
 }
 
@@ -469,11 +472,14 @@ pub fn expected_maps_test() {
   |> should.equal(1)
   returned.rows
   |> should.equal([
-    #(id, "neo", True, ["black"], #(#(2022, 10, 10), #(11, 30, 30)), #(
-      2020,
-      3,
-      4,
-    )),
+    #(
+      id,
+      "neo",
+      True,
+      ["black"],
+      pog.Timestamp(pog.Date(2022, 10, 10), pog.Time(11, 30, 30, 0)),
+      pog.Date(2020, 3, 4),
+    ),
   ])
 
   pog.disconnect(db)