Use configurations for passing changelog files in gradle

Author: mezz

Changelog/build.gradle.kts

@@ -9,7 +9,7 @@ plugins {
 val specificationVersion: String by extra
 val changelogUntaggedName = "Current release $specificationVersion"
 
-tasks.register<GitChangelogTask>("makeChangelog") {
+val makeHtmlChangelog = tasks.register<GitChangelogTask>("makeHtmlChangelog") {
 	val output = layout.buildDirectory.file("changelog.html")
 
 	fromRepo.set(project.rootProject.rootDir.absolutePath)
@@ -23,7 +23,7 @@ tasks.register<GitChangelogTask>("makeChangelog") {
 	outputs.file(output)
 }
 
-tasks.register<GitChangelogTask>("makeMarkdownChangelog") {
+val makeMarkdownChangelog = tasks.register<GitChangelogTask>("makeMarkdownChangelog") {
 	val output = layout.buildDirectory.file("changelog.md")
 
 	fromRepo.set(project.rootProject.rootDir.absolutePath)
@@ -40,3 +40,27 @@ tasks.register<GitChangelogTask>("makeMarkdownChangelog") {
 tasks.withType<GitChangelogTask> {
 	outputs.upToDateWhen { false } // Always run
 }
+
+val changelogHtml = configurations.create("changelogHtml") {
+	isCanBeConsumed = true
+	isCanBeResolved = false
+	isVisible = false
+	attributes {
+		attribute(Usage.USAGE_ATTRIBUTE, objects.named<Usage>("changelogHtml"))
+	}
+	outgoing.artifact(makeHtmlChangelog.map { it.outputs.files.singleFile }) {
+		type = "html"
+	}
+}
+
+val changelogMarkdown = configurations.create("changelogMarkdown") {
+	isCanBeConsumed = true
+	isCanBeResolved = false
+	isVisible = false
+	attributes {
+		attribute(Usage.USAGE_ATTRIBUTE, objects.named<Usage>("changelogMarkdown"))
+	}
+	outgoing.artifact(makeMarkdownChangelog.map { it.outputs.files.singleFile }) {
+		type = "markdown"
+	}
+}

NeoForge/build.gradle.kts

@@ -1,5 +1,3 @@
-import me.modmuss50.mpp.PublishModTask
-import me.modmuss50.mpp.platforms.curseforge.Curseforge
 import org.gradle.api.tasks.testing.logging.TestExceptionFormat
 import org.gradle.api.tasks.testing.logging.TestLogEvent
 import org.slf4j.event.Level
@@ -56,7 +54,6 @@ val dependencyProjects: List<Project> = listOf(
 dependencyProjects.forEach {
 	project.evaluationDependsOn(it.path)
 }
-project.evaluationDependsOn(":Changelog")
 
 tasks.withType<JavaCompile>().configureEach {
     dependencyProjects.forEach {
@@ -77,6 +74,31 @@ java {
 	withSourcesJar()
 }
 
+val changelogHtml = configurations.create("changelogHtml") {
+	isCanBeConsumed = false
+	isCanBeResolved = true
+	isVisible = false
+	attributes {
+		attribute(Usage.USAGE_ATTRIBUTE, objects.named<Usage>("changelogHtml"))
+	}
+}
+
+val changelogMarkdown = configurations.create("changelogMarkdown") {
+	isCanBeConsumed = false
+	isCanBeResolved = true
+	isVisible = false
+	attributes {
+		attribute(Usage.USAGE_ATTRIBUTE, objects.named<Usage>("changelogMarkdown"))
+	}
+}
+
+fun Configuration.singleFileContents(): Provider<String> =
+	incoming
+		.files
+		.elements
+		.map { elements -> elements.single() }
+		.map { it.asFile.readText() }
+
 dependencies {
 	dependencyProjects.forEach {
 		implementation(it)
@@ -91,6 +113,8 @@ dependencies {
 		name = "junit-jupiter-engine",
 		version = jUnitVersion
 	)
+	changelogHtml(project(":Changelog"))
+	changelogMarkdown(project(":Changelog"))
 }
 
 neoForge {
@@ -150,47 +174,6 @@ val sourcesJarTask = tasks.named<Jar>("sourcesJar") {
 	archiveClassifier.set("sources")
 }
 
-
-abstract class ReadChangelog : DefaultTask() {
-	@get:InputFile
-	abstract val inputFile: RegularFileProperty
-
-	@get:OutputFile
-	abstract val outputFile: RegularFileProperty
-
-	@TaskAction
-	fun read() {
-		val text = inputFile.get().asFile.readText()
-		outputFile.get().asFile.writeText(text)
-	}
-}
-
-val changelogHtmlFile: Provider<RegularFile> =
-	project(":Changelog").layout.buildDirectory.file("changelog.html")
-
-val changelogHtmlTask = tasks.register<ReadChangelog>("readChangelogHtml") {
-	dependsOn(":Changelog:makeChangelog")
-	inputFile.set(changelogHtmlFile)
-	outputFile.set(layout.buildDirectory.file("intermediates/changelog.html"))
-}
-
-val changelogHtmlContent: Provider<String> = changelogHtmlTask.flatMap {
-	it.outputFile.map { f -> f.asFile.readText() }
-}
-
-val changelogMdFile: Provider<RegularFile> =
-	project(":Changelog").layout.buildDirectory.file("changelog.md")
-
-val changelogMdTask = tasks.register<ReadChangelog>("readChangelogMd") {
-	dependsOn(":Changelog:makeMarkdownChangelog")
-	inputFile.set(changelogMdFile)
-	outputFile.set(layout.buildDirectory.file("intermediates/changelog.md"))
-}
-
-val changelogMdContent: Provider<String> = changelogMdTask.flatMap {
-	it.outputFile.map { f -> f.asFile.readText() }
-}
-
 publishMods {
 	file.set(tasks.jar.get().archiveFile)
 	type = BETA
@@ -201,7 +184,7 @@ publishMods {
 	curseforge {
 		projectId = curseProjectId
 		accessToken.set(curseforgeApikey ?: "0")
-		changelog.set(changelogHtmlContent)
+		changelog.set(changelogHtml.singleFileContents())
 		changelogType = "html"
 		minecraftVersionRange {
 			start = minecraftVersionRangeStart
@@ -213,18 +196,14 @@ publishMods {
 	modrinth {
 		projectId = modrinthId
 		accessToken = modrinthToken
-		changelog.set(changelogMdContent)
+		changelog.set(changelogMarkdown.singleFileContents())
 		minecraftVersionRange {
 			start = minecraftVersionRangeStart
 			end = minecraftVersion
 		}
 	}
 }
 
-tasks.withType<PublishModTask> {
-	dependsOn(tasks.jar, changelogHtmlTask, changelogMdTask)
-}
-
 tasks.named<Test>("test") {
 	useJUnitPlatform()
 	include("mezz/jei/test/**")