Add MAKE_CC_TEST helper

Author: breakds

CMakeLists.txt

@@ -27,10 +27,13 @@ include(GNUInstallDirs)                 # This will define the default values fo
 include(InstallRequiredSystemLibraries) # Tell CMake that the `install` target needs to install required system libraries (eg: Windows SDK)
 include(CMakePackageConfigHelpers)      # Helper to create relocatable packages
 
+
 # Custom modules and scripts
 
 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake") # Make our cmake scripts available
 
+include(BuildHelpers)  # Helpers for writing cmake files
+
 ###############
 ##  Options  ##
 ###############

cmake/BuildHelpers.cmake

@@ -0,0 +1,31 @@
+include(CMakeParseArguments)
+
+function(make_cc_test)
+    if (NOT ENABLE_TESTING)
+        return()
+    endif()
+
+    cmake_parse_arguments(MAKE_CC_TEST
+        ""
+        "NAME"
+        "SRCS;DEPS;DATA"
+        ${ARGN})
+
+    set(_NAME "${MAKE_CC_TEST_NAME}")
+
+    add_executable(${_NAME})
+    target_sources(${_NAME} PRIVATE ${MAKE_CC_TEST_SRCS})
+    target_link_libraries(${_NAME}
+        PRIVATE ${MAKE_CC_TEST_DEPS} gtest gmock gtest_main)
+    gtest_discover_tests(${_NAME})
+
+
+    file(RELATIVE_PATH _DEST_DIR ${PROJECT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
+    install(TARGETS ${_NAME} DESTINATION tests/${_DEST_DIR})
+    foreach (_DATA_FILE ${MAKE_CC_TEST_DATA})
+        get_filename_component(SUBPATH ${_DATA_FILE} DIRECTORY)
+        install(FILES ${_DATA_FILE} DESTINATION tests/${_DEST_DIR}/${SUBPATH})
+        configure_file(${_DATA_FILE} ${_DATA_FILE} COPYONLY)
+    endforeach()
+    
+endfunction()

src/CMakeLists.txt

@@ -10,8 +10,8 @@ target_sources(simple
     PRIVATE simple.cc)
 
 if(ENABLE_TESTING)
-    add_executable(simple_test)
-    target_sources(simple_test PRIVATE simple_test.cc)
-    target_link_libraries(simple_test PRIVATE simple gtest gmock gtest_main)
-    gtest_discover_tests(simple_test)
+    MAKE_CC_TEST(
+        NAME simple_test
+        SRCS simple_test.cc
+        DEPS simple)
 endif()