wiremix: add module

Author: rachitvrma

modules/misc/news/2026/05/2026-05-08_17-37-08.nix

@@ -0,0 +1,10 @@
+{ pkgs, ... }:
+{
+  time = "2026-05-08T12:07:08+00:00";
+  condition = pkgs.stdenv.hostPlatform.isLinux;
+  message = ''
+    A new module is available `programs.wiremix`
+
+    A simple TUI mixer for PipeWire.
+  '';
+}

modules/programs/wiremix.nix

@@ -0,0 +1,63 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  inherit (lib)
+    hm
+    mkIf
+    mkEnableOption
+    mkOption
+    mkPackageOption
+    platforms
+    ;
+
+  cfg = config.programs.wiremix;
+  tomlFormat = pkgs.formats.toml { };
+in
+{
+  meta.maintainers = [ hm.maintainers.rachitvrma ];
+
+  options.programs.wiremix = {
+    enable = mkEnableOption "wiremix";
+
+    package = mkPackageOption pkgs "wiremix" { nullable = true; };
+
+    settings = mkOption {
+      inherit (tomlFormat) type;
+
+      default = { };
+
+      example = lib.literalExpression ''
+        {
+          mouse = false;
+          peaks = "auto";
+          theme = "default";
+          max_volume_percent = 100.0;
+        }
+      '';
+
+      description = ''
+        Configuration written to
+        {file}`$XDG_CONFIG_HOME/wiremix/wiremix.toml`
+
+        See <https://github.com/tsowell/wiremix#configuration> for more
+        information.
+      '';
+    };
+
+  };
+  config = mkIf cfg.enable {
+    assertions = [
+      (hm.assertions.assertPlatform "programs.wiremix" pkgs platforms.linux)
+    ];
+
+    home.packages = mkIf (cfg.package != null) [ cfg.package ];
+
+    xdg.configFile."wiremix/wiremix.toml" = mkIf (cfg.settings != { }) {
+      source = tomlFormat.generate "hm_wiremix.toml" cfg.settings;
+    };
+  };
+}

tests/modules/programs/wiremix/default.nix

@@ -0,0 +1,4 @@
+{ lib, pkgs, ... }:
+lib.optionalAttrs pkgs.stdenv.hostPlatform.isLinux {
+  wiremix = ./wiremix.nix;
+}

tests/modules/programs/wiremix/expected.toml

@@ -0,0 +1,4 @@
+max_volume_percent = 100.0
+mouse = false
+peaks = "auto"
+theme = "default"

tests/modules/programs/wiremix/wiremix.nix

@@ -0,0 +1,16 @@
+{
+  programs.wiremix = {
+    enable = true;
+    settings = {
+      mouse = false;
+      peaks = "auto";
+      theme = "default";
+      max_volume_percent = 100.0;
+    };
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.config/wiremix/wiremix.toml
+    assertFileContent home-files/.config/wiremix/wiremix.toml ${./expected.toml}
+  '';
+}