opensearch-hadoop/hive/build.gradle at eda05d78850d06e820f7ddcbeb1f8c9ddf49d008 · opensearch-project/opensearch-hadoop · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
import org.opensearch.gradle.info.BuildParams

apply plugin: 'opensearch.hadoop.build.integration'

description = "OpenSearch Hadoop Hive"

evaluationDependsOn(':opensearch-hadoop-mr')

configurations {
    embedded {
        transitive = false
        canBeResolved = true
    }
    implementation {
        extendsFrom project.configurations.embedded
    }
}

configurations.all {
    resolutionStrategy.eachDependency { DependencyResolveDetails details ->
        if (details.requested.group == 'org.apache.hadoop') {
            details.useVersion project.ext.hadoopVersion
        }
    }
}

dependencies {
    embedded(project(":opensearch-hadoop-mr"))

    implementation("org.apache.hive:hive-service:$hiveVersion") {
        exclude module: "log4j-slf4j-impl"
    }
    implementation("org.apache.hive:hive-exec:$hiveVersion")
    implementation("org.apache.hive:hive-metastore:$hiveVersion")
    implementation("commons-logging:commons-logging:1.3.6")
    implementation("javax.xml.bind:jaxb-api:2.3.1")

    testImplementation(project(":test:shared"))
    testImplementation("org.apache.hive:hive-service:$hiveVersion") {
        exclude module: "log4j-slf4j-impl"
    }
    testImplementation("org.apache.hive:hive-jdbc:$hiveVersion") {
        exclude module: "log4j-slf4j-impl"
    }
    testImplementation("com.fasterxml.jackson.core:jackson-databind:2.21.4")

    itestImplementation(project(":test:shared"))
    itestImplementation("org.apache.hive:hive-service:$hiveVersion") {
        exclude module: "log4j-slf4j-impl"
    }
    itestImplementation("org.apache.hive:hive-jdbc:$hiveVersion") {
        exclude module: "log4j-slf4j-impl"
    }
    itestImplementation("org.apache.tez:tez-dag:0.9.2")
    itestImplementation("com.fasterxml.jackson.core:jackson-databind:2.21.4")

    additionalSources(project(":opensearch-hadoop-mr"))
    javadocSources(project(":opensearch-hadoop-mr"))
}

tasks.named("test").configure {
    onlyIf { JavaVersion.current() >= JavaVersion.VERSION_16 }
    jvmArgs "--add-opens=java.base/java.io=ALL-UNNAMED" // Needed for IOUtils's BYTE_ARRAY_BUFFER reflection
    jvmArgs "--add-opens=java.base/java.net=ALL-UNNAMED" // Needed for org.apache.hadoop.hive.common.StringInternUtils
}

jar {
    dependsOn(project.configurations.embedded)
    from(project.configurations.embedded.collect { it.isDirectory() ? it : zipTree(it)}) {
        include "org/opensearch/hadoop/**"
        include "opensearch-hadoop-build.properties"
        include "META-INF/services/*"
    }
}

def hiveSiteProperties = ['testSeed': BuildParams.testSeed]
processItestResources {
    filesMatching("**/hive-site.xml") {
        expand(hiveSiteProperties)
    }
}

itestJar {
    dependsOn(project.configurations.embedded)
    from(project.configurations.embedded.collect { it.isDirectory() ? it : zipTree(it)}) {
        include "org/opensearch/hadoop/**"
        include "opensearch-hadoop-build.properties"
        include "META-INF/services/*"
    }
}