Merge pull request #108 from mirage/with_port_of_string

Add *.with_port_of_string functions

Author: dinosaure

lib/ipaddr.ml

@@ -172,6 +172,20 @@ module V4 = struct
 
   let of_string s = try_with_result of_string_exn s
 
+  let with_port_of_string ~default s =
+    try
+      let len = String.length s and o = ref 0 in
+      let ipv4 = of_string_raw s o in
+      if !o < len && s.[!o] = ':' then (
+        incr o;
+        let port = parse_dec_int s o in
+        expect_end s o;
+        Ok (ipv4, port))
+      else (
+        expect_end s o;
+        Ok (ipv4, default))
+    with Parse_error (msg, _) -> Error (`Msg ("Ipaddr: " ^ msg))
+
   let to_buffer b i =
     Printf.bprintf b "%ld.%ld.%ld.%ld" (i >! 24) (i >! 16) (i >! 8) (i >! 0)
 
@@ -626,6 +640,20 @@ module V6 = struct
 
   let of_string s = try_with_result of_string_exn s
 
+  let with_port_of_string ~default s =
+    let len = String.length s and o = ref 0 in
+    try
+      let ipv6 = of_string_raw s o in
+      if !o < len && s.[!o] = ':' then (
+        incr o;
+        let port = parse_dec_int s o in
+        expect_end s o;
+        Ok (ipv6, port))
+      else (
+        expect_end s o;
+        Ok (ipv6, default))
+    with Parse_error (msg, _) -> Error (`Msg ("Ipaddr: " ^ msg))
+
   (* http://tools.ietf.org/html/rfc5952 *)
   let to_buffer buf addr =
     let ((a, b, c, d, e, f, g, h) as comp) = to_int16 addr in
@@ -1013,6 +1041,20 @@ let of_string_exn s =
 
 let of_string s = try_with_result of_string_exn s
 
+let with_port_of_string ~default s =
+  let len = String.length s and o = ref 0 in
+  try
+    let ipv6 = of_string_raw s o in
+    if !o < len && s.[!o] = ':' then (
+      incr o;
+      let port = parse_dec_int s o in
+      expect_end s o;
+      Ok (ipv6, port))
+    else (
+      expect_end s o;
+      Ok (ipv6, default))
+  with Parse_error (msg, _) -> Error (`Msg ("Ipaddr: " ^ msg))
+
 let v6_of_v4 v4 =
   V6.(Prefix.(network_address ipv4_mapped (of_int32 (0l, 0l, 0l, v4))))
 

lib/ipaddr.mli

@@ -67,6 +67,12 @@ module V4 : sig
       an unspecified value during the function call. [s] will a {!Parse_error}
       exception if it is an invalid or truncated IP address. *)
 
+  val with_port_of_string :
+    default:int -> string -> (t * int, [> `Msg of string ]) result
+  (** [with_port_of_string ~default s] is the address {!t} represented by the
+      human-readble IPv4 address [s] with a possibly port [:<port>] (otherwise,
+      we take the [default] value). *)
+
   val to_string : t -> string
   (** [to_string ipv4] is the dotted decimal string representation of [ipv4],
       i.e. [XXX.XX.X.XXX]. *)
@@ -332,6 +338,16 @@ module V6 : sig
   (** Same as [of_string_exn] but returns an option type instead of raising an
       exception. *)
 
