Adapt CMakelLists.txt for Windows conda build

Signed-off-by: Julien Jerphanion <[email protected]>

Author: jjerphan

cpp/CMakeLists.txt

@@ -75,20 +75,82 @@ if(ARCTICDB_SANITIZER_FLAGS)
     message(STATUS "Building ArcticDB with sanitizers. Compiler flags: ${ARCTICDB_SANITIZER_FLAGS}")
 endif()
 
+if(${ARCTICDB_USING_CONDA})
+    # Required to be able to include headers from glog since glog 0.7
+    # See: https://github.com/google/glog/pull/1030
+    add_compile_definitions(GLOG_USE_GLOG_EXPORT)
+endif()
+
 if(WIN32)
     add_compile_definitions(
         NOGDI WIN32_LEAN_AND_MEAN HAVE_SNPRINTF NOMINMAX
         "$<$<CONFIG:Debug>:DEBUG_BUILD>"
     )
+    if(${ARCTICDB_USING_CONDA})
+        add_compile_definitions(
+            # Required to link against zstd.dll
+            # See: https://github.com/facebook/zstd/blob/dev/lib/zstd.h#L47-L53
+            ZSTD_DLL_IMPORT=1
+
+            # Required to link against lz4.dll
+            # See: https://github.com/lz4/lz4/blob/dev/lib/lz4frame.h#L79-L85
+            LZ4_DLL_IMPORT=1
+
+            # Required to link against protobuf.dll
+            # See: https://github.com/protocolbuffers/protobuf/blob/384fabf35a9b5d1f1502edaf9a139b1f51551a01/cmake/README.md?plain=1#L296-L319
+            PROTOBUF_USE_DLLS=1
+
+            # Required to link against fmt.dll
+            FMT_SHARED=1
+
+            # Required to link against spdlog.dll
+            # See: https://github.com/gabime/spdlog/blob/faa0a7a9c5a3550ed5461fab7d8e31c37fd1a2ef/include/spdlog/common.h#L28-L48
+            SPDLOG_COMPILED_LIB=1
+            SPDLOG_SHARED_LIB=1
+            SPDLOG_HEADER_ONLY=0
+
+            # Indicate that we are building using fmt's external DLL instead of spdlog's internal fmt
+            SPDLOG_FMT_EXTERNAL=1
+
+            # Required to link against azure-core.dll
+            # See: https://github.com/Azure/azure-sdk-for-cpp/blob/c914c0933fa4835c6618a42bb276d6077423b170/sdk/storage/azure-storage-common/inc/azure/storage/common/dll_import_export.hpp#L19
+            AZ_CORE_DLL=1
+
+            # Required to link against azure-identity.dll
+            # See: https://github.com/Azure/azure-sdk-for-cpp/blob/bf36db827f5ea1ef2e38953875c6c335b4242b2e/sdk/identity/azure-identity/inc/azure/identity/dll_import_export.hpp
+            AZ_IDENTITY_DLL=1
+
+            # Required to link against azure-storage-common.dll
+            # See: https://github.com/Azure/azure-sdk-for-cpp/blob/c914c0933fa4835c6618a42bb276d6077423b170/sdk/storage/azure-storage-common/inc/azure/storage/common/dll_import_export.hpp#L19
+            AZ_STORAGE_COMMON_DLL=1
+
+            # Required to link against azure-storage-blobs.dll
+            # See: https://github.com/Azure/azure-sdk-for-cpp/blob/bf36db827f5ea1ef2e38953875c6c335b4242b2e/sdk/storage/azure-storage-blobs/inc/azure/storage/blobs/dll_import_export.hpp
+            AZ_STORAGE_BLOBS_DLL=1
+        )
+    endif()
 
     # We always generate the debug info on Windows since those are not in the final .dll.
     # sccache needs the /Z7 format, but the linker will still produce .pdb files.
     # Guide to MSVC compilation warnings https://learn.microsoft.com/en-us/cpp/error-messages/compiler-warnings/compiler-warnings-c4000-through-c4199?view=msvc-170
     add_compile_options(
         /DWIN32 /D_WINDOWS /GR /EHsc /bigobj /Z7 /wd4244 /wd4267
-        "$<$<CONFIG:Debug>:/Od;/MTd>"
-        "$<$<CONFIG:Release>:/MT;/Ox>"
     )
+
+    if(${ARCTICDB_USING_CONDA})
+        # Conda builds use dynamic linkage
+        add_compile_options(
+            "$<$<CONFIG:Debug>:/MDd>"
+            "$<$<CONFIG:Release>:/MD;/Ox>"
+        )
+    else()
+        # PyPI builds use static linkage
+        add_compile_options(
+            "$<$<CONFIG:Debug>:/Od;/MTd>"
+            "$<$<CONFIG:Release>:/MT;/Ox>"
+        )
+    endif()
+
     if(${ARCTICDB_MSVC_OMIT_RUNTIME_CHECKS})
         message(STATUS "Removing MSVC runtime checks")
         foreach(flag_var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
@@ -97,9 +159,7 @@ if(WIN32)
     endif()
 else()
     if(${ARCTICDB_USING_CONDA})
-        # Required to be able to include headers from glog since glog 0.7
-        # See: https://github.com/google/glog/pull/1030
-        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wextra -DGLOG_USE_GLOG_EXPORT")
+        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wextra")
     else()
         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra")
     endif()

cpp/arcticdb/CMakeLists.txt

@@ -168,11 +168,19 @@ if (NOT MSVC)
     add_compile_options("-fno-omit-frame-pointer")
 else()
     add_compile_options(
-        /WX
         /wd4250 # Suppress inherits via dominance warning
-        /we4189 # Unused local variable is an error
         /we4100 # Unused function parameter is an error
     )
+    if(NOT ${ARCTICDB_USING_CONDA})
+        # Some of the warnings are due to the protobuf library,
+        # observed for the conda-forge builds.
+        # For now, we do not want to treat warnings as errors for those builds.
+        # See: https://github.com/protocolbuffers/protobuf/pull/20840
+        add_compile_options(
+            /WX
+            /we4189 # Unused local variable is an error
+        )
+    endif()
 endif ()
 
 ## Core library without python bindings ##
@@ -692,8 +700,10 @@ if (WIN32)
         arcticdb_core_object
         PRIVATE
             /W4
-            /external:I${CMAKE_SOURCE_DIR}/vcpkg
-            /external:I${CMAKE_SOURCE_DIR}/third_party
+            # The distribution on conda-forge only uses the source code of ArcticDB itself
+            # without submodules and dependencies from `vcpkg` or `third_party`.
+            $<$<NOT:$<BOOL:${ARCTICDB_USING_CONDA}>>:/external:I${CMAKE_SOURCE_DIR}/vcpkg>
+            $<$<NOT:$<BOOL:${ARCTICDB_USING_CONDA}>>:/external:I${CMAKE_SOURCE_DIR}/third_party>
             /Zc:__cplusplus #needed to get the correct __cplusplus macro value
     )
 endif()