macOS deployment target mismatch when using CMake with vcpkg toolchain

[Nika0000]

I'm using vcpkg with the CMake toolchain on macOS, and I'm getting a large number of linker warnings like:

ld: warning: object file (.../libcurl-d.a[157](sectransp.c.o)) was built for newer 'macOS' version (15.0) than being linked (13.3)

I'm targeting macOS 13.3, but some dependencies like libcurl seem to be built for macOS 15.0. I've tried several things but can’t get vcpkg to build these libraries with the correct deployment target.

Attempts to Fix

• Set CMAKE_OSX_DEPLOYMENT_TARGET=13.3 in my CMakeLists.txt
• Exported CMAKE_OSX_DEPLOYMENT_TARGET=13.3 before installing packages
• Set VCPKG_OSX_DEPLOYMENT_TARGET=13.3
• Passed -DCMAKE_OSX_DEPLOYMENT_TARGET=13.3 to both CMake and vcpkg install
• Using x64-osx triplet with default settings

Question
How can I make sure vcpkg builds all libraries (like libcurl) for the correct macOS deployment target (13.3 in my case)?

Is a custom triplet required, or is there a better way to enforce this globally for both vcpkg and CMake?

Thanks!

[ADKaster]

In my experience, if you have to ask "is a custom triplet required to do x", the answer is always yes.

In my project, I create a custom triplet, and have it load a build-time file, like so:

arm64-osx.cmake

set(VCPKG_CMAKE_SYSTEM_NAME Darwin)
set(VCPKG_TARGET_ARCHITECTURE arm64)
set(VCPKG_OSX_ARCHITECTURES arm64)
set(VCPKG_CRT_LINKAGE dynamic)
set(VCPKG_OSX_SYSROOT macosx)

include(${_VCPKG_INSTALLED_DIR}/../build-vcpkg-variables.cmake OPTIONAL)

And then generate that vcpkg variables file like this:

generate_vcpkg_toolchain_variables.cmake

set(EXTRA_VCPKG_VARIABLES "")
if (CMAKE_OSX_DEPLOYMENT_TARGET)
    string(APPEND EXTRA_VCPKG_VARIABLES "set(VCPKG_OSX_DEPLOYMENT_TARGET ${CMAKE_OSX_DEPLOYMENT_TARGET})\n")
endif()
# there's more goodies here in the real project

file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/build-vcpkg-variables.cmake" "${EXTRA_VCPKG_VARIABLES}")

Which is called when using vcpkg's toolchain file

cmake_minimum_required(VERSION 3.25)

# Pass additional information to vcpkg toolchain files if we are using vcpkg.
if (CMAKE_TOOLCHAIN_FILE MATCHES "vcpkg.cmake$")
    set(CMAKE_PROJECT_myproject_INCLUDE_BEFORE "cmake/generate_vcpkg_toolchain_variables.cmake")
endif()

project(myproject LANGUAGES C CXX)

[Nika0000]

Thanks a lot, it worked! You saved my life 😄