Added challan service provider

Author: Ritankar Bose

lib/mobility-core/mobility-core.cabal

@@ -69,6 +69,13 @@ library
       Kernel.External.Call.TataClickToCall.Types
       Kernel.External.Call.Twillio.Config
       Kernel.External.Call.Types
+      Kernel.External.ChallanSearch.Interface
+      Kernel.External.ChallanSearch.Interface.Signzy
+      Kernel.External.ChallanSearch.Interface.Types
+      Kernel.External.ChallanSearch.Signzy.API
+      Kernel.External.ChallanSearch.Signzy.Config
+      Kernel.External.ChallanSearch.Signzy.Types
+      Kernel.External.ChallanSearch.Types
       Kernel.External.Encryption
       Kernel.External.EventTracking
       Kernel.External.EventTracking.Interface

lib/mobility-core/src/Kernel/External/ChallanSearch/Interface.hs

@@ -0,0 +1,16 @@
+module Kernel.External.ChallanSearch.Interface
+  ( module Kernel.External.ChallanSearch.Interface,
+    module Reexport,
+  )
+where
+
+import Kernel.External.ChallanSearch.Interface.Signzy as CIS
+import Kernel.External.ChallanSearch.Interface.Types as Reexport
+import Kernel.Prelude
+import Kernel.Tools.Metrics.CoreMetrics (CoreMetrics)
+import Kernel.Types.Common
+import Kernel.Utils.Servant.Client
+
+getPendingChallanCount :: (EncFlow m r, CoreMetrics m, Log m, HasRequestId r, MonadReader r m) => ChallanSearchServiceConfig -> PendingChallanReq -> m PendingChallanResp
+getPendingChallanCount serviceConfig req = case serviceConfig of
+  SignzyChallanSearch cfg -> CIS.signzyChallanSearch cfg req

lib/mobility-core/src/Kernel/External/ChallanSearch/Interface/Signzy.hs

@@ -0,0 +1,25 @@
+module Kernel.External.ChallanSearch.Interface.Signzy (signzyChallanSearch) where
+
+import qualified Data.Text as T
+import Kernel.External.ChallanSearch.Interface.Types as CIT
+import Kernel.External.ChallanSearch.Signzy.API as CSA
+import Kernel.External.ChallanSearch.Signzy.Config as CSC
+import Kernel.External.ChallanSearch.Signzy.Types as CST
+import Kernel.External.Encryption
+import Kernel.Prelude
+import Kernel.Tools.Metrics.CoreMetrics (CoreMetrics)
+import Kernel.Types.Common
+import Kernel.Utils.Logging (logInfo)
+import Kernel.Utils.Servant.Client
+
+signzyChallanSearch :: (EncFlow m r, CoreMetrics m, Log m, HasRequestId r, MonadReader r m) => CSC.SignzyChallanSearchCfg -> CIT.PendingChallanReq -> m CIT.PendingChallanResp
+signzyChallanSearch cfg req = do
+  apiKey <- decrypt cfg.apiKey
+  let signzyReq = CST.ChallanSearchReq {vehicleNumber = req.vehicleNumber, paymentCheck = True}
+  signzyResp <- CSA.challanSearch cfg.url apiKey signzyReq
+  let pendingChallans = filter isPending signzyResp.result.challanDetails
+  logInfo $ "Signzy challan search for " <> req.vehicleNumber <> ": found " <> show (length pendingChallans) <> " pending out of " <> show (length signzyResp.result.challanDetails) <> " total challans"
+  pure $ CIT.PendingChallanResp {pendingChallanCount = length pendingChallans}
+  where
+    isPending :: CST.ChallanDetail -> Bool
+    isPending detail = T.toLower detail.challanStatus == "pending"

lib/mobility-core/src/Kernel/External/ChallanSearch/Interface/Types.hs

@@ -0,0 +1,20 @@
+module Kernel.External.ChallanSearch.Interface.Types
+  ( module Kernel.External.ChallanSearch.Interface.Types,
+  )
+where
+
+import Kernel.External.ChallanSearch.Signzy.Config as Signzy
+import Kernel.Prelude
+
+data ChallanSearchServiceConfig = SignzyChallanSearch Signzy.SignzyChallanSearchCfg
+  deriving (Show, Eq, Generic, FromJSON, ToJSON)
+
+newtype PendingChallanReq = PendingChallanReq
+  { vehicleNumber :: Text
+  }
+  deriving (Show, Generic, ToJSON, FromJSON)
+
+newtype PendingChallanResp = PendingChallanResp
+  { pendingChallanCount :: Int
+  }
+  deriving (Show, Generic, ToJSON, FromJSON)

