pagopa
diff --git a/‎src/cloudo/.terraform.lock.hcl‎
Lines changed: 81 additions & 0 deletions b/‎src/cloudo/.terraform.lock.hcl‎
Lines changed: 81 additions & 0 deletions
diff --git a/‎src/cloudo/00_data.tf‎
Lines changed: 44 additions & 0 deletions b/‎src/cloudo/00_data.tf‎
Lines changed: 44 additions & 0 deletions
diff --git a/‎src/cloudo/01_networks.tf‎
Lines changed: 16 additions & 0 deletions b/‎src/cloudo/01_networks.tf‎
Lines changed: 16 additions & 0 deletions
diff --git a/‎src/cloudo/01_secrets.tf‎
Lines changed: 5 additions & 0 deletions b/‎src/cloudo/01_secrets.tf‎
Lines changed: 5 additions & 0 deletions
diff --git a/‎src/cloudo/01_tags.tf‎
Lines changed: 5 additions & 0 deletions b/‎src/cloudo/01_tags.tf‎
Lines changed: 5 additions & 0 deletions
diff --git a/‎src/cloudo/02_cloudo.tf‎
Lines changed: 86 additions & 0 deletions b/‎src/cloudo/02_cloudo.tf‎
Lines changed: 86 additions & 0 deletions
diff --git a/‎src/cloudo/99_locals.tf‎
Lines changed: 6 additions & 0 deletions b/‎src/cloudo/99_locals.tf‎
Lines changed: 6 additions & 0 deletions
diff --git a/‎src/cloudo/99_main.tf‎
Lines changed: 24 additions & 0 deletions b/‎src/cloudo/99_main.tf‎
Lines changed: 24 additions & 0 deletions
diff --git a/‎src/cloudo/99_outputs.tf‎ b/‎src/cloudo/99_outputs.tf‎
diff --git a/‎src/cloudo/99_variables.tf‎
Lines changed: 108 additions & 0 deletions b/‎src/cloudo/99_variables.tf‎
Lines changed: 108 additions & 0 deletions
@@ -0,0 +1,44 @@
+
+data "azurerm_key_vault" "key_vault" {
+  name                = "${local.product}-kv"
+  resource_group_name = "${local.product}-sec-rg"
+}
+
+data "azurerm_key_vault_secret" "github_pat" {
+  name         = "payments-cloud-github-bot-pat"
+  key_vault_id = data.azurerm_key_vault.key_vault.id
+}
+
+data "azurerm_key_vault_secret" "cloudo_slack_token" {
+  name         = "cloudo-slack-token"
+  key_vault_id = data.azurerm_key_vault.key_vault.id
+
+}
+
+data "azurerm_key_vault_secret" "opsgenie_token" {
+  count        = var.env_short == "p" ? 1 : 0
+  name         = "opsgenie-webhook-token"
+  key_vault_id = data.azurerm_key_vault.key_vault.id
+}
+
+
+data "azurerm_application_insights" "app_insight" {
+  name                = var.application_insisght_name
+  resource_group_name = var.application_insisght_resource_group_name
+}
+
+
+data "azurerm_kubernetes_cluster" "aks_weu" {
+  name                = "${local.product_region}-${var.env}-aks"
+  resource_group_name = "${local.product_region}-${var.env}-aks-rg"
+}
+
+data "azurerm_kubernetes_cluster" "aks_itn" {
+  name                = "${local.product_ita}-${var.env}-aks"
+  resource_group_name = "${local.product_ita}-${var.env}-aks-rg"
+}
+
+data "azurerm_virtual_network" "network_tools_vnet" {
+  name                = "${var.prefix}-${var.env_short}-${var.location_short_ita}-spoke-tools-vnet"
+  resource_group_name = "${var.prefix}-${var.env_short}-${var.location_short_ita}-network-hub-spoke-rg"
+}
@@ -0,0 +1,16 @@
+data "azurerm_subnet" "vpn_subnet" {
+  name                 = "GatewaySubnet"
+  resource_group_name  = "${local.product}-vnet-rg"
+  virtual_network_name = "${local.product}-vnet"
+}
+
+data "azurerm_private_dns_zone" "private_endpoint_dns_zone" {
+  name                = "privatelink.azurewebsites.net"
+  resource_group_name = "${local.product}-vnet-rg"
+}
+
+data "azurerm_subnet" "private_endpoint_snet" {
+  name                 = "${local.product}-common-private-endpoint-snet"
+  resource_group_name  = "${local.product}-vnet-rg"
+  virtual_network_name = "${local.product}-vnet"
+}
@@ -0,0 +1,5 @@
+
+data "azurerm_key_vault_secret" "google_client_id" {
+  key_vault_id = data.azurerm_key_vault.key_vault.id
+  name         = "cloudo-google-client-id"
+}
@@ -0,0 +1,5 @@
+module "tag_config" {
+  source      = "../tag_config"
+  domain      = "cloudo"
+  environment = var.env
+}
@@ -0,0 +1,86 @@
+
+resource "azurerm_resource_group" "rg" {
+  name     = "${var.prefix}-${var.env_short}-${var.location_short_ita}-cloudo-rg"
+  location = var.location_ita
+
+  tags = module.tag_config.tags
+}
+
+module "cloudo" {
+  source = "git::https://github.com/pagopa/payments-ClouDO.git//src/core/iac?ref=47479c40b3161ff9348ae3f114ce19c7d4a8a7d9"
+
+  prefix                    = local.product
+  product_name              = var.prefix
+  env                       = var.env
+  location                  = var.location_ita
+  resource_group_name       = azurerm_resource_group.rg.name
+  application_insights_name = data.azurerm_application_insights.app_insight.name
+  application_insights_rg   = data.azurerm_application_insights.app_insight.resource_group_name
+  subscription_id           = data.azurerm_subscription.current.subscription_id
+  vnet_name                 = data.azurerm_virtual_network.network_tools_vnet.name
+  vnet_rg                   = data.azurerm_virtual_network.network_tools_vnet.resource_group_name
+
+  vpn_subnet_id                  = data.azurerm_subnet.vpn_subnet.id
+  private_endpoint_dns_zone_name = data.azurerm_private_dns_zone.private_endpoint_dns_zone.name
+
+  cloudo_google_sso_integration_client_id = data.azurerm_key_vault_secret.google_client_id.value
+
+  github_repo_info = {
+    repo_name    = "pagopa/pagopa-infra"
+    repo_branch  = "main"
+    runbook_path = "src/cloudo/runbooks"
+  }
+
+  aks_integration = {
+    weu = {
+      cluster_id = data.azurerm_kubernetes_cluster.aks_weu.id
+    },
+    itn = {
+      cluster_id = data.azurerm_kubernetes_cluster.aks_itn.id
+    }
+  }
+
+  approval_runbook = {
+    ttl_min = "120"
+  }
+
+  slack_integration = {
+    channel = "#cloudo-${var.prefix}-${var.env}"
+    token   = data.azurerm_key_vault_secret.cloudo_slack_token.value
+  }
+
+  opsgenie_api_key = var.env_short == "p" ? data.azurerm_key_vault_secret.opsgenie_token.0.value : ""
+
+  schemas = file("${path.module}/env/${var.env}/schemas.json.tpl")
+
+  orchestrator_image = {
+    image_name        = var.cloudo_orchestrator.image_name
+    image_tag         = var.cloudo_orchestrator.image_tag
+    registry_url      = var.cloudo_orchestrator.registry_url
+    registry_username = var.cloudo_orchestrator.registry_username
+    registry_password = data.azurerm_key_vault_secret.github_pat.value
+  }
+
+  workers_config = {
+    workers = {
+      "generic-worker" = "generic"
+    }
+    image_name        = var.cloudo_worker.image_name
+    image_tag         = var.cloudo_worker.image_tag
+    registry_url      = var.cloudo_worker.registry_url
+    registry_username = var.cloudo_worker.registry_username
+    registry_password = data.azurerm_key_vault_secret.github_pat.value
+  }
+
+  enable_ui = true
+  ui_image = {
+    image_name        = var.cloudo_ui.image_name
+    image_tag         = var.cloudo_ui.image_tag
+    registry_url      = var.cloudo_ui.registry_url
+    registry_username = var.cloudo_ui.registry_username
+    registry_password = data.azurerm_key_vault_secret.github_pat.value
+  }
+
+  tags = module.tag_config.tags
+}
+
@@ -0,0 +1,6 @@
+
+locals {
+  product        = "${var.prefix}-${var.env_short}"
+  product_region = "${var.prefix}-${var.env_short}-${var.location_short}"
+  product_ita    = "${var.prefix}-${var.env_short}-${var.location_short_ita}"
+}
@@ -0,0 +1,24 @@
+terraform {
+  required_version = ">= 1.9.0"
+
+  required_providers {
+    azurerm = {
+      source  = "hashicorp/azurerm"
+      version = ">= 4"
+    }
+  }
+  backend "azurerm" {}
+}
+
+provider "azurerm" {
+  features {
+    key_vault {
+      purge_soft_delete_on_destroy = false
+    }
+    resource_group {
+      prevent_deletion_if_contains_resources = false
+    }
+  }
+}
+
+data "azurerm_subscription" "current" {}
@@ -0,0 +1,108 @@
+variable "prefix" {
+  type = string
+  validation {
+    condition = (
+      length(var.prefix) <= 6
+    )
+    error_message = "Max length is 6 chars."
+  }
+}
+
+variable "env" {
+  type = string
+}
+
+variable "env_short" {
+  type = string
+  validation {
+    condition = (
+      length(var.env_short) == 1
+    )
+    error_message = "Length must be 1 chars."
+  }
+}
+
+#
+# location
+#
+variable "location" {
+  type        = string
+  description = "One of westeurope, northeurope"
+}
+
+variable "location_short" {
+  type = string
+  validation {
+    condition = (
+      length(var.location_short) == 3
+    )
+    error_message = "Length must be 3 chars."
+  }
+  description = "One of wue, neu"
+}
+
+### Italy location
+variable "location_ita" {
+  type        = string
+  description = "Main location"
+  default     = "italynorth"
+}
+
+variable "location_short_ita" {
+  type = string
+  validation {
+    condition = (
+      length(var.location_short_ita) == 3
+    )
+    error_message = "Length must be 3 chars."
+  }
+  description = "Location short for italy: itn"
+  default     = "itn"
+}
+
+
+variable "application_insisght_name" {
+  type        = string
+  description = "The name of the Application Insights resource for monitoring and alerting"
+}
+
+variable "application_insisght_resource_group_name" {
+  type        = string
+  description = "The name of the resource group where the Application Insights resource is located"
+}
+
+###################
+### ClouDO Vars ###
+###################
+variable "cloudo_orchestrator" {
+  type = object({
+    image_name        = optional(string, "pagopa/cloudo-orchestrator")
+    image_tag         = optional(string, "0.0.0")
+    registry_url      = optional(string, "https://ghcr.io")
+    registry_username = optional(string)
+    registry_password = optional(string)
+  })
+  description = "Configuration for the ClouDO orchestrator container, including container image details and registry authentication."
+}
+
+variable "cloudo_ui" {
+  type = object({
+    image_name        = optional(string, "pagopa/cloudo-ui")
+    image_tag         = optional(string, "0.0.0")
+    registry_url      = optional(string, "https://ghcr.io")
+    registry_username = optional(string)
+    registry_password = optional(string)
+  })
+  description = "Configuration for the ClouDO UI App Service, including container image details and registry authentication."
+}
+
+variable "cloudo_worker" {
+  type = object({
+    image_name        = optional(string, "pagopa/cloudo-worker")
+    image_tag         = optional(string, "0.0.0")
+    registry_url      = optional(string, "https://ghcr.io")
+    registry_username = optional(string)
+    registry_password = optional(string)
+  })
+  description = "Configuration for the ClouDO worker container, including container image details and registry authentication."
+}