usage in toplevel ?

[lafleurdeboum]

First, thanks for this awesome library !

I couldn't find a way to use it in a toplevel though. I tried some things, like :

$ ocaml -ppx mlx-pp
OCaml version 5.4.1
Enter #help;; for help.

# #use_output "dune top";;
# JSX.render <h1>(JSX.string "ok")</h1>;;
Error: Syntax error

I think I read somewhere a long time ago that there was a way to activate preprocesses in utop. Or maybe it was that ppxs are automatically activated. But mlx-pp is not an ast preprocessor like reason-react-ppx, is it ? So is there a way to benefit from its usage in any toplevel ? That would be awesome !

[lafleurdeboum]

Well, it itched me, so I made top.ml :

let create_tmpfile () =
  let filename = Filename.temp_file "ocaml" "~" in
  at_exit (fun () -> try Sys.remove filename with Sys_error _ -> ());
  filename

let read file =
  In_channel.with_open_bin file @@ fun ic ->
    let len = in_channel_length ic in
    let buf = Bytes.create len in
    really_input ic buf 0 len;
    Bytes.unsafe_to_string buf

let write ~file txt =
  Out_channel.with_open_bin file @@ fun oc ->
    output_string oc txt

let read_command cmd =
  let res = create_tmpfile () in
  let cmd = Printf.sprintf "%s > %s" cmd res in
  match Sys.command cmd with
  | 0 -> String.trim (read res) 
  | n -> failwith (Printf.sprintf "command %s failed with exit code %d" cmd n)

let preprocess txt =
  if (String.length txt = 0 || txt.[0] = '#') then txt ^ "\n"
  else
    let raw_content_file = create_tmpfile () in
    write ~file:raw_content_file txt;
    let cmd = "mlx-pp -print-ml " ^ raw_content_file in
    let res = read_command cmd in
    res ^ ";;\n"

let custom_read_input
  : string -> bytes -> int -> int * bool
  = fun _prompt buffer _length ->
    output_string stdout "> "; flush stdout;
    let raw_input = read_line () in
    let processed_input = preprocess raw_input in
    let i_len = String.length processed_input in
    Bytes.blit_string processed_input 0 buffer 0 i_len;
    (i_len, false)

let () =
  Toploop.read_interactive_input := custom_read_input;
  Toploop.initialize_toplevel_env ();
  try Toploop.loop Format.std_formatter
  with Compenv.Exit_with_status 0 -> ()

This toplevel needs the following dune file :

(executable
  (name top)
  (public_name top)
  (modes byte)
  (link_flags -linkall)
  (libraries compiler-libs.toplevel))

and run with dune exec ./top.bc.

Now inside this toplevel, one may run :

> let h s = <h1>(JSX.string s)</h1>;;
# let h s = ((h1 () ~children:[JSX.string s])[@JSX ]);;
Error: Unbound value h1
> 

(Actually, the toplevel turns the initial prompt with > into the translated prompt with #, but then my readers wouldn't be able to know what I wrote in the first place.)

So it only needs an html processor now :) Would html_of_jsx do the job ?

[lafleurdeboum]

Yup, html_of_jsx was needed. A complete toplevel program :

let create_source_tmpfile () =
  let filename = Filename.temp_file "ocaml" ".ml" in
  at_exit (fun () -> try Sys.remove filename with Sys_error _ -> ());
  filename

let read file =
  In_channel.with_open_bin file @@ fun ic ->
    let len = in_channel_length ic in
    let buf = Bytes.create len in
    really_input ic buf 0 len;
    Bytes.unsafe_to_string buf

let write ~file txt =
  Out_channel.with_open_bin file @@ fun oc ->
    output_string oc txt

let read_command cmd =
  let res = create_source_tmpfile () in
  let cmd = Printf.sprintf "%s > %s" cmd res in
  match Sys.command cmd with
  | 0 -> String.trim (read res) 
  | n -> failwith (Printf.sprintf "command %s failed with exit code %d" cmd n)

let preprocess txt =
  if (String.length txt = 0 || txt.[0] = '#') then txt ^ "\n"
  else
    let raw_content_file = create_source_tmpfile () in
    write ~file:raw_content_file txt;
    let res = read_command ("mlx-pp -print-ml " ^ raw_content_file) in
    res ^ ";;\n"

