TropicalGeometry: add roots(::PolyRingElem{<:TropicalSemiringElem}) (#4781)

Author: YueRen

Diff for: docs/src/TropicalGeometry/semiring.md

@@ -23,5 +23,6 @@ convention(T::TropicalSemiring{typeof(min)})
 Other functions related to `TropicalSemiring`, matrices, and polynomials thereover include:
 ```@docs
 det(A::AbstractAlgebra.Generic.MatSpaceElem{<: Oscar.TropicalSemiringElem})
+roots(f::PolyRingElem{TropicalSemiringElem{minOrMax}}) where {minOrMax <: Union{typeof(min),typeof(max)}}
 tropical_polynomial(f::MPolyRingElem, nu::TropicalSemiringMap)
 ```

Diff for: src/TropicalGeometry/poly.jl

@@ -78,11 +78,69 @@ end
 ###
 #  Disabling ideals in tropical polyomial rings
 ###
-function MPolyIdeal(R::Ring, g::Vector{Generic.MPoly{TropicalSemiringElem{minOrMax}}}) where {minOrMax}
+function MPolyIdeal(::Ring, ::Vector{Generic.MPoly{TropicalSemiringElem{minOrMax}}}) where {minOrMax <: Union{typeof(min),typeof(max)}}
     error("Ideals over tropical semirings not supported")
 end
 
 
+###
+#  Roots of univariate tropical polynomials
+###
+"""
+    roots(f::PolyRingElem{<:TropicalSemiringElem})
+
+Return the tropical roots of a univariate tropical polynomial `f`, i.e., the variable values where
+the min or max is attained at least twice.
+
+# Examples
+
+```jldoctest
+julia> R,x = polynomial_ring(tropical_semiring(min),:x)
+(Univariate polynomial ring in x over min tropical semiring, x)
+
+julia> f = 1*x^2+x+0
+(1)*x^2 + x + (0)
+
+julia> roots(f)
+2-element Vector{QQFieldElem}:
+ 0
+ -1
+
+julia> R,x = polynomial_ring(tropical_semiring(max),:x)
+(Univariate polynomial ring in x over max tropical semiring, x)
+
+julia> f = 1*x^2+x+0
+(1)*x^2 + x + (0)
+
+julia> roots(f)
+1-element Vector{QQFieldElem}:
+ -1//2
+
+```
+"""
+function roots(f::PolyRingElem{TropicalSemiringElem{minOrMax}}) where {minOrMax <: Union{typeof(min),typeof(max)}}
+    # Construct either the lower (min) or upper (max) convex hull of degrees and coefficients
+    # Example: for min(1+2x,x,0) it is conv({(2,1), (1,0), (0,0)}) + RR_{>=0}*(0,1)
+    #          for max(1+2x,x,0) it is conv({(2,1), (1,0), (0,0)}) + RR_{>=0}*(0,-1)
+    # Note: univariate polynomials also enumerate over zero coefficients, necessitating !iszero(c) below
+    valsAndExps = [ QQFieldElem[first(d),QQ(c)] for (d,c) in zip(exponents(f),coefficients(f)) if !iszero(c) ]
+
+    if length(valsAndExps)<2
+        return QQFieldElem[] # return empty set if f not at least binomial
+    end
+
+    s = minOrMax==typeof(min) ? 1 : -1 # +1 if min, -1 if max
+    hullDirection = s*[0 1]
+    newtonPolygon = convex_hull(valsAndExps,hullDirection)
+
+    # The negated slopes of the lower (min) or upper (max) edges are when function value is attained at least twice
+    # Example: for min(1+2x,x,0) it is -1 and 0, for max(1+2x,x,0) it is -1/2
+    F = affine_inequality_matrix(facets(newtonPolygon))
+    negatedSlopes = [ F[i,2]/F[i,3] for i in 1:nrows(F) if s*F[i,3]<0 ]
+    return negatedSlopes
+end
+
+
 
 ################################################################################
 #

Diff for: test/TropicalGeometry/poly.jl

@@ -8,4 +8,9 @@
         @test issetequal(coefficients(tropf),tropical_semiring(nu).([0,1,2]))
         @test issetequal(exponents(tropf),[[1,0],[0,1],[0,0]])
     end
+
+    @testset "roots(::PolyRingElem{<:TropicalSemiringElem}) edge cases" begin
+        R, t = polynomial_ring(tropical_semiring(), "t")
+        @test isempty(roots(t))
+    end
 end