Update changelog code for configuration cache

Author: mezz

Changelog/build.gradle.kts

@@ -2,31 +2,41 @@ import se.bjurr.gitchangelog.plugin.gradle.GitChangelogTask
 
 plugins {
 	// https://plugins.gradle.org/plugin/se.bjurr.gitchangelog.git-changelog-gradle-plugin
-	id("se.bjurr.gitchangelog.git-changelog-gradle-plugin") version("2.1.2")
+	id("se.bjurr.gitchangelog.git-changelog-gradle-plugin") version("3.0.6")
 }
 
 // gradle.properties
 val specificationVersion: String by extra
 val changelogUntaggedName = "Current release $specificationVersion"
 
 tasks.register<GitChangelogTask>("makeChangelog") {
-	fromRepo = projectDir.absolutePath.toString()
-	file = file("changelog.html")
-	untaggedName = changelogUntaggedName
-	fromRevision = "HEAD~30"
-	toRevision = "HEAD"
-	templateContent = file("changelog.mustache").readText()
+	val output = layout.buildDirectory.file("changelog.html")
+
+	fromRepo.set(project.rootProject.rootDir.absolutePath)
+	file.set(output.get().asFile)
+	untaggedName.set(changelogUntaggedName)
+	fromRevision.set("HEAD~30")
+	toRevision.set("HEAD")
+	templateContent.set(file("changelog.mustache").readText())
+
+	// Register output for configuration cache
+	outputs.file(output)
 }
 
 tasks.register<GitChangelogTask>("makeMarkdownChangelog") {
-	fromRepo = projectDir.absolutePath.toString()
-	file = file("changelog.md")
-	untaggedName = changelogUntaggedName
-	fromRevision = System.getenv("GIT_PREVIOUS_SUCCESSFUL_COMMIT") ?: "HEAD~10"
-	toRevision = "HEAD"
-	templateContent = file("changelog-markdown.mustache").readText()
+	val output = layout.buildDirectory.file("changelog.md")
+
+	fromRepo.set(project.rootProject.rootDir.absolutePath)
+	file.set(output.get().asFile)
+	untaggedName.set(changelogUntaggedName)
+	fromRevision.set(System.getenv("GIT_PREVIOUS_SUCCESSFUL_COMMIT") ?: "HEAD~10")
+	toRevision.set("HEAD")
+	templateContent.set(file("changelog-markdown.mustache").readText())
+
+	// Register output for configuration cache
+	outputs.file(output)
 }
 
 tasks.withType<GitChangelogTask> {
-	notCompatibleWithConfigurationCache("invocation of 'Task.project' at execution time is unsupported")
+	outputs.upToDateWhen { false } // Always run
 }

NeoForge/build.gradle.kts

@@ -1,4 +1,5 @@
 import me.modmuss50.mpp.PublishModTask
+import me.modmuss50.mpp.platforms.curseforge.Curseforge
 import org.gradle.api.tasks.testing.logging.TestExceptionFormat
 import org.gradle.api.tasks.testing.logging.TestLogEvent
 import org.slf4j.event.Level
@@ -149,6 +150,47 @@ val sourcesJarTask = tasks.named<Jar>("sourcesJar") {
 	archiveClassifier.set("sources")
 }
 
+
+abstract class ReadChangelog : DefaultTask() {
+	@get:InputFile
+	abstract val inputFile: RegularFileProperty
+
+	@get:OutputFile
+	abstract val outputFile: RegularFileProperty
+
+	@TaskAction
+	fun read() {
+		val text = inputFile.get().asFile.readText()
+		outputFile.get().asFile.writeText(text)
+	}
+}
+
+val changelogHtmlFile: Provider<RegularFile> =
+	project(":Changelog").layout.buildDirectory.file("changelog.html")
+
+val changelogHtmlTask = tasks.register<ReadChangelog>("readChangelogHtml") {
+	dependsOn(":Changelog:makeChangelog")
+	inputFile.set(changelogHtmlFile)
+	outputFile.set(layout.buildDirectory.file("intermediates/changelog.html"))
+}
+
+val changelogHtmlContent: Provider<String> = changelogHtmlTask.flatMap {
+	it.outputFile.map { f -> f.asFile.readText() }
+}
+
+val changelogMdFile: Provider<RegularFile> =
+	project(":Changelog").layout.buildDirectory.file("changelog.md")
+
+val changelogMdTask = tasks.register<ReadChangelog>("readChangelogMd") {
+	dependsOn(":Changelog:makeMarkdownChangelog")
+	inputFile.set(changelogMdFile)
+	outputFile.set(layout.buildDirectory.file("intermediates/changelog.md"))
+}
+
+val changelogMdContent: Provider<String> = changelogMdTask.flatMap {
+	it.outputFile.map { f -> f.asFile.readText() }
+}
+
 publishMods {
 	file.set(tasks.jar.get().archiveFile)
 	type = BETA
@@ -159,7 +201,7 @@ publishMods {
 	curseforge {
 		projectId = curseProjectId
 		accessToken.set(curseforgeApikey ?: "0")
-		changelog.set(provider { file("../Changelog/changelog.html").readText() })
+		changelog.set(changelogHtmlContent)
 		changelogType = "html"
 		minecraftVersionRange {
 			start = minecraftVersionRangeStart
@@ -171,15 +213,18 @@ publishMods {
 	modrinth {
 		projectId = modrinthId
 		accessToken = modrinthToken
-		changelog.set(provider { file("../Changelog/changelog.md").readText() })
+		changelog.set(changelogMdContent)
 		minecraftVersionRange {
 			start = minecraftVersionRangeStart
 			end = minecraftVersion
 		}
 	}
+
+	dryRun = true
 }
+
 tasks.withType<PublishModTask> {
-	dependsOn(tasks.jar, ":Changelog:makeChangelog", ":Changelog:makeMarkdownChangelog")
+	dependsOn(tasks.jar, changelogHtmlTask, changelogMdTask)
 }
 
 tasks.named<Test>("test") {