let custom_read_input
  : string -> bytes -> int -> int * bool
  = fun _prompt buffer _length ->
    output_string stdout "+ "; flush stdout;
    let raw_input = read_line () in
    let processed_input = preprocess raw_input in
    let input_length = String.length processed_input in
    Bytes.blit_string processed_input 0 buffer 0 input_length;
    (input_length, false)

let eval_string s =
  let lexbuf = Lexing.from_string s in
  let phrase = !Toploop.parse_toplevel_phrase lexbuf in
  let success = Toploop.execute_phrase true Format.err_formatter phrase in
  ignore success

let () =
  Toploop.initialize_toplevel_env ();
  Findlib.init ();
  Topfind.load_deeply [ "html_of_jsx" ];
  Topfind.load_deeply [ "html_of_jsx.ppx" ];
  eval_string {|#load "pretty_expressive.cma";;|};
  eval_string {|#load "JSX.cma";;|};
  Toploop.read_interactive_input := custom_read_input;
  try Toploop.loop Format.std_formatter
  with Compenv.Exit_with_status 0 ->
    print_string "ciao\n- : tschüßie !\n\n";
    ()

Which desperately needs this dune file :

(executable
  (name top)
  (modes byte)
  (link_flags -linkall)
  (libraries compiler-libs.toplevel findlib.top))

A usage example :

$ dune exec ./top.bc 
/nix/store/k2vm65dbj3rzkj7iplnsnxwqs551zs2w-ocaml5.4.1-pretty_expressive-0.5/lib/ocaml/5.4.1/site-lib/pretty_expressive: added to search path
/nix/store/cdiax588j44r7k3nhiz4xx0vj4hqhhly-ocaml5.4.1-html_of_jsx-0.1.0/lib/ocaml/5.4.1/site-lib/html_of_jsx: added to search path
/nix/store/cdiax588j44r7k3nhiz4xx0vj4hqhhly-ocaml5.4.1-html_of_jsx-0.1.0/lib/ocaml/5.4.1/site-lib/html_of_jsx/ppx: added to search path
/nix/store/cdiax588j44r7k3nhiz4xx0vj4hqhhly-ocaml5.4.1-html_of_jsx-0.1.0/lib/ocaml/5.4.1/site-lib/html_of_jsx/ppx/./ppx.exe --as-ppx: activated
OCaml version 5.4.1
Enter #help;; for help.

+ JSX.render (<p>(JSX.string "let's go !")</p>)
- : string = "<p>let&apos;s go !</p>"
+ ciao
- : tschüßie !

And this answers the initial question.

So now the question is : how useful can this be for your library ? I do think it's nice to be able to poke around with mlx in the toplevel. So this could figure inside the ocaml-mlx' code. Or it could be a discussion somewhere in this repo. Or it could just stay here. It's up to you ; anyway a comment would be welcome.

[davesnx]

Nice exploration @lafleurdeboum, glad you had it working at the end.

Running only utop + mlx by itself might be quite limiting, and adding libraries and all the utop interface is the desired option here.

I would like to have this supported as documentation, rather than as a tool users need to install. There's a way to have mlx installing into the utop lib but unsure if it's a good idea, such as exposing mlx as a library with runtime code:

let () =
  Toploop.parse_toplevel_phrase := Mlx_parser.toplevel_phrase;
  Toploop.parse_use_file := Mlx_parser.use_file

This allows utop -require mlx to work, so your example might become utop -require mlx -require html_of_jsx -require html_of_jsx.pp.

Any thoughts @andreypopp? We might prefer to have a new mlx-utop lib instead of adding this into the core?

[lafleurdeboum]

Hey, great to read you ! Not sure what you mean with Mlx_parser - does it already exist ? Or is it a hint on what could become of this idea ?

[lafleurdeboum]

Oh yes, that must be toplevel_phrase in ./mlx/parser.ml, I suppose. I'm sorry, I'm a bit at loss here - I wrote what's above from outside mlx' database, and I was able to build mlx only once using #34, but now it fails (I'll submit a separate issue). So I'm not able to use Parser.toplevel_phrase ATM. But I would be very interested in using mlx' parser inside down.