Home-Assistant-Companion-for-Android/settings.gradle.kts at master · nesror/Home-Assistant-Companion-for-Android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
include(":common", ":app", ":testing-unit", ":lint")

rootProject.name = "home-assistant-android"

pluginManagement {
    includeBuild("build-logic")
    repositories {
        google {
            content {
                includeGroupByRegex("com\\.android.*")
                includeGroupByRegex("com\\.google.*")
                includeGroupByRegex("androidx.*")
            }
        }
        mavenCentral()
        gradlePluginPortal()
    }
}

plugins {
    // So we can't reach the libs.plugins.* aliases from here so we need to declare them the old way...
    id("org.ajoberstar.reckon.settings").version("0.19.2")
}

reckon {
    val isCiBuild = providers.environmentVariable("CI").isPresent

    setDefaultInferredScope("patch")
    if (!isCiBuild) {
        // Use a snapshot version scheme with Reckon when not running in CI, which allows caching to
        // improve performance. Background: https://github.com/home-assistant/android/issues/5220.
        snapshots()
    } else {
        stages("beta", "final")
    }
    setScopeCalc { java.util.Optional.of(org.ajoberstar.reckon.core.Scope.PATCH) }
    setStageCalc(calcStageFromProp())
    setTagWriter { it.toString() }
}


dependencyResolutionManagement {
    repositoriesMode = RepositoriesMode.FAIL_ON_PROJECT_REPOS
    repositories {
        google {
            content {
                includeGroupByRegex("com\\.android.*")
                includeGroupByRegex("com\\.google.*")
                includeGroupByRegex("androidx.*")
                includeGroupByRegex("org\\.chromium.*")
            }
        }
        mavenCentral()
        google()
        maven("https://jitpack.io")
    }
}


//typesafeConventions {
//    allowTopLevelBuild = true
//}