lib/mobility-core/src/Kernel/External/ChallanSearch/Signzy/API.hs

@@ -0,0 +1,24 @@
+module Kernel.External.ChallanSearch.Signzy.API where
+
+import EulerHS.Types (EulerClient, client)
+import Kernel.External.ChallanSearch.Signzy.Types as CST
+import Kernel.Prelude
+import Kernel.Tools.Metrics.CoreMetrics (CoreMetrics)
+import Kernel.Types.Common
+import Kernel.Types.Error
+import Kernel.Utils.Common
+import Servant hiding (throwError)
+
+type SignzyChallanSearchAPI =
+  "api" :> "v3" :> "vehicle" :> "challan-search"
+    :> Header "Authorization" Text
+    :> ReqBody '[JSON] CST.ChallanSearchReq
+    :> Post '[JSON] CST.ChallanSearchResp
+
+challanSearchClient :: Maybe Text -> CST.ChallanSearchReq -> EulerClient CST.ChallanSearchResp
+challanSearchClient = client (Proxy :: Proxy SignzyChallanSearchAPI)
+
+challanSearch :: (CoreMetrics m, MonadFlow m, Log m, HasRequestId r, MonadReader r m) => BaseUrl -> Text -> CST.ChallanSearchReq -> m CST.ChallanSearchResp
+challanSearch url apiKey req = do
+  callAPI url (challanSearchClient (Just apiKey) req) "signzyChallanSearch" (Proxy :: Proxy SignzyChallanSearchAPI)
+    >>= fromEitherM (ExternalAPICallError (Just "SIGNZY_CHALLAN_SEARCH_ERROR") url)

lib/mobility-core/src/Kernel/External/ChallanSearch/Signzy/Config.hs

@@ -0,0 +1,10 @@
+module Kernel.External.ChallanSearch.Signzy.Config where
+
+import Kernel.External.Encryption
+import Kernel.Prelude
+
+data SignzyChallanSearchCfg = SignzyChallanSearchCfg
+  { url :: BaseUrl,
+    apiKey :: EncryptedField 'AsEncrypted Text
+  }
+  deriving (Show, Eq, Generic, ToJSON, FromJSON)

lib/mobility-core/src/Kernel/External/ChallanSearch/Signzy/Types.hs

@@ -0,0 +1,34 @@
+module Kernel.External.ChallanSearch.Signzy.Types where
+
+import Kernel.Prelude
+
+data ChallanSearchReq = ChallanSearchReq
+  { vehicleNumber :: Text,
+    paymentCheck :: Bool
+  }
+  deriving (Show, Generic, ToJSON, FromJSON)
+
+newtype ChallanSearchResp = ChallanSearchResp
+  { result :: ChallanSearchResult
+  }
+  deriving (Show, Generic, ToJSON, FromJSON)
+
+data ChallanSearchResult = ChallanSearchResult
+  { regNo :: Text,
+    message :: Text,
+    status_code :: Int,
+    challanDetails :: [ChallanDetail],
+    successfulSources :: [Text],
+    failedSources :: [Text]
+  }
+  deriving (Show, Generic, ToJSON, FromJSON)
+
+data ChallanDetail = ChallanDetail
+  { number :: Int,
+    challanNumber :: Text,
+    rto :: Text,
+    accusedName :: Text,
+    amount :: Text,
+    challanStatus :: Text
+  }
+  deriving (Show, Generic, ToJSON, FromJSON)

lib/mobility-core/src/Kernel/External/ChallanSearch/Types.hs

@@ -0,0 +1,15 @@
+{-# LANGUAGE TemplateHaskell #-}
+
+module Kernel.External.ChallanSearch.Types
+  ( module Kernel.External.ChallanSearch.Types,
+  )
+where
+
+import Data.OpenApi hiding (email)
+import EulerHS.Prelude
+import Kernel.Beam.Lib.UtilsTH (mkBeamInstancesForEnumAndList)
+
+data ChallanSearchService = Signzy
+  deriving (Show, Read, Eq, Ord, Generic, ToJSON, FromJSON, ToSchema, ToParamSchema)
+
+$(mkBeamInstancesForEnumAndList ''ChallanSearchService)