dvcp-vaapi/meson.build at master · nowrep/dvcp-vaapi · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
project(
  'dvcp-vaapi',
  'cpp',
  version: '0.3.0',
  license: 'MIT',
  meson_version: '>=0.58.0',
  default_options: [
    'prefer_static=true',
    'cpp_std=c++20',
    'warning_level=3',
  ],
)

add_project_arguments(
  [
    '-DRESOLVE_VAAPI_VERSION="@0@"'.format(meson.project_version()),
    '-Wno-unused',
  ],
  language: 'cpp',
)

libdrm = dependency('libdrm')
libva = dependency('libva')

ffmpeg = subproject(
  'ffmpeg',
  default_options: [
    'gpl=enabled',
    'default_library=static',
    'programs=disabled',
    'libdrm=enabled',
    'vaapi=enabled',
    'vaapi_drm=enabled',
    'h264_vaapi_encoder=enabled',
    'hevc_vaapi_encoder=enabled',
    'av1_vaapi_encoder=enabled',
  ]
)
libavcodec = ffmpeg.get_variable('libavcodec_dep')
libavutil = ffmpeg.get_variable('libavutil_dep')

srcs = files(
  'wrapper/host_api.cpp',
  'wrapper/plugin_api.cpp',
  'plugin.cpp',
  'vaapi_encoder.cpp',
)

shared_module(
  'vaapi_encoder',
  srcs,
  include_directories: ['include'],
  dependencies: [libdrm, libva, libavcodec, libavutil],
  name_prefix: '',
  name_suffix: 'dvcp',
  link_args: [
    '-Wl,-Bsymbolic',
    '-Wl,--no-undefined',
    '-Wl,--exclude-libs=ALL',
    '-static-libstdc++',
    '-static-libgcc',
  ]
)