Skree/build.gradle at master · packet-loss-gaming/Skree · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
// These imports are needed further down
// -------------------------------------
import org.jooq.util.GenerationTool

import javax.xml.bind.JAXB

apply plugin: 'java'

buildscript {
    repositories {
        mavenCentral()
        jcenter()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = 'sonatype-snapshots'
            url = 'https://oss.sonatype.org/content/repositories/snapshots'
        }
    }

    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
        classpath 'org.jooq:jooq-codegen:3.6.0'
        classpath group: 'org.mariadb.jdbc', name: 'mariadb-java-client', version: '1.3.+'
    }
}

apply plugin: 'checkstyle'
apply plugin: 'net.minecraftforge.gradle.forge'

configurations {
    shade
    compile.extendsFrom shade
}

minecraft {
    version = "1.12.2-14.23.4.2705"
    runDir = "run"
    mappings = "stable_39"
}

repositories {
    mavenCentral()
    jcenter()
    maven {
        name 'Skelril Repository'
        url 'http://service.skelril.com/maven/'
    }
    maven {
        name 'Sponge maven repo'
        url 'http://repo.spongepowered.org/maven'
    }
    maven {
        name 'sk89q-repo'
        url 'http://maven.sk89q.com/repo/'
    }

    mavenLocal()
}

dependencies {
    compile group: 'org.jooq', name: 'jooq', version: '3.9.2'
    compile group: 'org.flywaydb', name: 'flyway-core', version: '4.1.2'
    compile group: 'com.skelril', name: 'Open Boss', version: '2.0-SNAPSHOT'
    compile group: 'com.nearce', name: 'GameChatterServer-Sponge', version: '1.0-SNAPSHOT'
    compile group: 'com.sk89q.worldedit', name: 'worldedit-sponge', version: '7.0.0-SNAPSHOT'
    compile group: 'org.spongepowered', name: 'spongeapi', version: '7.+'

    shade group: 'com.mitchellbosecke', name: 'pebble', version: '2.1.0'

    runtime group: 'org.mariadb.jdbc', name: 'mariadb-java-client', version: '1.3.3'
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8
version = '1.0'

sourceSets {
    main {
        resources.srcDirs = ["assets/Primary", "src/main/resources"]
    }
}

processResources {
    rename '(.+_at.cfg)', 'META-INF/$1'
}

jar {
    manifest {
        attributes 'FMLAT': 'FMLSkree_at.cfg'
    }
    configurations.shade.each { dep ->
        from(project.zipTree(dep)){
            exclude 'META-INF', 'META-INF/**'
        }
    }
}

tasks.withType(Checkstyle) {
    exclude '**/skree/db/schema/**'
}

task codegen << {
    println 'Generating new schema classes...'
    def writer = new StringWriter()
    def xml = new groovy.xml.MarkupBuilder(writer)
            .configuration('xmlns': 'http://www.jooq.org/xsd/jooq-codegen-3.6.0.xsd') {
        jdbc() {
            driver('org.mariadb.jdbc.Driver')
            url('jdbc:mariadb://localhost:3306')
            user('mc_db_dev')
            password('mc_db_dev')
        }
        generator() {
            database() {
                name('org.jooq.util.mariadb.MariaDBDatabase')
                inputSchema('mc_db')
            }
            generate() {
            }
            target() {
                packageName('com.skelril.skree.db.schema')
                directory('src/main/java')
            }
        }
    }

    GenerationTool.main(
            JAXB.unmarshal(new StringReader(writer.toString()), org.jooq.util.jaxb.Configuration.class)
    )
}