Display timestamps and last state for cron jobs

sorentwo · sorentwo · commit 0ebeda1bd907 · 2025-09-22T20:41:50.000+01:00
diff --git a/lib/oban/web/cron.ex b/lib/oban/web/cron.ex
@@ -0,0 +1,12 @@
+defmodule Oban.Web.Cron do
+  @moduledoc false
+
+  defstruct [:expression, :worker, :opts, :next_at, :last_at, :last_state]
+
+  def name(%__MODULE__{worker: worker, opts: opts}) do
+    base = String.replace(worker, ".", "-")
+    hash = :erlang.phash2(opts)
+
+    "#{base}-#{hash}"
+  end
+end
diff --git a/lib/oban/web/live/jobs/detail_component.ex b/lib/oban/web/live/jobs/detail_component.ex
@@ -200,7 +200,7 @@ defmodule Oban.Web.Jobs.DetailComponent do
             <div class="mb-12">
               <h4 class="mb-3 flex items-center space-x-2">
                 <div class="text-sm font-semibold">
-                  Attempt {attempt}&mdash;{Timing.iso8601_to_words(at)}
+                  Attempt {attempt}&mdash;{Timing.datetime_to_words(at)}
                 </div>
                 <div id={at} data-title={at} phx-hook="Tippy">
                   <Icons.info_circle class="w-5 h-5 text-gray-500 dark:text-gray-400" />
diff --git a/lib/oban/web/pages/crons_page.ex b/lib/oban/web/pages/crons_page.ex
@@ -3,7 +3,7 @@ defmodule Oban.Web.CronsPage do
 
   use Oban.Web, :live_component
 
-  alias Oban.Web.Page
+  alias Oban.Web.{Cron, CronQuery, Page, Timing}
 
   @impl Phoenix.LiveComponent
   def render(assigns) do
@@ -15,11 +15,7 @@ defmodule Oban.Web.CronsPage do
           class="pr-3 flex items-center border-b border-gray-200 dark:border-gray-700"
         >
           <div class="flex-none flex items-center pr-12">
-            <Core.all_checkbox
-              click="toggle-select-all"
-              checked={:none}
-              myself={@myself}
-            />
+            <Core.all_checkbox click="toggle-select-all" checked={:none} myself={@myself} />
 
             <h2 class="text-lg dark:text-gray-200 leading-4 font-bold">Crons</h2>
           </div>
@@ -30,7 +26,8 @@ defmodule Oban.Web.CronsPage do
             <.header label="name" class="ml-12 w-1/3 text-left" />
             <div class="ml-auto flex items-center space-x-6">
               <.header label="schedule" class="w-32 text-right" />
-              <.header label="activity" class="w-24 text-right" />
+              <.header label="last run" class="w-32 text-right" />
+              <.header label="next run" class="w-32 text-right" />
               <.header label="status" class="w-20 pr-3 text-right" />
             </div>
           </ul>
@@ -42,20 +39,16 @@ defmodule Oban.Web.CronsPage do
           </div>
 
           <ul class="divide-y divide-gray-100 dark:divide-gray-800">
-            <.cron_row
-              :for={{expr, worker, opts} <- @crontab}
-              expr={expr}
-              worker={worker}
-              opts={opts}
-              myself={@myself}
-            />
+            <.cron_row :for={cron <- @crontab} cron={cron} myself={@myself} />
           </ul>
         </div>
       </div>
     </div>
     """
   end
 
+  # Components
+
   attr :label, :string, required: true
   attr :class, :string, default: ""
 
@@ -67,47 +60,49 @@ defmodule Oban.Web.CronsPage do
     """
   end
 
