easyeffects: support separate startup presets

Author: Tenshock

modules/services/easyeffects.nix

@@ -9,12 +9,62 @@ let
 
   cfg = config.services.easyeffects;
 
-  presetOpts = lib.optionalString (cfg.preset != "") "--load-preset ${cfg.preset}";
+  isSplitPreset = builtins.isAttrs cfg.preset;
+
+  selectedPresets =
+    if isSplitPreset then lib.filterAttrs (_: preset: preset != "") cfg.preset else { };
+
+  presetOpts = lib.optionalString (
+    !isSplitPreset && cfg.preset != ""
+  ) "--load-preset ${lib.escapeShellArg cfg.preset}";
 
   olderThan8 = lib.versionOlder cfg.package.version "8.0.0"; # This version introduces breaking changes and this check is used to stay backwards compatible
 
+  olderThan8_0_9 = lib.versionOlder cfg.package.version "8.0.9";
+
   jsonFormat = pkgs.formats.json { };
 
+  splitPresetType = types.submodule {
+    options = {
+      input = mkOption {
+        type = types.str;
+        default = "";
+        description = "Input preset to load when starting EasyEffects.";
+      };
+
+      output = mkOption {
+        type = types.str;
+        default = "";
+        description = "Output preset to load when starting EasyEffects.";
+      };
+    };
+  };
+
+  splitPresetCommands = lib.concatStringsSep "\n" (
+    lib.mapAttrsToList (
+      pipeline: preset: "printf '%s\\n' ${lib.escapeShellArg "load_preset:${pipeline}:${preset}"}"
+    ) selectedPresets
+  );
+
+  loadSplitPresets = pkgs.writeShellScript "easyeffects-load-presets" ''
+    preset_socket=$1
+
+    for _ in {1..100}; do
+      if [[ -S "$preset_socket" ]]; then
+        if {
+          :
+          ${splitPresetCommands}
+        } | ${pkgs.socat}/bin/socat -u -T 1 - UNIX-CONNECT:"$preset_socket"; then
+          exit 0
+        fi
+      fi
+
+      ${pkgs.coreutils}/bin/sleep 0.1
+    done
+
+    exit 1
+  '';
+
   settingType = types.nullOr (
     types.oneOf [
       types.bool
@@ -142,11 +192,23 @@ in
     package = lib.mkPackageOption pkgs "easyeffects" { };
 
     preset = mkOption {
-      type = types.str;
+      type = types.either types.str splitPresetType;
       default = "";
+      example = literalExpression ''
+        {
+          input = "voice";
+          output = "music";
+        }
+      '';
       description = ''
-        Which preset to use when starting easyeffects.
-        Will likely need to launch easyeffects to initially create preset.
+        Preset to load when starting EasyEffects.
+
+        A string loads every input or output preset having that name. An
+        attribute set selects input and output presets independently and
+        requires EasyEffects 8.0.9 or later. An empty string leaves that
+        pipeline unchanged.
+
+        You will likely need to launch EasyEffects to initially create presets.
       '';
     };
 
@@ -179,6 +241,14 @@ in
         assertion = !hasSettings || !olderThan8;
         message = "${settingsOption} requires EasyEffects 8.0.0 or later.";
       }
+      {
+        assertion = !isSplitPreset || !olderThan8_0_9;
+        message = "Structured `services.easyeffects.preset` requires EasyEffects 8.0.9 or later.";
+      }
+      {
+        assertion = !isSplitPreset || selectedPresets != { };
+        message = "Structured `services.easyeffects.preset` must select at least one input or output preset.";
+      }
     ];
 
     home.packages = with pkgs; lib.optional olderThan8 at-spi2-core ++ [ cfg.package ]; # Only include if easyeffects version is below 8.0.0
@@ -222,6 +292,9 @@ in
       // lib.optionalAttrs hasSettings {
         ExecStartPre = settingsScript;
       }
+      // lib.optionalAttrs isSplitPreset {
+        ExecStartPost = "-${loadSplitPresets} %t/EasyEffectsServer";
+      }
       // (
         if olderThan8 then
           {

tests/modules/services/easyeffects/default.nix

@@ -5,4 +5,6 @@ lib.optionalAttrs pkgs.stdenv.hostPlatform.isLinux {
   easyeffects-example-preset = ./example-preset.nix;
   easyeffects-null-presets = ./null-presets.nix;
   easyeffects-settings-old-version = ./settings-old-version.nix;
+  easyeffects-split-presets = ./split-presets.nix;
+  easyeffects-split-presets-old-version = ./split-presets-old-version.nix;
 }

tests/modules/services/easyeffects/service.nix

@@ -11,6 +11,7 @@ in
 {
   services.easyeffects = {
     enable = true;
+    preset = "music";
     inherit settings;
   };
 
@@ -20,7 +21,8 @@ in
     serviceFile=home-files/.config/systemd/user/easyeffects.service
 
     assertFileExists $serviceFile
-    assertFileRegex $serviceFile 'ExecStart=.*/bin/easyeffects'
+    assertFileRegex $serviceFile \
+      'ExecStart=.*/bin/easyeffects .*--load-preset music'
     assertFileContains $serviceFile \
       'X-Restart-Triggers=${builtins.hashString "sha256" (builtins.toJSON settings)}'
 

tests/modules/services/easyeffects/split-presets-old-version.nix

@@ -0,0 +1,13 @@
+{ config, ... }:
+
+{
+  services.easyeffects = {
+    enable = true;
+    package = config.lib.test.mkStubPackage { version = "8.0.8"; };
+    preset.input = "home";
+  };
+
+  test.asserts.assertions.expected = [
+    "Structured `services.easyeffects.preset` requires EasyEffects 8.0.9 or later."
+  ];
+}

tests/modules/services/easyeffects/split-presets.nix

@@ -0,0 +1,34 @@
+{ config, ... }:
+
+{
+  services.easyeffects = {
+    enable = true;
+    package = config.lib.test.mkStubPackage { version = "8.0.9"; };
+    preset = {
+      input = "home";
+      output = "Discord Voice";
+    };
+  };
+
+  test.stubs.easyeffects = { };
+
+  nmt.script = ''
+    serviceFile=home-files/.config/systemd/user/easyeffects.service
+
+    assertFileExists "$serviceFile"
+    assertFileNotRegex "$serviceFile" 'ExecStart=.*--load-preset'
+    assertFileRegex "$serviceFile" \
+      'ExecStartPost=.*-easyeffects-load-presets %t/EasyEffectsServer'
+
+    presetLoader=$(sed -n \
+      's|^ExecStartPost=-\([^ ]*\).*|\1|p' "$TESTED/$serviceFile")
+
+    assertFileExists "$presetLoader"
+    assertFileContains "$presetLoader" \
+      "printf '%s\\n' load_preset:input:home"
+    assertFileContains "$presetLoader" \
+      "printf '%s\\n' 'load_preset:output:Discord Voice'"
+    assertFileContains "$presetLoader" \
+      'socat -u -T 1 - UNIX-CONNECT:"$preset_socket"'
+  '';
+}