pass binary plan to run-all command

[chell0veck]

Please suggest how I can pass generated binary plan file to run-all command.

Reasons:

• part of CD flow
• plan is safe and failed apply can result into inconsistent env
• plan and apply without binary is overlapping

Here hooks to generate binary I use

terraform {

  extra_arguments "generate_plan_binary" {
    commands  = ["plan"]
    arguments = [
      "--out=${get_terragrunt_dir()}/${basename(get_terragrunt_dir())}.plan.bin"
    ]
  }

  before_hook "render_metadata" {
    commands    = ["plan"]
    execute     = ["bash", "-c", "terragrunt render-json --with-metadata"]
    working_dir = get_terragrunt_dir()
  }

  after_hook "generate_plan_json" {
    commands    = ["plan"]
    execute     = [
      "bash", "-c",
      "terragrunt show -json ${basename(get_terragrunt_dir())}.plan.bin | jq > ${basename(get_terragrunt_dir())}.plan.json"
    ]
    working_dir = get_terragrunt_dir()
  }

}

Now I need to come up with idea how to pass it to run-all command.

---

Tracked in ticket #110159

[denis256]

Hi,
Depending on the repository structure, I would extract terraform block in the parent terragrunt.hcl and include it in modules:

include "root" {
  path = find_in_parent_folders()
}

References:

https://terragrunt.gruntwork.io/docs/features/keep-your-terragrunt-architecture-dry/#using-exposed-includes-to-override-common-configurations

https://terragrunt.gruntwork.io/docs/reference/config-blocks-and-attributes/#include

[chell0veck]

Hi,

Still confused.

Considering we have tree with 4 modules, each has generated plan file with individual name.
Ho to pass them to tg run-all apply.

Thank you

[denis256]

Hi,
basically, arguments to apply are passed to Terraform, like terragrunt run-all apply terraform.tfplan
To have "terrafom.tfplan" in working directory, can be used before_hook to copy plan file.

terraform {

  # collect plan files
  extra_arguments "generate_plan_binary" {
    commands  = ["plan"]
    arguments = [
      "--out=${get_repo_root()}/discussion-710/plan/${basename(get_terragrunt_dir())}.plan.bin"
    ]
  }

  # copy plan files before apply
  before_hook "copy_plan" {
    commands    = ["apply"]
    execute     = [
      "bash", "-c",
      "cp ${get_repo_root()}/discussion-710/plan/${basename(get_terragrunt_dir())}.plan.bin terraform.tfplan"
    ]
    working_dir = get_terragrunt_dir()
  }

}

Simplified end-to-end example in:
https://github.com/denis256/terragrunt-tests/tree/master/discussion-710