extract PipeWire cmake logic to FindPipeWire.cmake

Author: pri-yan-shu

CMakeLists.txt

@@ -3735,22 +3735,17 @@ target_include_directories(mixxx-lib SYSTEM PUBLIC lib/portaudio)
 target_link_libraries(mixxx-lib PRIVATE PortAudioRingBuffer)
 
 # PipeWire
-default_option(PIPEWIRE "Enable the PipeWire backend" "UNIX AND NOT APPLE")
+default_option(PIPEWIRE "Enable the PipeWire backend" "UNIX AND NOT APPLE AND NOT ANDROID")
 if(PIPEWIRE)
-  find_package(PkgConfig REQUIRED)
-  if(PKG_CONFIG_FOUND)
-    pkg_check_modules(PIPEWIRE REQUIRED IMPORTED_TARGET libpipewire-0.3)
-    if(PIPEWIRE_FOUND)
-      target_compile_definitions(mixxx-lib PUBLIC __PIPEWIRE__)
-      target_link_libraries(mixxx-lib PUBLIC PkgConfig::PIPEWIRE)
-      target_sources(
-        mixxx-lib
-        PRIVATE
-          src/soundio/pipewireenumerator.cpp
-          src/soundio/sounddevicepipewire.cpp
-      )
-    endif()
-  endif()
+  find_package(PipeWire REQUIRED)
+  target_link_libraries(mixxx-lib PUBLIC PipeWire::PipeWire)
+  target_compile_definitions(mixxx-lib PUBLIC __PIPEWIRE__)
+  target_sources(
+    mixxx-lib
+    PRIVATE
+      src/soundio/pipewireenumerator.cpp
+      src/soundio/sounddevicepipewire.cpp
+  )
 endif()
 
 # PortMidi

cmake/modules/FindPipeWire.cmake

@@ -0,0 +1,42 @@
+#[=======================================================================[.rst:
+FindPipeWire
+--------
+
+Finds the PipeWire library.
+
+Imported Targets
+^^^^^^^^^^^^^^^^
+
+This module provides the following imported targets, if found:
+
+``PipeWire::PipeWire``
+  The PipeWire library
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This will define the following variables:
+
+``PipeWire_FOUND``
+  True if the system has the PipeWire library.
+
+#]=======================================================================]
+
+find_package(PkgConfig REQUIRED)
+pkg_check_modules(PIPEWIRE REQUIRED IMPORTED_TARGET libpipewire-0.3)
+
+include(FindPackageHandleStandardArgs)
+
+find_package_handle_standard_args(
+  PipeWire
+  REQUIRED_VARS PIPEWIRE_FOUND
+  VERSION_VAR PIPEWIRE_VERSION
+)
+
+if(PipeWire_FOUND AND NOT TARGET PipeWire::PipeWire)
+  add_library(PipeWire::PipeWire INTERFACE IMPORTED)
+  set_target_properties(
+    PipeWire::PipeWire
+    PROPERTIES INTERFACE_LINK_LIBRARIES PkgConfig::PIPEWIRE
+  )
+endif()