chore(nix): re-organize nix packaging

Instead of adding patches on top of unlob package available on nixpkgs,
we keep our own package.nix version here so that it's easy to add new
third party dependencies that new handlers may require.

It also makes it easier to upstream it since we just have to submit the
package.nix file to nixpkgs.

Author: qkaiser

Diff for: overlay.nix

@@ -8,40 +8,5 @@ final: prev:
     nativeCheckInputs = (super.nativeCheckInputs or [ ]) ++ [ final.which ];
   });
 
-  unblob =
-    let
-      pyproject_toml = (builtins.fromTOML (builtins.readFile ./pyproject.toml));
-      version = pyproject_toml.project.version;
-    in
-    (prev.unblob.override { e2fsprogs = final.e2fsprogs-nofortify; }).overridePythonAttrs (super: rec {
-      inherit version;
-
-      src = final.nix-filter {
-        root = ./.;
-        include = [
-          "Cargo.lock"
-          "Cargo.toml"
-          "pyproject.toml"
-          "python"
-          "rust"
-          "tests"
-          "README.md"
-        ];
-      };
-
-      # remove this when packaging changes are upstreamed
-      cargoDeps = final.rustPlatform.importCargoLock {
-        lockFile = ./Cargo.lock;
-      };
-
-      nativeBuildInputs = with final.rustPlatform; [
-        cargoSetupHook
-        maturinBuildHook
-      ];
-
-      # override disabling of 'test_all_handlers[filesystem.extfs]' from upstream
-      pytestFlagsArray = [
-        "--no-cov"
-      ];
-    });
+  unblob = final.callPackage ./package.nix { };
 }

Diff for: package.nix

@@ -0,0 +1,129 @@
+{
+  lib,
+  python3,
+  fetchFromGitHub,
+  makeWrapper,
+  e2fsprogs-nofortify,
+  jefferson,
+  lz4,
+  lziprecover,
+  lzop,
+  p7zip,
+  nix-filter,
+  sasquatch,
+  sasquatch-v4be,
+  simg2img,
+  ubi_reader,
+  unar,
+  zstd,
+  versionCheckHook,
+  rustPlatform,
+}:
+
+let
+  # These dependencies are only added to PATH
+  runtimeDeps = [
+    e2fsprogs-nofortify
+    jefferson
+    lziprecover
+    lzop
+    p7zip
+    sasquatch
+    sasquatch-v4be
+    ubi_reader
+    simg2img
+    unar
+    zstd
+    lz4
+  ];
+  pyproject_toml = (builtins.fromTOML (builtins.readFile ./pyproject.toml));
+  version = pyproject_toml.project.version;
+in
+python3.pkgs.buildPythonApplication rec {
+  pname = "unblob";
+  pyproject = true;
+  disabled = python3.pkgs.pythonOlder "3.9";
+  inherit version;
+  src = nix-filter {
+    root = ./.;
+    include = [
+      "Cargo.lock"
+      "Cargo.toml"
+      "pyproject.toml"
+      "python"
+      "rust"
+      "tests"
+      "README.md"
+    ];
+  };
+
+  strictDeps = true;
+
+  build-system = with python3.pkgs; [ poetry-core ];
+
+  dependencies = with python3.pkgs; [
+    arpy
+    attrs
+    click
+    cryptography
+    dissect-cstruct
+    lark
+    lief.py
+    python3.pkgs.lz4 # shadowed by pkgs.lz4
+    plotext
+    pluggy
+    pyfatfs
+    pyperscan
+    python-magic
+    pyzstd
+    rarfile
+    rich
+    structlog
+    treelib
+    unblob-native
+  ];
+
+  cargoDeps = rustPlatform.importCargoLock {
+    lockFile = ./Cargo.lock;
+  };
+
+  nativeBuildInputs = with rustPlatform; [
+    cargoSetupHook
+    maturinBuildHook
+    makeWrapper
+  ];
+
+  # These are runtime-only CLI dependencies, which are used through
+  # their CLI interface
+  pythonRemoveDeps = [
+    "jefferson"
+    "ubi-reader"
+  ];
+
+  pythonImportsCheck = [ "unblob" ];
+
+  makeWrapperArgs = [
+    "--prefix PATH : ${lib.makeBinPath runtimeDeps}"
+  ];
+
+  nativeCheckInputs =
+    with python3.pkgs;
+    [
+      pytestCheckHook
+      pytest-cov
+      versionCheckHook
+    ]
+    ++ runtimeDeps;
+
+  versionCheckProgramArg = "--version";
+
+  pytestFlagsArray = [
+    "--no-cov"
+  ];
+
+  passthru = {
+    # helpful to easily add these to a nix-shell environment
+    inherit runtimeDeps;
+  };
+
+}

Diff for: shell.nix

@@ -4,7 +4,7 @@ let
     ./flake.lock
     ./flake.nix
     ./overlay.nix
-    ./nix
+    ./package.nix
   ];
 
   lock = builtins.fromJSON (builtins.readFile ./flake.lock);