-  attr :expr, :string
-  attr :worker, :string
-  attr :opts, :map
+  attr :cron, Cron
   attr :myself, :any
 
   defp cron_row(assigns) do
     ~H"""
     <li
-      id={"cron-#{cron_name(@worker, @opts)}"}
+      id={"cron-#{Cron.name(@cron)}"}
       class="flex items-center hover:bg-gray-50 dark:hover:bg-gray-950/30"
     >
-      <Core.row_checkbox
-        click="toggle-select"
-        value={@worker}
-        checked={false}
-        myself={@myself}
-      />
+      <Core.row_checkbox click="toggle-select" value={@cron.worker} checked={false} myself={@myself} />
 
       <div class="py-2.5 flex flex-grow items-center">
         <div class="w-1/3">
           <span class="block font-semibold text-sm text-gray-700 dark:text-gray-300">
-            {@worker}
+            {@cron.worker}
           </span>
 
           <samp class="font-mono truncate text-xs text-gray-500 dark:text-gray-400">
-            {format_opts(@opts)}
+            {format_opts(@cron.opts)}
           </samp>
         </div>
 
         <div class="ml-auto flex items-center space-x-6 tabular text-gray-500 dark:text-gray-300">
           <span class="w-32 text-right font-mono text-sm">
-            {@expr}
+            {@cron.expression}
+          </span>
+
+          <span class="w-32 text-right text-sm">
+            {Timing.datetime_to_words(@cron.last_at)}
           </span>
 
-          <span class="w-24 text-right">
-            -
+          <span class="w-32 text-right text-sm">
+            {Timing.datetime_to_words(@cron.next_at)}
           </span>
 
           <div class="w-20 pr-3 flex justify-end items-center space-x-1">
-            <span class="py-1.5 px-2 text-xs rounded-md bg-gray-100 dark:bg-gray-950">
-              Active
+            <span
+              id={"cron-state-icon-#{@cron.worker}"}
+              class="py-1.5 px-2 text-xs"
+              phx-hook="Tippy"
+              data-title={state_title(@cron)}
+            >
+              <.state_icon state={@cron.last_state} />
             </span>
           </div>
         </div>
@@ -116,16 +111,40 @@ defmodule Oban.Web.CronsPage do
     """
   end
 
-  defp cron_name(worker, opts) do
-    base = String.replace(worker, ".", "-")
-    hash = :erlang.phash2(opts)
+  attr :state, :string, required: true
+
+  defp state_icon(assigns) do
+    ~H"""
+    <%= case @state do %>
+      <% "available" -> %>
+        <Icons.pause_circle class="w-5 h-5 text-teal-400" />
+      <% "cancelled" -> %>
+        <Icons.x_circle class="w-5 h-5 text-violet-400" />
+      <% "completed" -> %>
+        <Icons.check_circle class="w-5 h-5 text-cyan-400" />
+      <% "discarded" -> %>
+        <Icons.exclamation_circle class="w-5 h-5 text-rose-400" />
+      <% "executing" -> %>
+        <Icons.play_circle class="w-5 h-5 text-orange-400" />
+      <% "retryable" -> %>
+        <Icons.arrow_path class="w-5 h-5 text-yellow-400" />
+      <% "scheduled" -> %>
+        <Icons.play_circle class="w-5 h-5 text-emerald-400" />
+      <% _ -> %>
+        <Icons.minus_circle class="w-5 h-5 text-gray-400" />
+    <% end %>
+    """
+  end
 
-    "#{base}-#{hash}"
+  defp state_title(cron) do
+    case cron.last_state do
+      nil -> "Unknown, no previous runs"
+      state -> "#{String.capitalize(state)} as of #{NaiveDateTime.truncate(cron.last_at, :second)}"
+    end
   end
 
   @impl Page
   def handle_mount(socket) do
-
     assign_new(socket, :crontab, fn -> crontab(socket.assigns.conf) end)
   end
 
@@ -136,6 +155,8 @@ defmodule Oban.Web.CronsPage do
 
   @impl Page
   def handle_params(_params, _uri, socket) do
+    socket = assign(socket, page_title: page_title("Crons"))
+
     {:noreply, socket}
   end
 
@@ -156,13 +177,15 @@ defmodule Oban.Web.CronsPage do
     {:noreply, socket}
   end
 
-  defp crontab(conf), do: Oban.Met.crontab(conf.name)
+  defp crontab(conf) do
+    CronQuery.all_crons(%{}, conf)
+  end
 
-  defp format_opts(opts) when map_size(opts) == 0, do: "%{}"
+  defp format_opts(opts) when map_size(opts) == 0, do: "[]"
 
   defp format_opts(opts) do
     opts
-    |> inspect(charlists: :as_lists, limit: :infinity)
+    |> Enum.map_join(", ", fn {key, val} -> "#{key}: #{inspect(val)}" end)
     |> truncate(0..98)
   end
 end
