Fix amqp091->amqp10 shovel with complex headers

Some AMQP 0.9.1 headers, in particular x-death headers,
cannot be set as application properties. Before this change,
trying to shovel dead-lettered messages from an AMQP 0.9.1
source to AMQP 1.0 destination would fail with:

```
reason: {badarg,
            [{unicode,characters_to_binary,
                 [[{table,
                       [{<<"count">>,long,1},
                        {<<"reason">>,longstr,<<"maxlen">>},
                        {<<"queue">>,longstr,<<"tmp">>},
                        {<<"time">>,timestamp,1745575728},
                        {<<"exchange">>,longstr,<<>>},
                        {<<"routing-keys">>,array,
                         [{longstr,<<"tmp">>}]}]}]],
                 [{file,"unicode.erl"},
                  {line,1219},
                  {error_info,#{module => erl_stdlib_errors}}]},
             {amqp10_client_types,utf8,1,
                 [{file,"amqp10_client_types.erl"},{line,99}]},
             {amqp10_msg,'-set_application_properties/2-fun-0-',3,
                 [{file,"amqp10_msg.erl"},{line,385}]},
             {maps,fold_1,4,[{file,"maps.erl"},{line,860}]},
             {amqp10_msg,set_application_properties,2,
                 [{file,"amqp10_msg.erl"},{line,384}]},
             {maps,fold_1,4,[{file,"maps.erl"},{line,860}]},
             {rabbit_amqp10_shovel,forward,4,
                 [{file,"rabbit_amqp10_shovel.erl"},{line,337}]},
             {rabbit_shovel_worker,handle_info,2,
                 [{file,"rabbit_shovel_worker.erl"},{line,104}]}]}
```

Author: mkuratczyk

deps/rabbitmq_shovel/Makefile

@@ -23,7 +23,7 @@ dep_amqp10_client = git https://github.com/rabbitmq/rabbitmq-amqp1.0-client.git
 
 LOCAL_DEPS = crypto
 
-TEST_DEPS = rabbitmq_ct_helpers rabbitmq_ct_client_helpers rabbitmq_amqp1_0 meck
+TEST_DEPS = rabbitmq_ct_helpers rabbitmq_ct_client_helpers rabbitmq_amqp1_0 rabbitmq_amqp_client meck
 
 PLT_APPS += rabbitmq_cli
 

deps/rabbitmq_shovel/src/rabbit_amqp10_shovel.erl

@@ -442,9 +442,12 @@ bin_to_hex(Bin) ->
            true  -> N + $0 end>>
       || <<N:4>> <= Bin>>.
 
-is_amqp10_compat(T) ->
-    is_binary(T) orelse
-    is_number(T) orelse
-    %% TODO: not all lists are compatible
-    is_list(T) orelse
-    is_boolean(T).
+-spec is_amqp10_compat(T :: term()) -> boolean().
+is_amqp10_compat(T) when is_binary(T) -> true;
+is_amqp10_compat(T) when is_number(T) -> true;
+is_amqp10_compat(T) when is_boolean(T) -> true;
+is_amqp10_compat(T) when is_list(T) ->
+    %% A list is compatible only if all its elements are also compatible.
+    lists:all(fun is_amqp10_compat/1, T);
+is_amqp10_compat(_) ->
+    false.

deps/rabbitmq_shovel/test/amqp10_dynamic_SUITE.erl

@@ -27,7 +27,8 @@ groups() ->
           autodelete_amqp091_dest_on_confirm,
           autodelete_amqp091_dest_on_publish,
           simple_amqp10_dest,
-          simple_amqp10_src
+          simple_amqp10_src,
+          amqp091_to_amqp10_with_dead_lettering
         ]},
       {with_map_config, [], [
           simple,
@@ -96,6 +97,29 @@ simple_amqp10_dest(Config) ->
                                       <<"src-queue">>)
       end).
 
+amqp091_to_amqp10_with_dead_lettering(Config) ->
+    Dest = ?config(destq, Config),
+    Src = ?config(srcq, Config),
+    TmpQ = <<"tmp">>,
+    with_session(Config,
+      fun (Sess) ->
+              {ok, LinkPair} = rabbitmq_amqp_client:attach_management_link_pair_sync(Sess, <<"my link pair">>),
+              {ok, _} = rabbitmq_amqp_client:declare_queue(LinkPair, TmpQ,
+                                               #{arguments =>#{<<"x-max-length">> => {uint, 0},
+                                                               <<"x-dead-letter-exchange">> => {utf8, <<"">>},
+                                                               <<"x-dead-letter-routing-key">> => {utf8, Src}}}),
+              {ok, Sender} = amqp10_client:attach_sender_link(Sess,
+                                                              <<"sender-tmp">>,
+                                                              <<"/queues/", TmpQ/binary>>,
+                                                              unsettled,
+                                                              unsettled_state),
+              ok = await_amqp10_event(link, Sender, attached),
+              expect_empty(Sess, TmpQ),
+              test_amqp10_destination(Config, Src, Dest, Sess, <<"amqp091">>, <<"src-queue">>),
+              %% publish to tmp, it should be dead-lettered to src and then shovelled to dest
+              _ = publish_expect(Sess, TmpQ, Dest, <<"tag1">>, <<"hello">>)
+      end).
+
 test_amqp10_destination(Config, Src, Dest, Sess, Protocol, ProtocolSrc) ->
     MapConfig = ?config(map_config, Config),
     shovel_test_utils:set_param(Config, <<"test">>,