public-letsql/flake.nix at main · mesejo/public-letsql · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
{
  description = "A modern data processing library focused on composability, portability, and performance.";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    pyproject-nix = {
      url = "github:pyproject-nix/pyproject.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    uv2nix = {
      url = "github:pyproject-nix/uv2nix";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    pyproject-build-systems = {
      url = "github:pyproject-nix/build-system-pkgs";
      inputs = {
        pyproject-nix.follows = "pyproject-nix";
        uv2nix.follows = "uv2nix";
        nixpkgs.follows = "nixpkgs";
      };
    };
    nix-utils = {
      url = "github:xorq-labs/nix-utils";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      pyproject-nix,
      uv2nix,
      pyproject-build-systems,
      nix-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pythonDarwinHotfix = old: {
          # https://github.com/NixOS/nixpkgs/pull/390454
          preConfigure = old.preConfigure + (
            pkgs.lib.optionalString
            (system == "aarch64-darwin")
            ''
              # Fix _ctypes module compilation
              export NIX_CFLAGS_COMPILE+=" -DUSING_APPLE_OS_LIBFFI=1"
            ''
          );
        };
        pkgs = import nixpkgs {
          inherit system;
          overlays = [
            (_final: prev: {
              python310 = prev.python310.overrideAttrs pythonDarwinHotfix;
              python311 = prev.python311.overrideAttrs pythonDarwinHotfix;
            })
          ];
        };
        inherit (nix-utils.lib.${system}.utils) drvToApp;

        src = ./.;
        mkXorq = import ./nix/xorq.nix {
          inherit
            system
            pkgs
            pyproject-nix
            uv2nix
            pyproject-build-systems
            src
            ;
        };
        xorq-310 = mkXorq pkgs.python310;
        xorq-311 = mkXorq pkgs.python311;
        xorq-312 = mkXorq pkgs.python312;
        xorq-313 = mkXorq pkgs.python313;
      in
      {
        formatter = pkgs.nixfmt-rfc-style;
        apps = {
          python-310-default = drvToApp {
            drv = xorq-310.virtualenv-default;
            name = "python";
          };
          python-311-default = drvToApp {
            drv = xorq-311.virtualenv-default;
            name = "python";
          };
          python-312-default = drvToApp {
            drv = xorq-312.virtualenv-default;
            name = "python";
          };
          python-313-default = drvToApp {
            drv = xorq-313.virtualenv-default;
            name = "python";
          };
          ipython-310-all = drvToApp {
            drv = xorq-310.virtualenv-all;
            name = "ipython";
          };
          ipython-311-all = drvToApp {
            drv = xorq-311.virtualenv-all;
            name = "ipython";
          };
          ipython-312-all = drvToApp {
            drv = xorq-312.virtualenv-all;
            name = "ipython";
          };
          ipython-313-all = drvToApp {
            drv = xorq-313.virtualenv-all;
            name = "ipython";
          };
          default = self.apps.${system}.python-312-default;
          xorq = drvToApp {
            drv = xorq-312.virtualenv-all;
            name = "xorq";
          };
        };
        lib = {
          inherit
            pkgs
            src
            mkXorq
            xorq-310
            xorq-311
            xorq-312
            ;
        };
        devShells = {
          impure = pkgs.mkShell {
            packages = [
              pkgs.python310
              pkgs.uv
              pkgs.gh
            ];
            env =
              {
                # Prevent uv from managing Python downloads
                UV_PYTHON_DOWNLOADS = "never";
                # Force uv to use nixpkgs Python interpreter
                UV_PYTHON = pkgs.python310.interpreter;
              }
              // pkgs.lib.optionalAttrs pkgs.stdenv.isLinux {
                # Python libraries often load native shared objects using dlopen(3).
                # Setting LD_LIBRARY_PATH makes the dynamic library loader aware of libraries without using RPATH for lookup.
                LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath pkgs.pythonManylinuxPackages.manylinux1;
              };
            shellHook = ''
              unset PYTHONPATH
            '';
          };
          uv = pkgs.mkShell {
            packages = [
              pkgs.python310
              pkgs.uv
            ];
            shellHook = ''
              unset PYTHONPATH
            '';
          };
          virtualenv-310 = xorq-310.shell;
          virtualenv-default-313 = xorq-313.defaultShell;
          virtualenv-editable-310 = xorq-310.editableShell;
          virtualenv-311 = xorq-311.shell;
          virtualenv-editable-311 = xorq-311.editableShell;
          virtualenv-312 = xorq-312.shell;
          virtualenv-editable-312 = xorq-312.editableShell;
          virtualenv-313 = xorq-313.shell;
          virtualenv-editable-313 = xorq-313.editableShell;
          default = self.devShells.${system}.virtualenv-313;
        };
      }
    );
}