+  val with_port_of_string :
+    default:int -> string -> (t * int, [> `Msg of string ]) result
+  (** [with_port_of_string ~default ipv6_string] is the address represented by
+      [ipv6_string] with a possibly [:<port>] (otherwise, we take the [default]
+      value). Due to the [':'] separator, the user should expand [ipv6_string]
+      to let us to consider the last [:<port>] as a port. In other words:
+
+      - [::1:8080] returns the IPv6 [::1:8080] with the [default] port
+      - [0:0:0:0:0:0:0:1:8080] returns [::1] with the port [8080]. *)
+
   val of_string_raw : string -> int ref -> t
   (** Same as [of_string_exn] but takes as an extra argument the offset into the
       string for reading. *)
@@ -612,6 +628,16 @@ val of_string_raw : string -> int ref -> t
 (** Same as [of_string_exn] but takes as an extra argument the offset into the
     string for reading. *)
 
+val with_port_of_string :
+  default:int -> string -> (t * int, [> `Msg of string ]) result
+(** [with_port_of_string ~default s] parses [s] as an IPv4 or IPv6 address with
+    a possible port seperated by a [':'] (if not, we use [default]). For IPv6,
+    due to the [':'] separator, only a full expansion of the IPv6 plus the port
+    lets us to interpret the last [:<int>] as the port. In other words:
+
+    - [::1:8080] returns the IPv6 [::1:8080] with the [default] port
+    - [0:0:0:0:0:0:0:1:8080] returns [::1] with the port [8080]. *)
+
 val v4_of_v6 : V6.t -> V4.t option
 (** [v4_of_v6 ipv6] is the IPv4 representation of the IPv6 address [ipv6]. If
     [ipv6] is not an IPv4-mapped address, None is returned. *)

lib_test/test_ipaddr.ml

@@ -954,6 +954,59 @@ let test_string_raw_rt () =
       assert_equal ~msg (ts, !c) (result, cursor))
     addrs
 
+let test_with_port_of_string () =
+  let default = 8080 in
+  let addrs =
+    [
+      ("127.0.0.1", (Ipaddr.(V4 V4.localhost), default));
+      ("127.0.0.1:8080", (Ipaddr.(V4 V4.localhost), 8080));
+      ("127.0.0.1:4343", (Ipaddr.(V4 V4.localhost), 4343));
+      ("::1", (Ipaddr.(V6 V6.localhost), default));
+      ("0:0:0:0:0:0:0:1:8080", (Ipaddr.(V6 V6.localhost), 8080));
+      ("0:0:0:0:0:0:0:1:4343", (Ipaddr.(V6 V6.localhost), 4343));
+    ]
+  in
+  List.iter
+    (fun (inet_addr, result) ->
+      match Ipaddr.with_port_of_string ~default inet_addr with
+      | Ok ((V4 ipv4, port) as result') ->
+          let result'' = V4.with_port_of_string ~default inet_addr in
+          let msg =
+            Format.asprintf "%s <> %a:%d" inet_addr Ipaddr.V4.pp ipv4 port
+          in
+          assert_equal ~msg result result';
+          assert_equal ~msg (Ok (ipv4, port)) result''
+      | Ok ((V6 ipv6, port) as result') ->
+          let result'' = V6.with_port_of_string ~default inet_addr in
+          let msg =
+            Format.asprintf "%s <> %a:%d" inet_addr Ipaddr.V6.pp ipv6 port
+          in
+          assert_equal ~msg result result';
+          assert_equal ~msg (Ok (ipv6, port)) result''
+      | Error (`Msg err) ->
+          assert_failure (Format.asprintf "%s: %s" inet_addr err))
+    addrs
+
+let test_invalid_with_port_of_string () =
+  let default = 8080 in
+  let addrs =
+    [
+      "127.0.0.1:"; "127.0.0.1!8080"; "0:0:0:0:0:0:0:1!8080"; "0:0:0:0:0:0:0:1:";
+    ]
+  in
+  List.iter
+    (fun inet_addr ->
+      match
+        ( Ipaddr.with_port_of_string ~default inet_addr,
+          Ipaddr.V4.with_port_of_string ~default inet_addr,
+          Ipaddr.V4.with_port_of_string ~default inet_addr )
+      with
+      | Error _, Error _, Error _ -> ()
+      | _ ->
+          assert_failure
+            (Format.asprintf "Unexpected valid inet_addr: %S" inet_addr))
+    addrs
+
 let test_string_raw_rt_bad () =
   let error (s, c) msg c' = ((s, c), (Parse_error (msg, s), c')) in
   let addrs =
@@ -1052,6 +1105,8 @@ let suite =
          "map" >:: test_map;
          "prefix_mem" >:: test_prefix_mem;
          "prefix_subset" >:: test_prefix_subset;
+         "with_port" >:: test_with_port_of_string;
+         "invalid_with_port" >:: test_invalid_with_port_of_string;
        ]
 ;;