[EVENT REQUEST] Table 5876 "Phys. Invt. Order Line" in procedure TestQtyRecorded()

[KaMu0608]

Why do you need this change?

Hi,
we have informational bin codes in the phys. Inventory recording which have no inventory. Therefore we have bin codes in the table "Phys. Invt. Record Line" but not in the table "Phys. Invt. Order Line". We have to prevent the testfield on Bin Code

Describe the request

We need an additional event in the table 5876 "Phys. Invt. Order Line" in the procedure TestQtyRecorded() to prevent the testfield on Bin Code.

    procedure TestQtyRecorded()
    var
        PhysInvtRecordLine: Record "Phys. Invt. Record Line";
        "Sum": Decimal;
        IsHandled: Boolean; //new
    begin
        Sum := 0;

        PhysInvtRecordLine.Reset();
        PhysInvtRecordLine.SetCurrentKey("Order No.", "Order Line No.");
        PhysInvtRecordLine.SetRange("Order No.", "Document No.");
        PhysInvtRecordLine.SetRange("Order Line No.", "Line No.");
        OnTestQtyRecordedOnAfterPhysInvtRecordLineSetFilters(Rec, PhysInvtRecordLine);
        if PhysInvtRecordLine.Find('-') then
            repeat
                PhysInvtRecordLine.TestField("Item No.", "Item No.");
                PhysInvtRecordLine.TestField("Variant Code", "Variant Code");
                PhysInvtRecordLine.TestField("Location Code", "Location Code");
                IsHandled := false;
                OnTestQtyRecordedOnBeforeTestFieldBinCode(Rec, PhysInvtRecordLine, IsHandled); //here new Event
                if not IsHandled then
                    PhysInvtRecordLine.TestField("Bin Code", "Bin Code");
                if "Use Item Tracking" then
                    if (PhysInvtRecordLine."Quantity (Base)" <> 0) and (not PhysInvtRecordLine.TrackingExists()) then
                        Error(
                            MustSpecifyTrackingErr, PhysInvtRecordLine."Recording No.",
                            StrSubstNo(IndenitiedValuesMsg, "Item No.", "Variant Code", "Location Code", "Bin Code"));
                Sum := Sum + PhysInvtRecordLine."Quantity (Base)";
            until PhysInvtRecordLine.Next() = 0;

        if "Qty. Recorded (Base)" <> Sum then
            Error(
                DifferentSumErr,
                StrSubstNo(IndenitiedValuesMsg, "Item No.", "Variant Code", "Location Code", "Bin Code"));
    end;

    [IntegrationEvent(false, false)]
    local procedure OnTestQtyRecordedOnBeforeTestFieldBinCode(var PhysInvtOrderLine: Record "Phys. Invt. Order Line"; var PhysInvtRecordLine: Record "Phys. Invt. Record Line"; var IsHandled: Boolean)
    begin
    end;

Internal work item: AB#612792

[AleksandricMarko]

Hello @KaMu0608

Recently we announced that for every new IsHandled event request, author need to provide a response to several question (please check link)

We want to be sure that IsHandled event is the only option, as this kind of events is not the best approach due to several reasons (codebase harder to maintain, harder refactoring, fragile solutions, easily break other implementations...)

Please also check the explanation about when and how to use IsHandled events (link)

[KaMu0608]

Thank you for your feedback, @AleksandricMarko. I understand your concerns about IsHandled events. Let me provide the required information per the minimum required guidelines.

Problem statement:
Our customers use informational bin codes in the phys. Inventory recording, so they can find the items more easily when counting the items.
These informational bins have no inventory.
Therefore we have bin codes in the table "Phys. Invt. Record Line" but not in the table "Phys. Invt. Order Line".
We have to skip the testfield on "Bin Code" (PhysInvtRecordLine.TestField("Bin Code", "Bin Code");)
This prevents us from finishing physical inventory orders when informational bins are involved.

Proposed code change:
As written above. The IsHandled parameter could be renamed to SkipTestFieldBinCode

Without this event, we're forced to copy and modify the entire Checkline() and TestQtyRecorded() funcions (fragile, high maintenance)

Alternatives evaluated:

• OnTestQtyRecordedOnAfterPhysInvtRecordLineSetFilters
  This event allows filtering which recording lines to validate, but doesn't help us skip the bin code validation itself. We still need to process these lines; we just need to conditionally skip the bin code test.

Justification for IsHandled:
The IsHandled parameter in the proposed code change could be renamed to SkipTestFieldBinCode.
The 4 testfield-statements could be moved to a new function like CheckPhysInvtRecordLine with an event, but still only the testfield for the "Bin Code " should be skipped.
Another option is a new function only for the line
PhysInvtRecordLine.TestField("Bin Code", "Bin Code");
That doesn’t feel right either.

Performance considerations:
The code is always executed when physical inventory recording is finished.
No additional locking is happening.

Data sensitivity review:
Only physical inventory lines are parameters.

Multi extension interaction:
It is only about skipping the testfield

Is this ok for you? Or do you need more information?
Thank you

[AleksandricMarko]

✅ Analysis complete - approved for implementation

---

Implementation:

Add a new integration event at the beginning of the loop in the TestQtyRecorded() procedure of Table 5876 "Phys. Invt. Order Line" to allow skipping bin code validation for informational bins.

Location in TestQtyRecorded() procedure (around line 701):

PhysInvtRecordLine.Reset();
PhysInvtRecordLine.SetCurrentKey("Order No.", "Order Line No.");
PhysInvtRecordLine.SetRange("Order No.", "Document No.");
PhysInvtRecordLine.SetRange("Order Line No.", "Line No.");
OnTestQtyRecordedOnAfterPhysInvtRecordLineSetFilters(Rec, PhysInvtRecordLine);
if PhysInvtRecordLine.Find('-') then
    repeat
        SkipTestFieldBinCode := false;
        OnTestQtyRecordedOnBeforeValidateRecordLine(Rec, PhysInvtRecordLine, SkipTestFieldBinCode);  // <-- New event
        PhysInvtRecordLine.TestField("Item No.", "Item No.");
        PhysInvtRecordLine.TestField("Variant Code", "Variant Code");
        PhysInvtRecordLine.TestField("Location Code", "Location Code");
        if not SkipTestFieldBinCode then
            PhysInvtRecordLine.TestField("Bin Code", "Bin Code");
        if "Use Item Tracking" then
            if (PhysInvtRecordLine."Quantity (Base)" <> 0) and (not PhysInvtRecordLine.TrackingExists()) then
                Error(
                    MustSpecifyTrackingErr, PhysInvtRecordLine."Recording No.",
                    StrSubstNo(IndenitiedValuesMsg, "Item No.", "Variant Code", "Location Code", "Bin Code"));
        Sum := Sum + PhysInvtRecordLine."Quantity (Base)";
    until PhysInvtRecordLine.Next() = 0;

Event Publisher (add at the end of the table with other events):

[IntegrationEvent(false, false)]
local procedure OnTestQtyRecordedOnBeforeValidateRecordLine(var PhysInvtOrderLine: Record "Phys. Invt. Order Line"; var PhysInvtRecordLine: Record "Phys. Invt. Record Line"; var SkipTestFieldBinCode: Boolean)
begin
end;

---

File: PhysInvtOrderLine.Table.al

[JesperSchulz]

Thanks for reporting this. We agree, and we’ll publish a fix asap, either in an update for the current version or in the next major release. Please do not reply to this, as we do not monitor closed issues. If you have follow-up questions or requests, please create a new issue where you reference this one.

Build ID: 43889.