Can't get Stylix working after going through installation documentation

[MoltenMonster]

Edit: Here's my whole config (minus hardware config) if that helps: nix config.zip

I've done lots of looking up and reading the documentation multiple times but it seems to be missing something. The theme isn't applied to programs.

I installed Stylix looking at the installation page, and the home manager module, both as flakes. It says "Installing Home Manager as a NixOS module is highly recommended" and "When Stylix is installed and enabled in a NixOS configuration, it will automatically set up its Home Manager modules if it detects that Home Manager is available".

Looking at the configuration page, This is in my configuration.nix:

      stylix = {
        base16Scheme = "${pkgs.base16-schemes}/share/themes/catppuccin-mocha.yaml";
        autoEnable = true;
        enable = true;
      };
    
    programs = {
        neovim.enable = true;
        fish.enable = true;
        yazi.enable = true;
    }

I have pkgs.base16-schemes installed but the theme is not applied to any of the programs. Even when I try having them installed via home-manager instead (in configuration.nix):

      home-manager.users.myUsername =
        { config, ... }:
        {
          home = {
            stateVersion = "25.11";
            packages = [
              pkgs.neovim
              pkgs.fish
              pkgs.yazi
            ];
          };
        };

My flake.nix:

        {
          inputs = {
            home-manager = {
              url = "github:nix-community/home-manager";
              inputs.nixpkgs.follows = "nixpkgs";
            };
            stylix = {
              url = "github:danth/stylix";
              inputs.nixpkgs.follows = "nixpkgs";
            };
            nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
          };
        
          outputs =
            { self, nixpkgs, ... }@inputs:
            {
              nixosConfigurations.NixOS-MBP = nixpkgs.lib.nixosSystem {
                specialArgs.flake-inputs = inputs;
                modules = [
                  {
                    home-manager.useGlobalPkgs = true;
                    home-manager.useUserPackages = true;
                  }
                  inputs.home-manager.nixosModules.home-manager
                  inputs.stylix.nixosModules.stylix
                  ./configuration.nix
                  ./hardware-configuration.nix
                ];
              };
            };
        }

[0xda157]

For most targets you need to use the programs. or services. option in home-manager inside of adding them to home.packages or environment.systemPackages.

[trueNAHO]

Can you give examples for clarity?

Stylix themes most applications with options similar to programs.${program}.settings, which themselves are ideally guarded by upstream with programs.${program}.enable. Unless you declare programs.${program}.enable = true; in your configuration we are intentionally not theming the application. Manually installing applications with home.packages or environment.systemPackages circumvents proper upstream integration, which sidesteps Stylix theming.

In other words:

-home.packages = [pkgs.neovim];
+programs.neovim.enable = true;

[MoltenMonster]

I tried that and it didn't work. I have a whole neovim configuration, I moved it out ~/.config and rebuilt my flake but it still shows the default colorscheme after reopening it.

[trueNAHO]

I tried that and it didn't work. I have a whole neovim configuration, I moved it out ~/.config and rebuilt my flake but it still shows the default colorscheme after reopening it.

Does the configuration contain the expected Stylix code? Also, consider rebooting.

[MoltenMonster]

I tried this example from another thread but doesn't work even after rebooting.

[danth]

I tried this example from another thread but doesn't work even after rebooting.

In that example, programs.neovim.enable is used in the NixOS configuration, not Home Manager. Confusingly, Stylix currently only supports programs.neovim.enable under Home Manager (this is something we could potentially improve).

[MoltenMonster]

After lots of back and forth here, this seems to work:

configuration.nix:

# configuration.nix
{ pkgs, flake-inputs, ... }: {
  imports = [
    ./hardware-configuration.nix
    flake-inputs.home-manager.nixosModules.home-manager
    flake-inputs.stylix.nixosModules.stylix
  ];

  stylix = {
    base16Scheme = "${pkgs.base16-schemes}/share/themes/catppuccin-mocha.yaml";
    autoEnable = true;
    enable = true;
  };

  home-manager = {
    useGlobalPkgs = true;
    useUserPackages = true;
    # See next snippet
    users.myUsername = import ./home.nix;
  };

  # Any other config here
}

home.nix:

# home.nix
{ pkgs, ... }: {
  home = {
    # Remember not to touch this, no
    # it's not for updating, no it should
    # not be changed when updating
    stateVersion = "25.11";
  };

  stylix.targets.neovim.enable = true;
  programs.neovim.enable = true;

  # Any other config here
}

flake.nix:

# somewhere in flake.nix
nixosConfigurations.DeviceNameHere = nixpkgs.lib.nixosSystem {
  specialArgs.flake-inputs = inputs;
  modules = [
    ./configuration.nix
  ];
}