terraform-hcloud-kubernetes/talos_config_bare_metal.tf at main · mlinares1998/terraform-hcloud-kubernetes · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
locals {
  # Bare Metal Network Config
  bare_metal_vswitch_link_name             = "${local.talos_public_link_name}.${local.hcloud_vswitch_vlan_id}"
  bare_metal_vswitch_ipv4_cidr_prefix_size = split("/", local.network_bare_metal_shared_ipv4_cidr)[1]
  bare_metal_vswitch_ipv4_netmask          = cidrnetmask(local.network_bare_metal_shared_ipv4_cidr)
  bare_metal_vswitch_ipv4_gateway          = cidrhost(local.network_bare_metal_shared_ipv4_cidr, 1)
  bare_metal_extra_routes = [
    for route in local.talos_extra_routes : merge(route, {
      gateway = local.bare_metal_vswitch_ipv4_gateway
    })
  ]

  bare_metal_public_ipv6_enabled = {
    for server_name in keys(local.bare_metal_servers) :
    server_name => local.network_public_ipv6_enabled && local.bare_metal_server_public_network[server_name].server_ipv6_net != ""
  }

  bare_metal_public_ipv6_addresses = {
    for server_name in keys(local.bare_metal_servers) :
    server_name => local.bare_metal_public_ipv6_enabled[server_name] ? cidrhost(
      format("%s/64", local.bare_metal_server_public_network[server_name].server_ipv6_net),
      1
    ) : null
  }

  bare_metal_talos_config_patches = {
    for server_name, server in local.bare_metal_servers : server_name => [
      {
        apiVersion = "v1alpha1"
        kind       = "LinkConfig"
        name       = local.talos_public_link_name
        up         = true
        addresses = concat(
          local.network_public_ipv4_enabled ? [
            {
              address = "${local.bare_metal_server_public_network[server_name].server_ipv4}/${local.bare_metal_server_public_network[server_name].server_ipv4_mask}"
            }
          ] : [],
          local.bare_metal_public_ipv6_enabled[server_name] ? [
            {
              address = "${local.bare_metal_public_ipv6_addresses[server_name]}/64"
            }
          ] : []
        )
        routes = concat(
          local.network_public_ipv4_enabled ? [
            {
              gateway = local.bare_metal_server_public_network[server_name].server_ipv4_gateway
            }
          ] : [],
          local.bare_metal_public_ipv6_enabled[server_name] ? [
            {
              gateway = "fe80::1"
            }
          ] : []
        )
      },
      {
        apiVersion = "v1alpha1"
        kind       = "VLANConfig"
        name       = local.bare_metal_vswitch_link_name
        parent     = local.talos_public_link_name
        vlanID     = local.hcloud_vswitch_vlan_id
        mtu        = 1400
        addresses = [
          {
            address = "${server.private_ipv4}/${local.bare_metal_vswitch_ipv4_cidr_prefix_size}"
          }
        ]
        routes = concat(
          [
            {
              destination = local.network_ipv4_cidr
              gateway     = local.bare_metal_vswitch_ipv4_gateway
              metric      = 512
            }
          ],
          local.bare_metal_extra_routes
        )
      },
      {
        machine = {
          nodeLabels = merge(
            local.bare_metal_nodepools_map[server.nodepool].labels,
            {
              "nodeid"                             = tostring(server.number),
              "instance.hetzner.cloud/provided-by" = "robot"
            }
          )
          nodeAnnotations = local.bare_metal_nodepools_map[server.nodepool].annotations
          kubelet = {
            extraArgs = {
              "provider-id" = "hrobot://${server.number}"
            }
            extraConfig = merge(
              {
                registerWithTaints = local.bare_metal_nodepools_map[server.nodepool].taints
                systemReserved = {
                  cpu               = "100m"
                  memory            = "300Mi"
                  ephemeral-storage = "1Gi"
                }
                kubeReserved = {
                  cpu               = "100m"
                  memory            = "350Mi"
                  ephemeral-storage = "1Gi"
                }
              },
              var.kubernetes_kubelet_extra_config
            )
          }
        }
      },
      {
        apiVersion = "v1alpha1"
        kind       = "HostnameConfig"
        hostname   = server.name
        auto       = "off"
      }
    ]
  }
}

data "talos_machine_configuration" "bare_metal" {
  for_each = local.bare_metal_servers

  talos_version      = var.talos_version
  cluster_name       = var.cluster_name
  cluster_endpoint   = local.kube_api_url_internal
  kubernetes_version = var.kubernetes_version
  machine_type       = "worker"
  machine_secrets    = talos_machine_secrets.this.machine_secrets
  docs               = false
  examples           = false

  config_patches = concat(
    [for patch in local.talos_common_config_patches : yamlencode(patch)],
    [for patch in local.bare_metal_talos_config_patches[each.key] : yamlencode(patch)],
    [for patch in var.bare_metal_config_patches : yamlencode(patch)]
  )
}