LETTER.HPB

100 REM *** LETTER - A LETTER GUESSING GAME ***
110 REM *** COPYRIGHT PEOPLE'S COMPUTER COMPANY
120 REM *** P.O. BOX 310, MENLO PARK CA 94025
130 DIM A$[26],G$[26],L$[1]
140 LET A$="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
150 REM *** PRINT INSTRUCTIONS ON HOW TO PLAY
160 PRINT "I WILL THINK OF A LETTER FROM A TO Z."
170 PRINT "TRY TO GUESS MY LETTER. AFTER EACH GUESS, I WILL"
180 PRINT "TELL YOU IF YOU GUESSED MY LETTER OR IF YOUR GUESS"
190 PRINT "IS TOO HIGH OR TOO LOW. THE LOWEST LETTER IS 'A'"
200 PRINT "AND THE HIGHEST LETTER IS 'Z'."
210 PRINT
220 PRINT "IF YOU WISH, THINK OF THE LETTERS FROM 'A'"
230 PRINT "TO 'Z' ARRANGED IN A TOTEM POLE WITH 'A' ON THE"
240 PRINT "BOTTOM AND 'Z' ON THE TOP. IF I TELL YOU TO TRY A"
250 PRINT "HIGHER LETTER, TRY ONE CLOSER TO THE TOP OF THE"
260 PRINT "TOTEM POLE. IF I TELL YOU TO TRY A LOWER LETTER, TRY"
270 PRINT "ONE CLOSER TO THE BOTTOM OF THE TOTEM POLE. ENJOY!!!"
280 REM *** COMPUTER 'THINKS' OF A LETTER
290 LET X=INT(26*RND(0))+1
300 LET L$=A$[X,X]
310 PRINT
320 PRINT "OK, I HAVE A LETTER. START GUESSING."
330 REM *** ASK FOR A GUESS
340 PRINT
350 PRINT "WHAT IS YOUR GUESS";
360 INPUT G$
370 REM *** IF GUESS IS NOT A LETTER, TRY AGAIN
380 FOR K =1 TO 26
390 IF G$=A$[K,K] THEN 440
400 NEXT K
410 PRINT "HEY!!! THAT'S NOT A SINGLE LETTER. PLAY FAIR, NOW!"
420 GOTO 340
430 REM *** COMPARE GUESS WITH COMPUTER'S LETTER
440 IF G$=L$ THEN 510
450 IF G$>L$ THEN 480
460 PRINT "TOO LOW. TRY A HIGHER LETTER."
470 GOTO 340
480 PRINT "TOO HIGH. TRY A LOWER LETTER."
490 GOTO 340
500 REM *** HUMAN HAS GUESSED THE COMPUTER'S LETTER
510 PRINT
520 PRINT "YOU GOT IT!!! LET'S PLAY AGAIN."
530 PRINT
540 GOTO 290
550 END