samples-android/build.gradle at master · okta/samples-android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    ext {
        compose_ui_version = libs.versions.compose.ui.get()
    }
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath libs.gradle
        classpath libs.kotlin.gradle.plugin
        classpath libs.android.navigation.safe.args
        classpath libs.spotless

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

plugins {
    id 'com.google.dagger.hilt.android' version '2.48.1' apply false
    id 'org.jetbrains.kotlin.android' version '1.9.10' apply false
}

allprojects {
    configureSpotless(it)
}

def configureSpotless(Project project) {
    project.apply plugin: 'com.diffplug.spotless'

    project.spotless {
        format 'misc', {
            target '**/*.gradle', '**/*.md', '**/.gitignore', '**/*.xml', '**/*.json', '**/*.properties', '**/*.yml', '**/*.kt'
            targetExclude '.idea/**', '**/build/**', '.gradle/**'

            trimTrailingWhitespace()
            endWithNewline()

        }
    }

    project.plugins.withId('kotlin-android') {
        project.spotless {
            kotlin {
                target '**/*.kt'
                targetExclude '**/build/**'
                ktlint()
                    .editorConfigOverride([
                        ktlint_disabled_rules : "package-name"
                    ])
                licenseHeaderFile rootProject.file('licenseTemplate.txt')
            }
        }
    }
}