applications: nrf_desktop: add constraints for MCUboot RAM load

Added the DTS RAM layout constraints to the nRF Desktop application
when it uses the MCUboot bootloader in the RAM load mode. These
constraints enforce a specific RAM layout for supported board targets.
The user is required to define two DTS nodes that are part of the
chosen SRAM DTS node of the application image:

- cpuapp_sram_app_rxm_region
- cpuapp_sram_mcuboot_ram_region

Additionally, the cpuapp_sram_app_rxm_region DTS node must be placed
before the cpuapp_sram_mcuboot_ram_region DTS node in the target
device memory.

Added a linker script with the assert statement that prevents the
executable RAM region of the application image to overflow the
standard RAM region of the MCUboot image.

Ref: NCSDK-35506

Signed-off-by: Kamil Piszczek <[email protected]>

Author: kapi-no

applications/nrf_desktop/CMakeLists.txt

@@ -47,6 +47,55 @@ if(CONFIG_IMG_MANAGER)
   zephyr_library_link_libraries(MCUBOOT_BOOTUTIL)
 endif()
 
+if(CONFIG_BOOTLOADER_MCUBOOT)
+  if(NOT (CONFIG_MCUBOOT_BOOTLOADER_MODE_SINGLE_APP OR
+          CONFIG_MCUBOOT_BOOTLOADER_MODE_DIRECT_XIP OR
+          CONFIG_MCUBOOT_BOOTLOADER_MODE_RAM_LOAD OR
+          CONFIG_MCUBOOT_BOOTLOADER_MODE_SWAP_USING_MOVE))
+    message(WARNING "
+            ------------------------------------------------------------------------------
+            --- WARNING: The currently selected mode of the MCUboot bootloader has not ---
+            --- been used or tested with any nRF Desktop configuration.                ---
+            ------------------------------------------------------------------------------
+            ")
+  endif()
+
+  if(CONFIG_MCUBOOT_BOOTLOADER_MODE_RAM_LOAD)
+    message(WARNING "
+            -----------------------------------------------------------------------------
+            --- WARNING: The RAM load mode of the MCUboot bootloader is experimental. ---
+            -----------------------------------------------------------------------------
+            ")
+
+    # Enforce the specific RAM layout in DTS when MCUboot uses the RAM load mode.
+    dt_nodelabel(app_rxm_region_node NODELABEL cpuapp_sram_app_rxm_region)
+    if(NOT app_rxm_region_node)
+      message(FATAL_ERROR
+              "Missing RXM (ROM + RAM) region definition (cpuapp_sram_app_rxm_region) for the "
+              "application image in DTS.")
+    endif()
+
+    dt_nodelabel(mcuboot_ram_region_node NODELABEL cpuapp_sram_mcuboot_ram_region)
+    if(NOT mcuboot_ram_region_node)
+      message(FATAL_ERROR
+              "Missing RAM region definition (cpuapp_sram_mcuboot_ram_region) for the MCUboot "
+              "bootloader in DTS.")
+    endif()
+
+    dt_reg_addr(app_rxm_region_addr PATH ${app_rxm_region_node})
+    dt_reg_addr(mcuboot_ram_region_addr PATH ${mcuboot_ram_region_node})
+    if(mcuboot_ram_region_addr LESS_EQUAL app_rxm_region_addr)
+      message(FATAL_ERROR
+              "The start address of the RXM region (0x${app_rxm_region_addr}) must be located "
+              "before the start address of the MCUboot RAM region (0x${mcuboot_ram_region_addr})."
+              "The current order is wrong — modify your DTS RAM layout to fix this error.")
+    endif()
+
+    # Ensure that generated application image will fit in the defined RAM partition after build.
+    zephyr_linker_sources(RODATA linker/mcuboot_ram_load.ld)
+  endif()
+endif()
+
 if(CONFIG_DESKTOP_CONFIG_CHANNEL_ENABLE)
   zephyr_linker_sources(SECTIONS nrf_desktop.ld)
   zephyr_linker_section(NAME config_channel_modules KVMA RAM_REGION GROUP RODATA_REGION NOINPUT)

applications/nrf_desktop/Kconfig.defaults

@@ -24,6 +24,18 @@ config DESKTOP_LTO_DEFAULTS
 	help
 	  nRF Desktop enables LTO to limit memory usage and improve performance.
 
+config DESKTOP_MCUBOOT_RAM_LOAD_MCUBOOT_RAM_START_ADDR
+	hex
+	depends on MCUBOOT_BOOTLOADER_MODE_RAM_LOAD
+	depends on $(dt_nodelabel_exists,cpuapp_sram_mcuboot_ram_region)
+	default $(dt_nodelabel_reg_addr_hex,cpuapp_sram_mcuboot_ram_region)
+	help
+	  The start address of the MCUboot RAM region. The Kconfig option is used to validate
+	  if the executable RAM region of the application image (also called the ROM section)
+	  does not overlap with the RAM region of the MCUboot image. The validation process
+	  assumes a specific RAM layout in DTS - you can refer to the following file as an example:
+	  ./configuration/nrf54lm20dk_nrf54lm20a_cpuapp/memory_map_ram_load.dtsi
+
 config APP_EVENT_MANAGER_MAX_EVENT_CNT
 	default 64
 	help

applications/nrf_desktop/linker/mcuboot_ram_load.ld

@@ -0,0 +1,9 @@
+/* Validate that the ROM section from the application RAM region does not overlap with the
+ * MCUboot RAM region. This ROM section defines the memory space where MCUboot copies the
+ * application image. If this copied data overlaps with the MCUboot RAM region, MCUboot may
+ * override its own RAM during the copy operation. The validation process assumes a specific
+ * RAM layout in DTS - you can refer to the following file as an example:
+ * ./configuration/nrf54lm20dk_nrf54lm20a_cpuapp/memory_map_ram_load.dtsi
+ */
+ASSERT(__rom_region_end <= CONFIG_DESKTOP_MCUBOOT_RAM_LOAD_MCUBOOT_RAM_START_ADDR,
+	"The executable RAM region overlaps with the MCUboot RAM region");