add query_platform_raw for acme

Author: martinatpeek

lib/peek_app_sdk.ex

@@ -88,4 +88,13 @@ defmodule PeekAppSDK do
 
   defdelegate query_platform(install_id, method, url, body),
     to: PeekAppSDK.Client
+
+  @doc """
+  Queries a platform API and returns the raw response body.
+  Unlike `query_platform/4`, this does not expect a `{data: ...}` wrapper around the response.
+  """
+  @spec query_platform_raw(String.t(), atom(), String.t(), map()) ::
+          {:ok, map()} | {:error, list()} | {:error, {integer(), any()}}
+  defdelegate query_platform_raw(install_id, method, url, body),
+    to: PeekAppSDK.Client
 end

lib/peek_app_sdk/client.ex

@@ -99,6 +99,35 @@ defmodule PeekAppSDK.Client do
     end
   end
 
+  @doc """
+  Queries a platform API and returns the raw response body.
+  Unlike `query_platform/4`, this does not expect a `{data: ...}` wrapper around the response.
+  """
+  @spec query_platform_raw(String.t(), atom(), String.t(), map()) ::
+          {:ok, map()} | {:error, list()} | {:error, {integer(), any()}}
+  def query_platform_raw(install_id, method, url, body_params) do
+    config = Config.get_config(nil)
+    peek_api_key = config.peek_api_key
+
+    case Tesla.request(client(),
+           method: method,
+           url: url,
+           body: body_params,
+           headers: headers(install_id, nil, peek_api_key)
+         ) do
+      {:ok, %Tesla.Env{status: 200, body: %{errors: [_error | _rest] = errors}}} ->
+        {:error, errors}
+
+      {:ok, %Tesla.Env{status: status, body: body}} when status in 200..299 ->
+        {:ok, body}
+
+      {:ok, %Tesla.Env{status: status, body: body}} ->
+        Logger.error("Unexpected Platform response when hitting #{url} - (#{status}): #{inspect(body)}")
+
+        {:error, {status, body}}
+    end
+  end
+
   def operation_name(query) do
     regex = ~r/\b(query|mutation|subscription)\s+(\w+)/
 

test/peek_app_sdk/client_test.exs

@@ -292,6 +292,69 @@ defmodule PeekAppSDK.ClientTest do
     end
   end
 
+  describe "query_platform_raw/4" do
+    test "successfully returns raw response body for 200 status" do
+      install_id = "test_install_id"
+      url = "https://api.example.com/some/endpoint"
+      body_params = %{}
+      response_body = %{result: "success", other_field: "value"}
+
+      Tesla.Adapter.Finch
+      |> Mimic.stub(:call, fn env, _opts ->
+        assert env.method == :get
+        assert env.url == url
+
+        {:ok, %Tesla.Env{status: 200, body: response_body}}
+      end)
+
+      assert {:ok, ^response_body} = Client.query_platform_raw(install_id, :get, url, body_params)
+    end
+
+    test "successfully returns raw response body for 201 status" do
+      install_id = "test_install_id"
+      url = "https://api.example.com/api/resource"
+      body_params = %{"key" => "value"}
+      response_body = %{created: true, id: 123}
+
+      Tesla.Adapter.Finch
+      |> Mimic.stub(:call, fn env, _opts ->
+        assert env.method == :post
+        assert env.url == url
+
+        {:ok, %Tesla.Env{status: 201, body: response_body}}
+      end)
+
+      assert {:ok, ^response_body} = Client.query_platform_raw(install_id, :post, url, body_params)
+    end
+
+    test "handles error response with status and body tuple" do
+      install_id = "test_install_id"
+      url = "https://api.example.com/api/resource"
+      error_body = %{error: "Not found"}
+
+      Tesla.Adapter.Finch
+      |> Mimic.stub(:call, fn _env, _opts ->
+        {:ok, %Tesla.Env{status: 404, body: error_body}}
+      end)
+
+      assert {:error, {404, ^error_body}} = Client.query_platform_raw(install_id, :get, url, %{})
+    end
+
+    test "bubbles up errors when status is 200 but errors key is present" do
+      install_id = "test_install_id"
+      url = "https://api.example.com/api/resource"
+
+      errors = [%{message: "Validation failed"}]
+
+      Tesla.Adapter.Finch
+      |> Mimic.stub(:call, fn _env, _opts ->
+        {:ok, %Tesla.Env{status: 200, body: %{errors: errors}}}
+      end)
+
+      assert {:error, ^errors} = Client.query_platform_raw(install_id, :post, url, %{})
+    end
+  end
+
   describe "operation_name/1" do
     test "extracts operation name from query" do
       query = "query TestOperation { test }"