transient-use-accessible-values: New option

Author: tarsius

lisp/transient.el

@@ -563,6 +563,25 @@ in a more natural order."
   :group 'transient
   :type 'boolean)
 
+(defcustom transient-use-accessible-values nil
+  "Whether to show values in a way that does not rely on coloring.
+
+By default faces are used to indicate the state of arguments and
+other values, in a way that makes those faces necessary.  For example,
+if a command-line switch is enabled, it is shown in green, and if it
+disabled, it is shown in gray.  Coloring aside, the exact same text
+is inserted in both cases.
+
+If this is non-nil, then different text is inserted after the argument.
+For example, for a switch either \" is disable\" or \" is disabled\" is
+inserted after the switch.
+
+If you enable this, then `transient-prefer-reading-value' should also
+be enabled.  Also consider enabling `transient-use-accessible-formats'."
+  :package-version '(transient . "0.13.0")
+  :group 'transient
+  :type 'boolean)
+
 (defcustom transient-use-accessible-formats nil
   "Whether to use a more accessible formats for menu elements.
 
@@ -574,7 +593,9 @@ By default the format specified by an elements `format' slot is used.
 When this is non-nil, then the `accessible-format' is used instead.
 The most notable difference is that for an element represent an
 argument or variable, the description is moved after the variable
-and value."
+and value.
+
+Also consider enabling `transient-use-accessible-values'."
   :package-version '(transient . "0.13.0")
   :group 'transient
   :type 'boolean)
@@ -4971,44 +4992,60 @@ apply the face `transient-unreachable' to the complete string."
   "Format OBJ's value for display and return the result.")
 
 (cl-defmethod transient-format-value ((obj transient-suffix))
-  (propertize (oref obj argument) 'face (transient-argument-face obj)))
+  (with-slots (argument value inapt) obj
+    (concat (propertize argument 'face (transient-argument-face obj))
+            (cond ((not transient-use-accessible-values) nil)
+                  (inapt " is inapt")
+                  (value " is enabled")
+                  (t     " is disabled")))))
 
 (cl-defmethod transient-format-value ((obj transient-option))
-  (let ((argument (prin1-to-string (oref obj argument) t)))
+  (let ((argument (prin1-to-string (oref obj argument) t))
+        (aface (transient-argument-face obj))
+        (vface (transient-value-face obj)))
     (if-let ((value (oref obj value)))
-        (let* ((aface (transient-argument-face obj))
-               (vface (transient-value-face obj)))
-          (pcase-exhaustive (oref obj multi-value)
-            ('nil
-             (concat (propertize argument 'face aface)
-                     (propertize value    'face vface)))
-            ((or 't 'rest)
-             (concat (propertize (if (string-suffix-p " " argument)
-                                     argument
-                                   (concat argument " "))
-                                 'face aface)
-                     (propertize (mapconcat #'prin1-to-string value " ")
-                                 'face vface)))
-            ('repeat
-             (mapconcat (lambda (value)
-                          (concat (propertize argument 'face aface)
-                                  (propertize value    'face vface)))
-                        value " "))))
-      (propertize argument 'face 'transient-inactive-argument))))
+        (pcase-exhaustive (oref obj multi-value)
+          ('nil
+           (concat (propertize argument 'face aface)
+                   (propertize value    'face vface)))
+          ((or 't 'rest)
+           (concat (propertize (if (string-suffix-p " " argument)
+                                   argument
+                                 (concat argument " "))
+                               'face aface)
+                   (propertize (mapconcat #'prin1-to-string value " ")
+                               'face vface)))
+          ('repeat
+           (mapconcat (lambda (value)
+                        (concat (propertize argument 'face aface)
+                                (propertize value    'face vface)))
+                      value " ")))
+      (concat (propertize (if (string-suffix-p "=" argument)
+                              (substring argument 0 -1)
+                            argument)
+                          'face aface)
+              (and transient-use-accessible-values " is disabled")))))
 
 (cl-defmethod transient-format-value ((obj transient-switches))
-  (with-slots (value argument-format choices) obj
-    (format (propertize argument-format 'face (transient-argument-face obj))
-            (format
-             (propertize "[%s]" 'face 'transient-delimiter)
-             (mapconcat
-              (lambda (choice)
-                (propertize choice 'face
-                            (transient-value-face
-                             obj
-                             (equal (format argument-format choice) value))))
-              choices
-              (propertize "|" 'face 'transient-delimiter))))))
+  (pcase-let (((eieio value argument-format choices) obj)
+              (face (transient-argument-face obj)))
+    (cond
+      ((not transient-use-accessible-values)
+       (format (propertize argument-format 'face face)
+               (format
+                (propertize "[%s]" 'face 'transient-delimiter)
+                (mapconcat
+                 (lambda (choice)
+                   (propertize choice 'face
+                               (transient-value-face
+                                obj
+                                (equal (format argument-format choice) value))))
+                 choices
+                 (propertize "|" 'face 'transient-delimiter)))))
+      (value (propertize value 'face face))
+      ((format "No %s argument is enabled"
+               (propertize (string-replace "%s" "*" argument-format)
+                           'face face))))))
 
 (defun transient-argument-face (obj)
   (if (oref obj value)