pcloud-networking-java/publish-mavencentral.gradle at master · pCloud/pcloud-networking-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
apply plugin: 'maven-publish'
apply plugin: 'signing'
apply from: rootProject.file('publishing.gradle')

if (project.hasProperty("android")) { // Android libraries

    tasks.register('sourcesJar', Jar) {
        archiveClassifier.convention('sources')
        archiveClassifier.set('sources')
        from android.sourceSets.main.java.srcDirs
    }

    tasks.register('javadoc', Javadoc) {
        failOnError = true
        source = android.sourceSets.main.java.srcDirs
        classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
    }
} else { // Java libraries
    tasks.register('sourcesJar', Jar) {
        dependsOn classes
        archiveClassifier.convention('sources')
        archiveClassifier.set('sources')
        from sourceSets.main.allSource
    }
}

tasks.register('javadocJar', Jar) {
    if (project.hasProperty("android")) {
        dependsOn "javadoc"
        from javadoc.destinationDir
    }
    archiveClassifier.convention('javadoc')
    archiveClassifier.set('javadoc')
}

artifacts {
    archives javadocJar
    archives sourcesJar
}

group = project.getPublishProperty('groupId')
version = project.getPublishProperty('versionName')

ext["signing.keyId"] = ''
ext["signing.password"] = ''
ext["signing.secretKeyRingFile"] = ''


File secretPropsFile = project.rootProject.file('local.properties')
if (secretPropsFile.exists()) {
    Properties p = new Properties()
    p.load(new FileInputStream(secretPropsFile))
    p.each { name, value ->
        ext[name] = value
    }
} else {
    ext["signing.keyId"] = System.getenv('SIGNING_KEY_ID')
    ext["signing.password"] = System.getenv('SIGNING_PASSWORD')
    ext["signing.secretKeyRingFile"] = System.getenv('SIGNING_SECRET_KEY_RING_FILE')
}

afterEvaluate {
    publishing {
        publications {
            release(MavenPublication) {

                groupId = getPublishProperty('groupId')
                version = getPublishProperty('versionName')
                if (project.plugins.findPlugin("com.android.library")) {
                    javadoc.classpath += files(android.libraryVariants.collect { variant ->
                        variant.javaCompile.classpath.files
                    })
                    from components.release
                } else {
                    from components.java
                }

                artifact sourcesJar
                artifact javadocJar

                pom {
                    name = getPublishProperty('libraryName')
                    description = getPublishProperty('description')
                    url = getPublishProperty('siteUrl')
                    license {
                        name = getPublishProperty('licenseName')
                        url = getPublishProperty('licenseUrl')
                    }
                    developer {
                        name = getPublishProperty('developerName')
                        email = getPublishProperty('developerEmail')
                        organization = getPublishProperty('developerName')
                        organizationUrl = getPublishProperty('developerUrl')
                    }
                    scm {
                        connection = getPublishProperty('scmUrl')
                        developerConnection = getPublishProperty('scmUrl')
                        url = getPublishProperty('siteUrl')
                    }
                }
            }
        }
    }
}

signing {
    sign publishing.publications
}