Add "Run Now" button to cron details page

Missed crons can be ran manually through the UI now with the "Run Now"
button. Options are preserved and the job is properly marked as being
part of that cron lineage.

Author: sorentwo

lib/oban/web/live/crons/detail_component.ex

@@ -31,6 +31,16 @@ defmodule Oban.Web.Crons.DetailComponent do
         </.link>
 
         <div class="flex space-x-3">
+          <button
+            :if={can?(:insert_jobs, @access)}
+            type="button"
+            class="flex items-center text-sm text-gray-600 dark:text-gray-400 bg-white dark:bg-gray-800 px-4 py-2 border border-gray-300 dark:border-gray-700 rounded-md focus-visible:outline-none focus-visible:ring-1 focus-visible:ring-blue-500 focus-visible:border-blue-500 hover:text-blue-500 hover:border-blue-600 cursor-pointer"
+            phx-click="run-now"
+            phx-target={@myself}
+          >
+            <Icons.play_circle class="mr-2 h-5 w-5" /> Run Now
+          </button>
+
           <button
             :if={@cron.dynamic? and can?(:pause_queues, @access)}
             type="button"
@@ -330,6 +340,34 @@ defmodule Oban.Web.Crons.DetailComponent do
   # Handlers
 
   @impl Phoenix.LiveComponent
+  def handle_event("run-now", _params, socket) do
+    enforce_access!(:insert_jobs, socket.assigns.access)
+
+    %{cron: cron, conf: conf} = socket.assigns
+
+    worker = Module.safe_concat([cron.worker])
+    args = Map.get(cron.opts, "args", %{})
+
+    opts =
+      cron.opts
+      |> Map.take(~w(max_attempts priority queue tags))
+      |> Keyword.new(fn {key, val} -> {String.to_existing_atom(key), val} end)
+      |> Keyword.put(:meta, %{cron: true, cron_expr: cron.expression, cron_name: cron.name})
+
+    changeset = worker.new(args, opts)
+
+    case Oban.insert(conf.name, changeset) do
+      {:ok, _job} ->
+        send(self(), :refresh)
+        send(self(), {:flash, :info, "Job inserted for #{cron.worker}"})
+
+      {:error, _reason} ->
+        send(self(), {:flash, :error, "Failed to insert job"})
+    end
+
+    {:noreply, socket}
+  end
+
   def handle_event("toggle-pause", _params, socket) do
     enforce_access!(:pause_queues, socket.assigns.access)
 

test/oban/web/pages/crons/detail_test.exs

@@ -150,6 +150,25 @@ defmodule Oban.Web.Pages.Crons.DetailTest do
       refute has_element?(live, "fieldset[disabled]")
       assert has_element?(live, "button:not([disabled])", "Save Changes")
     end
+
+    test "run now button inserts a job for the cron" do
+      DynamicCron.insert([{"0 * * * *", DetailCronWorker, name: "run-now-test"}])
+
+      {:ok, live, _html} = live(build_conn(), "/oban/crons/run-now-test")
+
+      refresh(live)
+
+      assert has_element?(live, "button", "Run Now")
+
+      live
+      |> element("button", "Run Now")
+      |> render_click()
+
+      assert [job] = Repo.all(Job)
+
+      assert "Oban.Workers.DetailCronWorker" == job.worker
+      assert %{"cron_expr" => "0 * * * *", "cron_name" => "run-now-test"} = job.meta
+    end
   end
 
   defp refresh(live) do