gradle-git-versioning-plugin/build.gradle.kts at 3f486ca55e1a0d64c6618050249c5bccbf67b640 · qoomon/gradle-git-versioning-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
plugins {
    `kotlin-dsl`
    `java-gradle-plugin`

    kotlin("jvm") version embeddedKotlinVersion

    id("com.gradle.plugin-publish") version "1.0.0"
    `maven-publish` // for local testing only

    id("com.github.ben-manes.versions") version "0.43.0"
    id("com.adarshr.test-logger") version "3.2.0"

    idea
}

group = "me.qoomon"
version = "6.3.7"

dependencies {
    implementation("org.eclipse.jgit:org.eclipse.jgit:6.3.0.202209071007-r")
    implementation("org.apache.maven:maven-artifact:3.8.6")
    implementation("org.apache.commons:commons-configuration2:2.8.0")

    testImplementation("org.junit.jupiter:junit-jupiter-api:5.9.1")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.9.1")
    testImplementation("org.assertj:assertj-core:3.23.1")
}

tasks.withType<Test>().configureEach {
    useJUnitPlatform()
}

gradlePlugin {
    plugins.create("gitVersioning") {
        id = "me.qoomon.git-versioning"
        displayName = "Git Versioning Plugin"
        description =
            "This extension will adjust the project version, based on current git branch or tag."
        implementationClass = "me.qoomon.gradle.gitversioning.GitVersioningPlugin"
    }
}

pluginBundle {
    website = "https://github.com/qoomon/gradle-git-versioning-plugin"
    vcsUrl = "https://github.com/qoomon/gradle-git-versioning-plugin.git"
    tags = listOf("git", "versioning", "version", "commit", "branch", "tag", "generated")
}

val projectJvmTarget = "11"

kotlin {
    jvmToolchain {
        languageVersion.set(JavaLanguageVersion.of(projectJvmTarget))
    }
}

kotlinDslPluginOptions {
    jvmTarget.set(projectJvmTarget)
}

tasks.withType<org.jetbrains.kotlin.gradle.tasks.KotlinCompile>().configureEach {
    kotlinOptions {
        jvmTarget = projectJvmTarget
    }
}

idea {
    module {
        isDownloadSources = true
        isDownloadJavadoc = false
    }
}