Android-DFU-Library/settings.gradle.kts at main · nordicsemi/Android-DFU-Library · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
@Suppress("UnstableApiUsage")
pluginManagement {
    repositories {
        mavenLocal()
        google {
            content {
                includeGroupAndSubgroups("com.android")
                includeGroupAndSubgroups("com.google")
                includeGroupAndSubgroups("androidx")
            }
        }
        gradlePluginPortal {
            content {
                includeGroupAndSubgroups("com.gradle")
                includeGroupAndSubgroups("no.nordicsemi")
                includeGroupAndSubgroups("org.jetbrains")
            }
        }
        mavenCentral()
    }
}

@Suppress("UnstableApiUsage")
dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        mavenLocal()
        google {
            content {
                includeGroupAndSubgroups("com.android")
                includeGroupAndSubgroups("com.google")
                includeGroupAndSubgroups("androidx")
            }
        }
        mavenCentral()
    }
    versionCatalogs {
        // Use Nordic Gradle Version Catalog with common external libraries versions.
        create("libs") {
            from("no.nordicsemi.android.gradle:version-catalog:2.11.3-1")
        }
        // Fixed versions for Nordic libraries.
        create("nordic") {
            from(files("gradle/nordic.versions.toml"))
        }
        // Nordic Version Catalog is released after library releases, so cannot be used internally in libs.
        // create("nordic") {
        //    from("no.nordicsemi.android:version-catalog:2025.10.00")
        // }
    }
}

rootProject.name = "Device Firmware Update"

include(":app")
include(":lib:analytics")
include(":lib:dfu")
include(":lib:storage")
include(":lib:settings")
include(":profile:main")
include(":profile:scanner")
include(":profile:settings")
include(":profile:welcome")
include(":profile:navigation")