flake-edit: init

Author: Malix-Labs

modules/misc/news/2026/07/2026-07-25_16-39-10.nix

@@ -0,0 +1,8 @@
+{
+  time = "2026-07-25T14:39:10+00:00";
+  condition = true;
+  message = ''
+    A new module is available: 'programs.flake-edit',
+    featuring a '.settings' option to generate {file}`$XDG_CONFIG_HOME/flake-edit/config.toml`
+  '';
+}

modules/programs/flake-edit.nix

@@ -0,0 +1,55 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  name = "flake-edit";
+  cfg = config.programs.${name};
+  tomlFormat = pkgs.formats.toml { };
+  configFile = "config.toml";
+  configDir =
+    if pkgs.stdenv.hostPlatform.isDarwin then "Library/Application Support" else config.xdg.configHome;
+  configPath = "${name}/${configFile}";
+in
+{
+  meta.maintainers = with lib.maintainers; [ malix ];
+
+  options.programs.${name} = {
+    enable = lib.mkEnableOption name;
+
+    package = lib.mkPackageOption pkgs name { nullable = true; };
+
+    settings = lib.mkOption {
+      inherit (tomlFormat) type;
+      default = { };
+      example = {
+        follow = {
+          ignore = [
+            "systems"
+            "crane.flake-utils"
+          ];
+          transitive_min = 2;
+          aliases = {
+            nixpkgs = [ "nixpkgs-lib" ];
+          };
+          max_depth = 1;
+        };
+      };
+      description = ''
+        Configuration written to {file}`$XDG_CONFIG_HOME/${configPath}` on Linux or
+        {file}`$HOME/Library/Application Support/${configPath}` on Darwin.
+        See <https://github.com/a-kenji/${name}#configuration> for documentation.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
+
+    home.file."${configDir}/${configPath}" = lib.mkIf (cfg.settings != { }) {
+      source = tomlFormat.generate configFile cfg.settings;
+    };
+  };
+}

tests/modules/programs/flake-edit/default.nix

@@ -0,0 +1,44 @@
+{
+  flake-edit-basic-settings =
+    {
+      lib,
+      pkgs,
+      ...
+    }:
+    let
+      configDir = if pkgs.stdenv.hostPlatform.isDarwin then "Library/Application Support" else ".config";
+      configFile = "home-files/${configDir}/flake-edit/config.toml";
+    in
+    {
+      programs.flake-edit = {
+        enable = true;
+        settings = {
+          follow = {
+            ignore = [
+              "systems"
+              "crane.flake-utils"
+            ];
+            transitive_min = 2;
+            aliases = {
+              nixpkgs = [ "nixpkgs-lib" ];
+            };
+            max_depth = 1;
+          };
+        };
+      };
+
+      nmt.script = ''
+        assertFileExists ${lib.escapeShellArg configFile}
+        assertFileContent ${lib.escapeShellArg configFile} \
+          ${pkgs.writeText "flake-edit-expected.toml" ''
+            [follow]
+            ignore = ["systems", "crane.flake-utils"]
+            max_depth = 1
+            transitive_min = 2
+
+            [follow.aliases]
+            nixpkgs = ["nixpkgs-lib"]
+          ''}
+      '';
+    };
+}