meta-nilrt/recipes-bsp/grub/grub-efi_2.%.bbappend at 154e4c06fc1dd49859d0a62912d41c9b5678552f · ni/meta-nilrt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
require grub-nilrt.inc

GRUB_BUILDIN:append = " \
    ata \
    btrfs \
    chain \
    echo \
    efi_uga \
    font \
    gfxmenu \
    gfxterm \
    help \
    iorw \
    loopback \
    ls \
    lvm \
    memdisk \
    minicmd \
    multiboot \
    ntfs \
    probe \
    reboot \
    regexp \
    reiserfs \
    search_fs_uuid \
    serial \
    smbios \
    tar \
    terminal \
    terminfo \
    tpm \
    udf \
    xfs \
"

PACKAGES:prepend = "${PN}-nilrt "

do_install:append:class-target() {

    # Build NILRT grub image with prefix=\efi\nilrt instead of
    # the default \EFI\BOOT. We keep the upstream grub image
    # unchanged so that we may use it with USB provisioning tool
    # and other removable storage.
    (
        cd "${B}"
        grub-mkimage \
            --prefix=/efi/nilrt \
            --directory=./grub-core/ \
            --format=${GRUB_TARGET}-efi \
            --output=./${GRUB_IMAGE_PREFIX}nilrt-${GRUB_IMAGE} \
            ${GRUB_BUILDIN}
    )

    # Install NILRT grub image
    install -d ${D}/boot/efi/nilrt
    install -m 644 ${B}/${GRUB_IMAGE_PREFIX}nilrt-${GRUB_IMAGE} ${D}/boot/efi/nilrt/${GRUB_IMAGE}
}

FILES:${PN}-nilrt = "/boot/efi/nilrt/${GRUB_IMAGE}"