agent-belay/build.gradle.kts at main · mikepenz/agent-belay · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
plugins {
    alias(baseLibs.plugins.composeMultiplatform) apply false
    alias(baseLibs.plugins.composeCompiler) apply false
    alias(baseLibs.plugins.kotlinMultiplatform) apply false
    alias(baseLibs.plugins.kotlinSerialization) apply false
    alias(baseLibs.plugins.aboutLibraries) apply false
    alias(libs.plugins.nucleus) apply false
    alias(libs.plugins.versionCatalogUpdate)
}

versionCatalogUpdate {
    sortByKey.set(false)
    versionCatalogs {
        create("libs") {
            catalogFile.set(file("gradle/libs.versions.toml"))
        }
    }
    pin {
        versions.addAll("nucleus", "composenativetray")
    }
}

// Resolves every resolvable configuration across all projects (buildscript + project).
// Used to force Gradle to download every dependency so `--write-verification-metadata`
// captures host-independent checksums. Mirrors the approach used by the JetBrains/kotlin repo.
tasks.register("resolveDependencies") {
    doLast {
        rootProject.allprojects.forEach { p ->
            (p.buildscript.configurations + p.configurations)
                .filter { it.isCanBeResolved }
                .forEach { c ->
                    runCatching {
                        c.incoming.artifactView { isLenient = true }.files.files
                    }
                }
        }
    }
}