libkeyfinder/cmake/FindFFTW3.cmake at 2452ecd674ca52ab4b8efb32ef60544891dd431a · mixxxdj/libkeyfinder · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
#[=======================================================================[.rst:
FindFFTW3
--------

Finds the FFTW3 library.

Imported Targets
^^^^^^^^^^^^^^^^

This module provides the following imported targets, if found:

``FFTW3::fftw3``
  The FFTW3 library

Result Variables
^^^^^^^^^^^^^^^^

This will define the following variables:

``FFTW3_FOUND``
  True if the system has the FFTW3 library.
``FFTW3_INCLUDE_DIRS``
  Include directories needed to use FFTW3.
``FFTW3_LIBRARIES``
  Libraries needed to link to FFTW3.

Cache Variables
^^^^^^^^^^^^^^^

The following cache variables may also be set:

``FFTW3_INCLUDE_DIR``
  The directory containing ``fftw3.h``.
``FFTW3_LIBRARY``
  The path to the FFTW3 library.

#]=======================================================================]

find_path(FFTW3_INCLUDE_DIR
  NAMES fftw3.h
  DOC "FFTW3 include directory")
mark_as_advanced(FFTW3_INCLUDE_DIR)

find_library(FFTW3_LIBRARY
  NAMES fftw3 fftw-3.3
  DOC "FFTW3 library"
)
mark_as_advanced(FFTW3_LIBRARY)

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(
  FFTW3
  DEFAULT_MSG
  FFTW3_LIBRARY
  FFTW3_INCLUDE_DIR
)

if(FFTW3_FOUND)
  set(FFTW3_LIBRARIES "${FFTW3_LIBRARY}")
  set(FFTW3_INCLUDE_DIRS "${FFTW3_INCLUDE_DIR}")

  if(NOT TARGET FFTW3::fftw3)
    add_library(FFTW3::fftw3 UNKNOWN IMPORTED)
    set_target_properties(FFTW3::fftw3
      PROPERTIES
        IMPORTED_LOCATION "${FFTW3_LIBRARY}"
        INTERFACE_INCLUDE_DIRECTORIES "${FFTW3_INCLUDE_DIR}"
    )
  endif()
endif()