Completion at point for bibtex-mode?

[apc]

Thanks again for a great package.

This may be outside the scope of citar, but I was wondering if you had thought of making use of the citar data to enable completion at point when editing bibtex files themselves. This would help ensure some uniformity in one's bibtex files, especially with capitalization for journal titles, use or not of middle initial for author names, etc.

I just played around with this for a bit and came up with something that seems to work, but I'm sure there are more elegant ways of accomplishing this.

This is what I got:

(defvar +citar-completion-fields
  '("journaltitle" "author" "editor" "publisher" "location" "address" "booktitle")
  "List of BibTeX fields (canonical) for which to provide completion from the citar cache.")

(defun +citar--field-at-point ()
  "Return the normalized field name on the current line, or nil if none."
  (save-excursion
    (beginning-of-line)
    (when (re-search-forward "\\(\\w+\\)\\s-*=" (line-end-position) t)
      (string-remove-prefix "opt" (downcase (match-string 1))))))

(defun +citar--bounds-of-field-value ()
  "Return (START . END) bounds for the BibTeX field value around point, or nil."
  (save-excursion
    (let* ((initial-point (point))
           (open (and (re-search-backward "[{\"]" (line-beginning-position) t)
                      (1+ (point))))
           (close (and open
                       (goto-char open)
                       (re-search-forward "[}\"]" (line-end-position) t)
                       (1- (point)))))
      (when (and open close (>= close open))
        (cons open close)))))

(defun +citar--field-value-completion-at-point ()
  "Provide completion for certain BibTeX fields using values in citar's database."
  (when (derived-mode-p 'bibtex-mode)
    (let ((field (+citar--field-at-point)))
      (when (member field +citar-completion-fields)
        (let ((bounds (+citar--bounds-of-field-value))
              (candidates (+citar--collect-field-values field)))
          (when (and bounds candidates)
            (list (car bounds) (cdr bounds) candidates :exclusive 'no)))))))

(defun +citar--collect-field-values (field)
  "Collect all unique, non-trivial values of FIELD from the citar cache."
  (let* ((canonical (+citar--canonical-field field))
         (values (+citar--get-field-values (intern canonical))))
    (seq-filter (lambda (val)
                  (and val
                       (> (length (string-trim val)) 2)))
                (sort values #'string<))))

(defun +citar--canonical-field (field)
  "Return canonical field name for FIELD, e.g., merging 'journaltitle' and 'journal'.

This should eventually take values from a list of the form (FIELD LIST), where LIST is a list of aliases for FIELD, if any."
  (pcase field
    ((or "journaltitle" "journal") "journaltitle")
    (_ field)))

(defun +citar--get-field-values (field)
  "Return a lit of unique non-empty values for FIELD from the BibTeX entries cached by `citar`."
  (let ((entries (citar-cache--entries (citar--bibliographies))))
    (if (not entries)
        (progn
          (message "Error: BibTeX cache is empty or unavailable.")
          nil)
      (let ((field-key (symbol-name field))
            (values '()))
        (maphash
         (lambda (_key entry)
           (let ((field-value (cdr (assoc field-key entry))))
             (cond
              ((and (listp field-value) field-value)
               (dolist (v field-value)
                 (when (and v (not (string-empty-p v)))
                   (push (string-trim v) values)))) ; Ensure each value is a string
              ((and (stringp field-value) (not (string-empty-p field-value)))
               (push (string-trim field-value) values))))) ; Ensure value is a string
         entries)
        (delete-dups values)))))

(defun +citar--enable-completion ()
  "Enable field value completion in bibtex-mode."
  (add-hook 'completion-at-point-functions
            #'+citar--field-value-completion-at-point
            0 t))

(add-hook 'bibtex-mode-hook #'+citar--enable-completion)

I haven't tested this very thoroughly, but so far it does what I need!

Any suggestions for improvement would be welcome, too, even if you think nothing like this should be part of citar. Happy to add it to the wiki also if you think that would be useful.

[bdarcus]

I'm not really sure whether it should be in scope or not, though generally if in doubt I'd vote for not.

But nice work!

Maybe you could add it to the wiki?

[apc]

Done! I tweaked it a bit more, and now the citar integration is optional. Feel free to do what you will with it!