Change Mini TOC level in PDF (XSL:FO/FOP)

[stefan-jung]

Hi,

I use a mini TOC (yellow highlight). This is generated with the template <xsl:template match="*" mode="createMiniToc"> from the commons.xsl file. I only get entries for the first level. To be honest, I do not understand the code. Could you help me to get entries for deeper topic levels? Unfortunately I cannot change the map or topic structure.

Test files: toc-levels.zip

Update 1:
I see that this question has been asked by Leigh White on groups.io a few years ago already https://dita-users.groups.io/g/main/message/24927

Update 2:
I see that @chrispy-snps has crafted a new <minitoc> element and processing in this plugin: https://github.com/chrispy-snps/DITA-mini-toc-element

[stefan-jung]

The solution is to adjust the XPath of the following template.

This line ...

<xsl:apply-templates select="*[contains(@class, ' topic/topic ')]" mode="in-this-chapter-list"/>

... has to be changed to ...

<xsl:apply-templates select="descendant::*[contains(@class, ' topic/topic ')]" mode="in-this-chapter-list"/>

. The full template now looks like this:

<xsl:template match="*" mode="createMiniToc">
    <fo:table xsl:use-attribute-sets="__toc__mini__table">
        <fo:table-column xsl:use-attribute-sets="__toc__mini__table__column_1"/>
        <fo:table-column xsl:use-attribute-sets="__toc__mini__table__column_2"/>
        <fo:table-body xsl:use-attribute-sets="__toc__mini__table__body">
            <fo:table-row>
                <fo:table-cell>
                    <fo:block xsl:use-attribute-sets="__toc__mini">
                        <xsl:if test="*[contains(@class, ' topic/topic ')]">
                            <fo:block xsl:use-attribute-sets="__toc__mini__header">
                                <xsl:call-template name="getVariable">
                                    <xsl:with-param name="id" select="'Mini Toc'"/>
                                </xsl:call-template>
                            </fo:block>
                            <fo:list-block xsl:use-attribute-sets="__toc__mini__list">
                                <xsl:apply-templates select="*[contains(@class, ' topic/topic ')]" mode="in-this-chapter-list"/>
                            </fo:list-block>
                        </xsl:if>
                    </fo:block>
                </fo:table-cell>
                <fo:table-cell xsl:use-attribute-sets="__toc__mini__summary">
                    <!--Really, it would be better to just apply-templates, but the attribute sets for shortdesc, body
                    and abstract might indent the text.  Here, the topic body is in a table cell, and should
                    not be indented, so each element is handled specially.-->
                    <fo:block>
                        <xsl:apply-templates select="*[contains(@class, ' topic/titlealts ')]"/>
                        <xsl:if test="
                                *[contains(@class, ' topic/shortdesc ')
                                or contains(@class, ' topic/abstract ')]/node()">
                            <fo:block xsl:use-attribute-sets="p">
                                <xsl:apply-templates select="
                                        *[contains(@class, ' topic/shortdesc ')
                                        or contains(@class, ' topic/abstract ')]/node()"/>
                            </fo:block>
                        </xsl:if>
                        <xsl:apply-templates select="*[contains(@class, ' topic/body ')]/*"/>
                        <xsl:apply-templates select="*[contains(@class, ' ditaot-d/ditaval-endprop ')]"/>

                        <xsl:if test="
                                *[contains(@class, ' topic/related-links ')]//
                                *[contains(@class, ' topic/link ')][not(@role) or @role != 'child']">
                            <xsl:apply-templates select="*[contains(@class, ' topic/related-links ')]"/>
                        </xsl:if>

                    </fo:block>
                </fo:table-cell>
            </fo:table-row>
        </fo:table-body>
    </fo:table>
</xsl:template>