PKGBUILD

# Maintainer: aksr <aksr at t-com dot me>
pkgname=scrollz-git
pkgver=2.3.1.r1664.642cecf
pkgrel=1
pkgdesc="An advanced IRC client based on ircII client."
arch=('i686' 'x86_64')
url="https://github.com/ScrollZ/ScrollZ"
license=('custom')
depends=('ncurses' 'openssl')
makedepends=('git')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
source=("$pkgname::git+https://github.com/ScrollZ/ScrollZ.git"
        "fix-fortify-snprintf.patch"
        "fix-mirc-256color.patch")
md5sums=('SKIP'
         'SKIP'
         'SKIP')

prepare() {
	cd "$srcdir/$pkgname"
	patch -p1 -N -i "$srcdir/fix-fortify-snprintf.patch" || true
	patch -p1 -N -i "$srcdir/fix-mirc-256color.patch" || true
}

pkgver() {
	cd "$srcdir/$pkgname"
	printf "%s.r%s.%s" \
		"$(git describe --tags | sed -E 's/ScrollZ-//;s/-.*//')" \
		"$(git rev-list --count HEAD)" \
		"$(git rev-parse --short HEAD)"
}

build() {
	cd $srcdir/$pkgname
	export CFLAGS="$CFLAGS -std=gnu89 -Wno-incompatible-pointer-types -Wno-implicit-function-declaration -Wno-implicit-int -Wno-int-conversion"
	./configure \
		--prefix=/usr   \
		--enable-regexp \
		--enable-fish   \
		--with-openssl  \
		--with-default-server=chat.freenode.net:6667
	make
}

package() {
	cd $srcdir/$pkgname
	make DESTDIR="$pkgdir/" install
	install -D -m644 COPYRIGHT $pkgdir/usr/share/licenses/$pkgname/COPYRIGHT
}