nix: initial testing framework

Author: NotAShelf

checks/nixos/test.nix

@@ -0,0 +1,109 @@
+{
+  testers,
+  writeText,
+  ...
+}:
+testers.runNixOSTest {
+  name = "nh-nixos-test";
+  nodes.machine = {
+    lib,
+    pkgs,
+    ...
+  }: {
+    imports = [
+      ../vm.nix
+    ];
+
+    nix.settings = {
+      substituters = lib.mkForce [];
+      hashed-mirrors = null;
+      connect-timeout = 1;
+    };
+
+    # Indicate parent config
+    environment.systemPackages = [
+      (pkgs.writeShellScriptBin "parent" "")
+    ];
+
+    programs.nh = {
+      enable = true;
+      flake = "/etc/nixos";
+    };
+  };
+
+  testScript = {nodes, ...}: let
+    newConfig =
+      writeText "configuration.nix" # nix
+
+      ''
+        { lib, pkgs, ... }: {
+          imports = [
+            ./hardware-configuration.nix
+            <nixpkgs/nixos/modules/testing/test-instrumentation.nix>
+          ];
+
+          boot.loader.grub = {
+            enable = true;
+            device = "/dev/vda";
+            forceInstall = true;
+          };
+
+          documentation.enable = false;
+
+          environment.systemPackages = [
+            (pkgs.writeShellScriptBin "parent" "")
+          ];
+
+
+          specialisation.foo = {
+            inheritParentConfig = true;
+
+            configuration = {...}: {
+              environment.etc."specialisation".text = "foo";
+            };
+          };
+
+          specialisation.bar = {
+            inheritParentConfig = true;
+
+            configuration = {...}: {
+              environment.etc."specialisation".text = "bar";
+            };
+          };
+        }
+      '';
+  in
+    # python
+    ''
+      machine.start()
+      machine.succeed("udevadm settle")
+      machine.wait_for_unit("multi-user.target")
+
+      machine.succeed("nixos-generate-config --flake")
+      machine.copy_from_host("${newConfig}", "/etc/nixos/configuration.nix")
+
+      with subtest("Switch to the base system"):
+        machine.succeed("nh os switch --no-nom")
+        machine.succeed("parent")
+        machine.fail("cat /etc/specialisation/text | grep 'foo'")
+        machine.fail("cat /etc/specialisation/text | grep 'bar'")
+
+      with subtest("Switch to the foo system"):
+        machine.succeed("nh os switch --no-nom --specialisation foo")
+        machine.succeed("parent")
+        machine.succeed("cat /etc/specialisation/text | grep 'foo'")
+        machine.fail("cat /etc/specialisation/text | grep 'bar'")
+
+      with subtest("Switch to the bar system"):
+        machine.succeed("nh os switch --no-nom --specialisation bar")
+        machine.succeed("parent")
+        machine.fail("cat /etc/specialisation/text | grep 'foo'")
+        machine.succeed("cat /etc/specialisation/text | grep 'bar'")
+
+      with subtest("Switch into specialization using `nh os test`"):
+        machine.succeed("nh os test --specialisation foo")
+        machine.succeed("parent")
+        machine.succeed("foo")
+        machine.fail("bar")
+    '';
+}

checks/vm.nix

@@ -0,0 +1,20 @@
+{
+  pkgs,
+  lib,
+  ...
+}: {
+  nix.settings = {
+    substituters = lib.mkForce [];
+    hashed-mirrors = null;
+    connect-timeout = 1;
+  };
+
+  environment.systemPackages = [pkgs.hello];
+
+  system.includeBuildDependencies = true;
+
+  virtualisation = {
+    cores = 2;
+    memorySize = 4096;
+  };
+}

flake.nix

@@ -3,36 +3,36 @@
     nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.11";
   };
 
-  outputs =
-    {
-      self,
-      nixpkgs,
-    }:
-    let
-      forAllSystems =
-        function:
-        nixpkgs.lib.genAttrs [
-          "x86_64-linux"
-          "aarch64-linux"
-          # experimental
-          "x86_64-darwin"
-          "aarch64-darwin"
-        ] (system: function nixpkgs.legacyPackages.${system});
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    forAllSystems = function:
+      nixpkgs.lib.genAttrs [
+        "x86_64-linux"
+        "aarch64-linux"
+        # experimental
+        "x86_64-darwin"
+        "aarch64-darwin"
+      ] (system: function nixpkgs.legacyPackages.${system});
 
-      rev = self.shortRev or self.dirtyShortRev or "dirty";
-    in
-    {
-      overlays.default = final: prev: { nh = final.callPackage ./package.nix { inherit rev; }; };
+    rev = self.shortRev or self.dirtyShortRev or "dirty";
+  in {
+    overlays.default = final: prev: {nh = final.callPackage ./package.nix {inherit rev;};};
 
-      packages = forAllSystems (pkgs: rec {
-        nh = pkgs.callPackage ./package.nix { inherit rev; };
-        default = nh;
-      });
+    packages = forAllSystems (pkgs: rec {
+      nh = pkgs.callPackage ./package.nix {inherit rev;};
+      default = nh;
+    });
 
-      devShells = forAllSystems (pkgs: {
-        default = import ./shell.nix { inherit pkgs; };
-      });
+    checks = forAllSystems (pkgs: {
+      nixos = pkgs.callPackage ./checks/nixos/test.nix {};
+    });
 
-      formatter = forAllSystems (pkgs: pkgs.nixfmt-rfc-style);
-    };
+    devShells = forAllSystems (pkgs: {
+      default = import ./shell.nix {inherit pkgs;};
+    });
+
+    formatter = forAllSystems (pkgs: pkgs.nixfmt-rfc-style);
+  };
 }