diff --git a/lib/oban/web/queries/cron_query.ex b/lib/oban/web/queries/cron_query.ex
@@ -0,0 +1,78 @@
+defmodule Oban.Web.CronQuery do
+  @moduledoc false
+
+  import Ecto.Query
+
+  alias Oban.Cron.Expression
+  alias Oban.{Job, Met, Repo}
+  alias Oban.Web.Cron
+
+  def all_crons(_params, conf) do
+    # TODO: Cache these values and avoid running the query too frequently
+    crontab = Met.crontab(conf.name)
+    workers = Enum.map(crontab, &elem(&1, 1))
+    history = crontab_history(workers, conf)
+
+    for {expr, worker, opts} <- crontab do
+      fields = [
+        expression: expr,
+        worker: worker,
+        opts: opts,
+        next_at: next_at(expr),
+        last_at: last_at(history, worker),
+        last_state: get_in(history, [worker, :state])
+      ]
+
+      struct!(Cron, fields)
+    end
+  end
+
+  # TODO: Support mysql/sqlite
+  defp crontab_history(workers, conf) do
+    query =
+      from(
+        f in fragment("json_array_elements_text(?)", ^workers),
+        as: :list,
+        inner_lateral_join:
+          j in subquery(
+            Job
+            |> select(~w(state attempted_at cancelled_at completed_at discarded_at scheduled_at)a)
+            |> where([j], j.worker == parent_as(:list).value)
+            |> order_by(desc: :id)
+            |> limit(1)
+          ),
+        on: true,
+        select:
+          {f.value,
+           %{
+             state: j.state,
+             attempted_at: j.attempted_at,
+             cancelled_at: j.cancelled_at,
+             completed_at: j.completed_at,
+             discarded_at: j.discarded_at,
+             scheduled_at: j.scheduled_at
+           }}
+      )
+
+    conf
+    |> Repo.all(query)
+    |> Map.new()
+  end
+
+  defp last_at(history, worker) do
+    case Map.get(history, worker) do
+      %{state: state, scheduled_at: at} when state in ~w(available scheduled retryable) -> at
+      %{state: "executing", attempted_at: at} -> at
+      %{state: "cancelled", cancelled_at: at} -> at
+      %{state: "completed", completed_at: at} -> at
+      %{state: "discarded", discarded_at: at} -> at
+      _ -> nil
+    end
+  end
+
+  defp next_at(expression) do
+    expression
+    |> Expression.parse!()
+    |> Expression.next_at()
+  end
+end
diff --git a/lib/oban/web/timing.ex b/lib/oban/web/timing.ex
@@ -138,7 +138,7 @@ defmodule Oban.Web.Timing do
       iex> Oban.Web.Timing.to_words(-1, relative: false)
       "1s"
   """
-  def to_words(ellapsed, opts \\ [relative: true]) when is_integer(ellapsed) do
+  def to_words(ellapsed, opts \\ []) when is_integer(ellapsed) do
     distance =
       case abs(ellapsed) do
         0 -> "now"
@@ -151,7 +151,7 @@ defmodule Oban.Web.Timing do
       end
 
     cond do
-      not opts[:relative] -> distance
+      opts[:relative] == false -> distance
       ellapsed < 0 -> "#{distance} ago"
       ellapsed > 0 -> "in #{distance}"
       true -> distance
@@ -252,14 +252,22 @@ defmodule Oban.Web.Timing do
   defp truncate_sec(datetime), do: NaiveDateTime.truncate(datetime, :second)
 
   @doc """
-  Convert a stringified timestamp (i.e. from an error) into a relative time.
+  Convert a naive date time or iso8601 stringified version to a relative time.
   """
-  def iso8601_to_words(iso8601, now \\ NaiveDateTime.utc_now()) do
+  def datetime_to_words(datetime, opts \\ [])
+
+  def datetime_to_words(nil, _), do: "-"
+
+  def datetime_to_words(iso8601, opts) when is_binary(iso8601) do
     {:ok, datetime} = NaiveDateTime.from_iso8601(iso8601)
 
+    datetime_to_words(datetime, opts)
+  end
+
+  def datetime_to_words(datetime, opts) do
     datetime
-    |> NaiveDateTime.diff(now)
-    |> to_words()
+    |> NaiveDateTime.diff(NaiveDateTime.utc_now())
+    |> to_words(opts)
   end
 
   defp pad(time, places \\ 2) do
diff --git a/test/oban/web/pages/crons/index_test.exs b/test/oban/web/pages/crons/index_test.exs
@@ -16,11 +16,16 @@ defmodule Oban.Web.Pages.Crons.IndexTest do
   use Oban.Web.Case, async: true
 
   setup do
-    start_supervised_oban!(plugins: [{Oban.Plugins.Cron, crontab: [
-      {"* * * * *", Oban.Workers.CronA},
-      {"0 * * * *", Oban.Workers.CronA, args: %{special: true}},
-      {"0 0 * * *", Oban.Workers.CronB, priority: 3},
-    ]}])
+    start_supervised_oban!(
+      plugins: [
+        {Oban.Plugins.Cron,
+         crontab: [
+           {"* * * * *", Oban.Workers.CronA},
+           {"0 * * * *", Oban.Workers.CronA, args: %{special: true}},
+           {"0 0 * * *", Oban.Workers.CronB, priority: 3}
+         ]}
+      ]
+    )
 
     {:ok, live, _html} = live(build_conn(), "/oban/crons")
 
