dprint: add module

Author: Rachit Kumar Verma

modules/misc/news/2026/04/2026-04-14_14-50-21.nix

@@ -0,0 +1,11 @@
+{
+  time = "2026-04-14T09:20:21+00:00";
+  condition = true;
+  message = ''
+    A new module is available: 'programs.dprint'.
+
+    dprint is a code formatter written in rust.
+    It allows formatting toml, markdown, yaml, and many other filetypes.
+    See https://dprint.dev/ for more.
+  '';
+}

modules/programs/dprint.nix

@@ -0,0 +1,52 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}:
+let
+  inherit (lib) mkIf mkOption;
+  cfg = config.programs.dprint;
+  jsonFormat = pkgs.formats.json { };
+in
+{
+  meta.maintainers = [ lib.maintainers.rachitvrma ];
+  options.programs.dprint = {
+    enable = lib.mkEnableOption ''
+      dprint: a code formatter for common filetypes like markdown, toml, yaml,
+      and many more. See https://dprint.dev/
+    '';
+    package = lib.mkPackageOption pkgs "dprint" { nullable = true; };
+    settings = mkOption {
+      inherit (jsonFormat) type;
+      default = { };
+      description = ''
+        Settings to add to {file}`$XDG_CONFIG_HOME/dprint/dprint.json`.
+      '';
+      example = lib.literalExpression ''
+        {
+          excludes = [
+            "**/node_modules"
+            "**/*-lock.json"
+          ];
+          plugins = [
+            "https://plugins.dprint.dev/typescript-0.96.1.wasm"
+            "''${pkgs.dprint-plugins.g-plane-pretty_yaml}/plugin.wasm"
+          ];
+          json = { };
+          malva = { };
+          markdown = { };
+          toml = { };
+          typescript = { };
+          yaml = { };
+        }
+      '';
+    };
+  };
+  config = mkIf cfg.enable {
+    home.packages = lib.mkIf (cfg.package != null) [ cfg.package ];
+    xdg.configFile."dprint/dprint.json" = mkIf (cfg.settings != { }) {
+      source = jsonFormat.generate "hm_dprintdprint.json" cfg.settings;
+    };
+  };
+}

tests/modules/programs/dprint/default.nix

@@ -0,0 +1,4 @@
+{
+  dprint-example-settings = ./example-dprint.nix;
+  dprint-empty-settings = ./empty-dprint.nix;
+}

tests/modules/programs/dprint/empty-dprint.nix

@@ -0,0 +1,6 @@
+{
+  programs.dprint.enable = true;
+  nmt.script = ''
+    assertPathNotExists home-files/.config/dprint
+  '';
+}

tests/modules/programs/dprint/example-dprint.nix

@@ -0,0 +1,26 @@
+{
+  programs.dprint = {
+    enable = true;
+    settings = {
+      excludes = [ "**/*-lock.json" ];
+      json = {
+        indentWidth = 2;
+      };
+      lineWidth = 80;
+      plugins = [
+        "https://plugins.dprint.dev/typescript-0.96.1.wasm"
+        "https://plugins.dprint.dev/json-0.23.0.wasm"
+        "https://plugins.dprint.dev/markdown-0.22.1.wasm"
+      ];
+      typescript = {
+        "binaryExpression.operatorPosition" = "sameLine";
+        quoteStyle = "preferSingle";
+      };
+    };
+  };
+  nmt.script = ''
+    assertFileContent \
+      home-files/.config/dprint/dprint.json \
+      ${./expected-dprint.json}
+  '';
+}

tests/modules/programs/dprint/expected-dprint.json

@@ -0,0 +1,18 @@
+{
+  "excludes": [
+    "**/*-lock.json"
+  ],
+  "json": {
+    "indentWidth": 2
+  },
+  "lineWidth": 80,
+  "plugins": [
+    "https://plugins.dprint.dev/typescript-0.96.1.wasm",
+    "https://plugins.dprint.dev/json-0.23.0.wasm",
+    "https://plugins.dprint.dev/markdown-0.22.1.wasm"
+  ],
+  "typescript": {
+    "binaryExpression.operatorPosition": "sameLine",
+    "quoteStyle": "preferSingle"
+  }
+}