snowblower/build.gradle at main · neoforged/snowblower · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
import net.neoforged.snowblower.gradle.DependencyHashingTask
import net.neoforged.snowblower.gradle.ShadowJarFixupTask
import net.neoforged.gradleutils.PomUtilsExtension.License

plugins {
    id 'java'
    id 'maven-publish'
    id 'eclipse'
    id 'idea'
    id 'net.neoforged.licenser' version '0.7.5'
    id 'com.gradleup.shadow' version '9.4.1'
    id 'net.neoforged.gradleutils' version '5.1.1'
}

group = 'net.neoforged'
base {
    archivesName.set('snowblower')
}
gradleutils {
    setupSigning()
}

version = gradleutils.version.toString()
println "Version: $version"

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(25)
    }
}

repositories {
    mavenCentral()
    maven gradleutils.maven
}

configurations {
    shade
    implementation.extendsFrom shade
}

dependencies {
    compileOnly 'org.jetbrains:annotations:26.0.2'

    // When updating shade dependencies, you must also run the generateDependencyHashes task
    shade 'org.slf4j:slf4j-api:2.0.17'
    shade 'ch.qos.logback:logback-classic:1.5.18'
    shade 'org.eclipse.jgit:org.eclipse.jgit:7.2.0.202503040940-r'
    shade 'net.sf.jopt-simple:jopt-simple:6.0-alpha-3'
    shade 'com.google.code.gson:gson:2.12.1'
    shade 'net.neoforged:srgutils:1.0.10'
    shade 'org.vineflower:vineflower:1.12.0'
    shade 'net.neoforged:vineflower-plugins:0.1.6'
    shade 'net.neoforged.installertools:installertools:4.0.13'
    shade 'net.neoforged:mergetool:2.0.7'

    shade 'org.bouncycastle:bcpkix-jdk18on:1.80'
    shade 'com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.18.3'

    shade 'io.jsonwebtoken:jjwt-api:0.12.6'
    shade 'io.jsonwebtoken:jjwt-impl:0.12.6'
    shade 'io.jsonwebtoken:jjwt-jackson:0.12.6'
    shade 'org.kohsuke:github-api:1.327'
}

tasks.register('generateDependencyHashes', DependencyHashingTask) {
    configuration = configurations.shade
    output = file('src/main/generated_resources/dependency_hashes.txt')
}

tasks.register('shadowJarFixup', ShadowJarFixupTask) {
    outputs.upToDateWhen { false }
    input = shadowJar.archiveFile
    output = shadowJar.archiveFile
}

afterEvaluate {
    tasks.named('generateMetadataFileForMavenJavaPublication').configure {
        dependsOn 'shadowJarFixup'
    }
}

sourceSets {
    main {
        resources {
            srcDirs += file('src/main/generated_resources')
        }
    }
}

tasks.named('processResources', ProcessResources).configure {
    dependsOn 'generateDependencyHashes'
    from 'gradlew'
    from 'gradlew.bat'
}

tasks.named('eclipseClasspath', GenerateEclipseClasspath).configure {
    dependsOn 'generateDependencyHashes'
}

tasks.named('idea').configure {
    dependsOn 'generateDependencyHashes'
}

tasks.named('jar', Jar).configure {
    from('gradle/wrapper') {
        into 'gradle/wrapper'
    }
    manifest {
        attributes([
            'Main-Class': 'net.neoforged.snowblower.Main',
            'Implementation-Version': "${project.version} (${gradleutils.gitInfo.commit})"
        ])
    }
}

tasks.named('shadowJar', ShadowJar).configure {
    archiveClassifier = 'all'
    configurations = [project.configurations.shade]

    from('gradle/wrapper') {
        into 'gradle/wrapper'
        rename '(.+).jar', '$1.zip'
    }

    finalizedBy 'shadowJarFixup'
}

changelog {
    from '2.0'
}

license {
    header = file('LICENSE-header.txt')
    newLine = false
    exclude '**/*.properties'
    exclude '**/*.xml'
    skipExistingHeaders true
}

test {
    enabled = false
}

publishing {
    publications.register('mavenJava', MavenPublication) {
        from components.java
        artifactId = 'snowblower'
        gradleutils.sign(it)

        pom {
            name = 'Snowblower'
            description = 'A utility to create a git repository of Minecraft decompiled code to make it easier to see what changed between minecraft versions.'
            pomUtils.githubRepo(it, 'snowblower')
            pomUtils.license(it, License.MIT)
        }
    }

    repositories {
        maven gradleutils.publishingMaven
    }
}