claude-code: allow hooks to accept a path like skills/commands

programs.claude-code.hooks previously only accepted inline strings.
It now shares the same either-lines-or-path content option used by
agents, commands, and rules, so a hook script can be referenced from
a file instead of being inlined.

mkSourceEntry used lib.isPath, which does not match derivations such
as pkgs.writeShellScript. Since lib.types.path accepts derivations,
a derivation-backed hook (or agent, command, rule, or output style)
sent the derivation to home.file.*.text and failed evaluation. Use
lib.hm.strings.isPathLike instead, and add a derivation-backed hook
test.

No release-notes entry: other option additions/extensions to this
module (e.g. path support for agents/commands, the rules option
itself) haven't warranted one either.

Author: vidhanio

modules/programs/claude-code/lib.nix

@@ -6,7 +6,8 @@ in
   mkHelpers =
     { configDir }:
     let
-      mkSourceEntry = content: if lib.isPath content then { source = content; } else { text = content; };
+      mkSourceEntry =
+        content: if lib.hm.strings.isPathLike content then { source = content; } else { text = content; };
 
       mkMarketplaceEntry = _name: content: {
         source = {
@@ -22,10 +23,7 @@ in
         attrs:
         lib.mapAttrs' (
           name: content:
-          lib.nameValuePair "${configDir}/hooks/${name}" {
-            text = content;
-            executable = true;
-          }
+          lib.nameValuePair "${configDir}/hooks/${name}" ((mkSourceEntry content) // { executable = true; })
         ) attrs;
 
       mkInstalledMarketplaceEntry =

modules/programs/claude-code/options.nix

@@ -278,25 +278,24 @@ in
       '';
     };
 
-    hooks = mkOption {
-      type = lib.types.attrsOf lib.types.lines;
-      default = { };
+    hooks = mkContentOption {
       description = ''
         Custom hooks for Claude Code.
-        The attribute name becomes the hook filename, and the value is the hook script content.
+        The attribute name becomes the hook filename, and the value is either:
+        - Inline content as a string
+        - A path to a file containing the hook script content
         Hooks are stored in the {file}`hooks/` subdirectory of
-        {option}`programs.claude-code.configDir`.
+        {option}`programs.claude-code.configDir` and made executable.
+      '';
+      example = literalExpression ''
+        {
+          pre-edit = '''
+            #!/usr/bin/env bash
+            echo "About to edit file: $1"
+          ''';
+          post-commit = ./hooks/post-commit.sh;
+        }
       '';
-      example = {
-        pre-edit = ''
-          #!/usr/bin/env bash
-          echo "About to edit file: $1"
-        '';
-        post-commit = ''
-          #!/usr/bin/env bash
-          echo "Committed with message: $1"
-        '';
-      };
     };
 
     rules = mkContentOption {

tests/modules/programs/claude-code/default.nix

@@ -21,6 +21,7 @@
   claude-code-skills-subdir = ./skills-subdir.nix;
   claude-code-agents-path = ./agents-path.nix;
   claude-code-commands-path = ./commands-path.nix;
+  claude-code-hooks-path = ./hooks-path.nix;
   claude-code-skills-path = ./skills-path.nix;
   claude-code-legacy-memory-text = ./legacy-memory-text.nix;
   claude-code-legacy-memory-source-and-skills-dir = ./legacy-memory-source-and-skills-dir.nix;

tests/modules/programs/claude-code/hooks-path.nix

@@ -0,0 +1,34 @@
+{ pkgs, ... }:
+let
+  derivation-hook = pkgs.writeShellScript "derivation-hook" ''
+    echo "About to edit file: $1"
+  '';
+in
+{
+  programs.claude-code = {
+    enable = true;
+    hooks = {
+      inline-hook = ''
+        #!/usr/bin/env bash
+        echo "About to edit file: $1"
+      '';
+      test-hook = ./hooks/test-hook;
+      inherit derivation-hook;
+    };
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.claude/hooks/inline-hook
+    assertFileIsExecutable home-files/.claude/hooks/inline-hook
+
+    assertFileExists home-files/.claude/hooks/test-hook
+    assertFileIsExecutable home-files/.claude/hooks/test-hook
+    assertFileContent home-files/.claude/hooks/test-hook \
+      ${./hooks/test-hook}
+
+    assertFileExists home-files/.claude/hooks/derivation-hook
+    assertFileIsExecutable home-files/.claude/hooks/derivation-hook
+    assertFileContent home-files/.claude/hooks/derivation-hook \
+      ${derivation-hook}
+  '';
+}

tests/modules/programs/claude-code/mixed-content.nix

@@ -31,6 +31,13 @@
       '';
       path-skill = ./test-skill.md;
     };
+    hooks = {
+      inline-hook = ''
+        #!/usr/bin/env bash
+        echo "This hook is defined inline."
+      '';
+      path-hook = ./hooks/test-hook;
+    };
   };
 
   nmt.script = ''
@@ -40,12 +47,18 @@
     assertFileExists home-files/.claude/agents/path-agent.md
     assertFileExists home-files/.claude/skills/inline-skill/SKILL.md
     assertFileExists home-files/.claude/skills/path-skill/SKILL.md
+    assertFileExists home-files/.claude/hooks/inline-hook
+    assertFileExists home-files/.claude/hooks/path-hook
 
     assertFileContent home-files/.claude/commands/path-command.md \
       ${./test-command.md}
     assertFileContent home-files/.claude/agents/path-agent.md \
       ${./test-agent.md}
     assertFileContent home-files/.claude/skills/path-skill/SKILL.md \
       ${./test-skill.md}
+    assertFileContent home-files/.claude/hooks/path-hook \
+      ${./hooks/test-hook}
+    assertFileIsExecutable home-files/.claude/hooks/inline-hook
+    assertFileIsExecutable home-files/.claude/hooks/path-hook
   '';
 }