zeroclaw/package.nix at main · maxtongwang/zeroclaw · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
{
  makeRustPlatform,
  rustToolchain,
  lib,
  zeroclaw-web,
  removeReferencesTo,
}:
let
  rustPlatform = makeRustPlatform {
    cargo = rustToolchain;
    rustc = rustToolchain;
  };
in
rustPlatform.buildRustPackage (finalAttrs: {
  pname = "zeroclaw";
  version = "0.1.8";

  src =
    let
      fs = lib.fileset;
    in
    fs.toSource {
      root = ./.;
      fileset = fs.unions (
        [
          ./src
          ./Cargo.toml
          ./Cargo.lock
          ./crates
          ./benches
        ]
        ++ (lib.optionals finalAttrs.doCheck [
          ./tests
          ./test_helpers
        ])
      );
    };
  prePatch = ''
    mkdir web
    ln -s ${zeroclaw-web} web/dist
  '';

  cargoLock.lockFile = ./Cargo.lock;

  nativeBuildInputs = [
    removeReferencesTo
  ];

  # Since tests run in the official pipeline, no need to run them in the Nix sandbox.
  # Can be changed by consumers using `overrideAttrs` on this package.
  doCheck = false;

  # Some dependency causes Nix to detect the Rust toolchain to be a runtime dependency
  # of zeroclaw. This manually removes any reference to the toolchain.
  postFixup = ''
    find "$out" -type f -exec remove-references-to -t ${rustToolchain} '{}' +
  '';
})