Add domain name to the api gateway

Author: oktaviandi-nugraha

main.tf

@@ -270,3 +270,60 @@ resource "aws_api_gateway_deployment" "RestApiDeploymentv1" {
   rest_api_id = "${aws_api_gateway_rest_api.athauthapi.id}"
   stage_name  = "v1"
 }
+
+resource "aws_acm_certificate" "cert" {
+  domain_name       = "${var.fqdn}"
+  validation_method = "DNS"
+  lifecycle {
+    create_before_destroy = true
+  }
+
+  tags = {
+    Name          = "${var.fqdn}"
+    ProductDomain = "${local.product_domain}"
+    Environment   = "${var.environment}"
+    Description   = "Certificate for ${var.fqdn}"
+    ManagedBy     = "terraform"
+  }
+}
+
+resource "aws_route53_record" "cert_validation" {
+  name    = "${aws_acm_certificate.cert.domain_validation_options.0.resource_record_name}"
+  type    = "${aws_acm_certificate.cert.domain_validation_options.0.resource_record_type}"
+  zone_id = "${var.zone_id}"
+  records = ["${aws_acm_certificate.cert.domain_validation_options.0.resource_record_value}"]
+  ttl     = 60
+}
+
+resource "aws_acm_certificate_validation" "athmgmt_domain" {
+  certificate_arn         = "${aws_acm_certificate.cert.arn}"
+  validation_record_fqdns = ["${aws_route53_record.cert_validation.fqdn}"]
+}
+
+resource "aws_api_gateway_domain_name" "athmgmt_domain" {
+  domain_name              = "${var.fqdn}"
+  regional_certificate_arn = "${aws_acm_certificate_validation.athmgmt_domain.certificate_arn}"
+  security_policy          = "TLS_1_2"
+
+  endpoint_configuration {
+    types = ["REGIONAL"]
+  }
+}
+
+resource "aws_route53_record" "athmgmt_domain" {
+  name    = "${aws_api_gateway_domain_name.athmgmt_domain.domain_name}"
+  type    = "A"
+  zone_id = "${var.zone_id}"
+
+  alias {
+    evaluate_target_health = true
+    name                   = "${aws_api_gateway_domain_name.athmgmt_domain.regional_domain_name}"
+    zone_id                = "${aws_api_gateway_domain_name.athmgmt_domain.regional_zone_id}"
+  }
+}
+
+resource "aws_api_gateway_base_path_mapping" "athmgmt_domain" {
+  api_id      = "${aws_api_gateway_rest_api.athauthapi.id}"
+  stage_name  = "${aws_api_gateway_deployment.RestApiDeploymentv1.stage_name}"
+  domain_name = "${aws_api_gateway_domain_name.athmgmt_domain.domain_name}"
+}

variables.tf

@@ -231,3 +231,13 @@ variable "lambda_timeout" {
   type        = "string"
   description = "The timeout of lambda execution"
 }
+
+variable "fqdn" {
+  type        = "string"
+  description = "FQDN of the api gateway"
+}
+
+variable "zone_id" {
+  type        = "string"
+  description = "Route 53 zone id"
+}