SockExchange/build.gradle.kts at master · mythicmc/SockExchange · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

plugins {
    java
    `maven-publish`
    id("com.gradleup.shadow") version "9.2.2"
    id("net.kyori.blossom") version "2.2.0"
    id("org.jetbrains.gradle.plugin.idea-ext") version "1.3" // IntelliJ + Blossom integration
}

group = "com.gmail.tracebachi"
version = "1.1.2"

repositories {
    mavenCentral()
    maven(url = "https://oss.sonatype.org/content/repositories/snapshots")
    maven(url = "https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
    maven(url = "https://nexus.velocitypowered.com/repository/maven-public/")
}

dependencies {
    compileOnly("io.netty:netty-all:4.0.23.Final")
    compileOnly("net.md-5:bungeecord-api:1.21-R0.3")
    compileOnly("org.spigotmc:spigot-api:1.13.2-R0.1-SNAPSHOT")
    compileOnly("com.velocitypowered:velocity-api:3.0.1")
    annotationProcessor("com.velocitypowered:velocity-api:3.0.1")
}

java {
    withJavadocJar()
    withSourcesJar()
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(8))
    }
}

sourceSets {
    main {
        blossom {
            resources {
                property("version", project.version.toString())
                property("description", project.description ?: "")
            }
            javaSources {
                property("version", project.version.toString())
                property("description", project.description ?: "")
            }
        }
    }
}

tasks.getByName<ShadowJar>("shadowJar") {
    minimize()
}

publishing {
    repositories {
        maven {
            name = "mythicmcReleases"
            url = uri("https://maven.mythicmc.org/releases")
            credentials(PasswordCredentials::class)
            authentication {
                create<BasicAuthentication>("basic")
            }
        }
    }
    publications {
        create<MavenPublication>("maven") {
            groupId = "com.gmail.tracebachi"
            artifactId = "sockexchange"
            version = project.version.toString()
            from(components["java"])
            pom {
                name = project.name
                description = project.description
                url = "https://github.com/mythicmc/SockExchange"
                // properties = mapOf("myProp" to "value", "prop.with.dots" to "anotherValue")
                licenses {
                    license {
                        name = "GPL-3.0-only"
                        url = "https://spdx.org/licenses/GPL-3.0-only.html"
                    }
                }
                developers {
                    developer {
                        id = "GeeItsZee"
                        email = "tracebachi@gmail.com"
                    }
                    developer {
                        id = "retrixe"
                        name = "Ibrahim Ansari"
                        email = "ibu2@mythicmc.org"
                    }
                }
                scm {
                    connection = "scm:git:git://github.com/mythicmc/SockExchange.git"
                    developerConnection = "scm:git:ssh://github.com/mythicmc/SockExchange.git"
                    url = "https://github.com/mythicmc/SockExchange/"
                }
            }
        }
    }
}