extract settings model

Author: demarey

src/PharoLauncher-Settings-Tests/PhLSettingTest.class.st

@@ -0,0 +1,105 @@
+Class {
+	#name : 'PhLSettingTest',
+	#superclass : 'TestCase',
+	#category : 'PharoLauncher-Settings-Tests',
+	#package : 'PharoLauncher-Settings-Tests'
+}
+
+{ #category : 'tests' }
+PhLSettingTest >> testCanReadRealValue [
+	
+	self assert: SettingsTestData booleanSetting realValue equals: false.
+	self assert: SettingsTestData rangeSetting realValue equals: 1.
+]
+
+{ #category : 'tests' }
+PhLSettingTest >> testCanSetRealValueWhenBooleanSetting [
+	| setting |
+	setting := SettingsTestData booleanSetting.
+	
+	setting realValue: false.
+	self deny: setting realValue.
+	
+	setting realValue: true.
+	self assert: setting realValue 
+]
+
+{ #category : 'tests' }
+PhLSettingTest >> testCanSetRealValueWhenRangeSetting [
+	| setting |
+	setting := SettingsTestData rangeSetting.
+	
+	setting realValue: 2.
+	self  assert: setting realValue equals: 2.
+	
+	setting realValue: 1.5.
+	self  assert: setting realValue equals: 1.5.
+
+]
+
+{ #category : 'tests' }
+PhLSettingTest >> testChildIdentifier [
+
+	self
+		assert: SettingsTestData rangeSetting settingIdentifier
+		equals: '#appearance#scaleFactor'
+]
+
+{ #category : 'tests - realTarget' }
+PhLSettingTest >> testReceiverIsClassDefiningSettingWhenNoTargetSpecified [
+
+	| setting |
+	setting := (SettingsTestData settingsFor: #basic_setting_test_data) first.
+
+	self assert: setting settingReceiver equals: SettingsTestData
+]
+
+{ #category : 'tests - realTarget' }
+PhLSettingTest >> testReceiverIsClassDefiningSettingWhenNoTargetSpecifiedAndGroupSWithNoTarget [
+
+	self
+		assert: SettingsTestData basicSettingWithGroupAndNoTarget settingReceiver
+		equals: SettingsTestData
+]
+
+{ #category : 'tests - realTarget' }
+PhLSettingTest >> testReceiverIsEvaluationOfGroupTargetSelectorWhenNoTargetSpecifiedAndGroupTargetSelectorSpecified [
+
+	self
+		assert: SettingsTestData basicSettingWithGroupTargetSelector settingReceiver
+		equals: Array empty
+]
+
+{ #category : 'tests - realTarget' }
+PhLSettingTest >> testReceiverIsEvaluationOfTargetSelectorWhenTargetSelectorSpecified [
+
+	| setting |
+	setting := (SettingsTestData settingsFor: #basic_setting_with_target_selector_test_data) first.
+
+	self assert: setting settingReceiver equals: String empty
+]
+
+{ #category : 'tests - realTarget' }
+PhLSettingTest >> testReceiverIsGroupTargetWhenNoTargetSpecified [
+
+	self
+		assert: SettingsTestData basicSettingWithGroupTarget settingReceiver
+		equals: Object
+]
+
+{ #category : 'tests - realTarget' }
+PhLSettingTest >> testReceiverIsTargetWhenTargetSpecified [
+
+	| setting |
+	setting := (SettingsTestData settingsFor: #basic_setting_with_target_test_data) first.
+
+	self assert: setting settingReceiver equals: String
+]
+
+{ #category : 'tests' }
+PhLSettingTest >> testRootIdentifier [
+
+	self
+		assert: SettingsTestData booleanSetting settingIdentifier
+		equals: '#shouldQuit'
+]

src/PharoLauncher-Settings-Tests/PhLSystemSettingsTest.class.st

@@ -0,0 +1,38 @@
+Class {
+	#name : 'PhLSystemSettingsTest',
+	#superclass : 'TestCase',
+	#category : 'PharoLauncher-Settings-Tests',
+	#package : 'PharoLauncher-Settings-Tests'
+}
+
+{ #category : 'building' }
+PhLSystemSettingsTest >> systemSettings [
+
+	^ (SettingsBuilder forPragmaNamed: #systemsettings) settings
+]
+
+{ #category : 'tests' }
+PhLSystemSettingsTest >> testCanAccessAllSettingsRealValues [
+
+	self systemSettings do: [ :eachSetting |
+		eachSetting hasDefaultValue and: [ eachSetting realValue ] ]
+]
+
+{ #category : 'tests' }
+PhLSystemSettingsTest >> testUniqueIdentifiers [
+
+	| identifiers |
+	identifiers := self systemSettings collect: [ :each | each settingIdentifier ].
+	
+	self assert: identifiers size equals: identifiers asSet size
+]
+
+{ #category : 'tests' }
+PhLSystemSettingsTest >> testUniqueNames [
+
+	| names |
+	names := self systemSettings collect: [ :eachSetting |
+						eachSetting groupName printString, eachSetting name ].
+					
+	self assert: names size equals: names asSet size
+]

src/PharoLauncher-Settings-Tests/SettingsBuilderTest.class.st

@@ -0,0 +1,84 @@
+Class {
+	#name : 'SettingsBuilderTest',
+	#superclass : 'TestCase',
+	#instVars : [
+		'builder'
+	],
+	#category : 'PharoLauncher-Settings-Tests',
+	#package : 'PharoLauncher-Settings-Tests'
+}
+
+{ #category : 'tests' }
+SettingsBuilderTest >> testCanBuildAPickOneSetting [
+
+	| setting |
+	builder := SettingsBuilder forPragmaNamed: #pick_one_setting_test_data.
+	
+	self assert: builder settings size equals: 1.
+	setting := builder settings first.
+	self assert: setting name equals: #uiThemeClass.
+	self assert: setting label equals: 'User interface theme'.
+	self assert: setting defaultValue equals: PhLAppearanceThemeLight.
+	self assert: setting domainValues equals: PhLAppearanceTheme all
+]
+
+{ #category : 'tests' }
+SettingsBuilderTest >> testCanBuildARangeSetting [
+
+	| setting |
+	builder := SettingsBuilder forPragmaNamed: #range_setting_test_data.
+	
+	self assert: builder settings size equals: 1.
+	setting := builder settings first.
+	self assert: setting name equals: #scaleFactor.
+	self assert: setting label equals: 'Display scale factor'.
+	self assert: setting defaultValue equals: 1.
+	self assert: setting range equals: (0.5 to: 5 by: 0.5)
+
+]
+
+{ #category : 'tests' }
+SettingsBuilderTest >> testCanBuildASetting [
+
+	| setting |
+	builder := SettingsBuilder forPragmaNamed: #boolean_setting_test_data.
+	
+	self assert: builder settings size equals: 1.
+	setting := builder settings first.
+	self assert: setting name equals: #shouldQuit.
+	self assert: setting description equals: 'will quit the app after action if setting set to true'.
+	self assert: setting label equals:'A boolean setting'.
+	self assert: setting defaultValue equals: false
+
+]
+
+{ #category : 'tests' }
+SettingsBuilderTest >> testCanBuildASettingGroup [
+
+	| settingGroup |
+	builder := SettingsBuilder forPragmaNamed: #basic_settings_group_test_data.
+	
+	self assert: builder settings size equals: 1.
+	settingGroup := builder settings first.
+	self assert: settingGroup name equals: #nonInteractive.
+	self assert: settingGroup description equals: 'Settings related to mode without UI'.
+	self assert: settingGroup label equals: 'Headless mode'.
+	self assert: settingGroup groupName equals: nil
+]
+
+{ #category : 'tests' }
+SettingsBuilderTest >> testCanBuildASettingGroupDefiningASetting [
+
+	| setting settingGroup |
+	builder := SettingsBuilder forPragmaNamed: #settings_group_with_setting_test_data.
+	
+	self assert: builder settings size equals: 2.
+	settingGroup := builder settings first.
+	self assert: settingGroup name equals: #nonInteractive.
+	
+	setting := builder settings second.
+	self assert: setting name equals: #snapshotErrorImage.
+	self assert: setting groupName equals: settingGroup name.
+	self assert: setting group equals: settingGroup
+
+]